I_MaterialStockNetWeight

@EndUserText.label: 'Netweight of Material on Stock'
@Analytics. dataCategory: #DIMENSION
@VDM.viewType: #COMPOSITE
@ObjectModel.representativeKey: ['PeriodType','EndDate','YearPeriod','Material','Plant','StorageLocation']
@Metadata.allowExtensions:true 

@AccessControl.authorizationCheck: #CHECK

@AbapCatalog.sqlViewName: 'IMATSTKNETW'
@AbapCatalog.compiler.compareFilter: true

// Client handling by session 

@ClientHandling.algorithm: #SESSION_VARIABLE

// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #D,         // default < 500ms

                         sizeCategory:  #XL,         // < 100.000.000   // due to OTR text lookup

                         dataClass: #MIXED }   

define view I_MaterialStockNetWeight
 with parameters
    P_StartDate  : vdm_v_start_date,
    P_EndDate    : vdm_v_end_date 
    
as select from I_MaterialStockTimeSeries( P_StartDate: $parameters.P_StartDate, P_EndDate: $parameters.P_EndDate , P_PeriodType: 'D' )

{
  key PeriodType,
 
  key EndDate,
  key YearPeriod,
  key Material, 
  key Plant,  
  key StorageLocation,
  key Batch,
  @ObjectModel.foreignKey.association: '_Supplier' 
  key Supplier,
  key SDDocument,
  key SDDocumentItem,
  key WBSElementInternalID,
  @ObjectModel.foreignKey.association: '_Customer'
  key Customer,
  @ObjectModel.foreignKey.association: '_InventoryStockType'
  key InventoryStockType,
  @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
  key InventorySpecialStockType,
  @Semantics.fiscal.yearVariant: true
  key FiscalYearVariant,
  key MaterialBaseUnit,
  
  _Material,
  _Plant,
//  _Plant._Address.Country,

//  _Plant._Address,

//  _Plant.AddressID,

  _Supplier,
  _Customer,
  _InventorySpecialStockType,
  _InventoryStockType,
  _StorageLocation,
  _Material.MaterialWeightUnit,
  _Material._WeightUnit,
  _Material.MaterialNetWeight,
  _FiscalYearVariant,

   MatlWrhsStkQtyInMatlBaseUnit,


  cast (MatlWrhsStkQtyInMatlBaseUnit as abap.quan(14,3) )  // cast needed on order to be able to mutiply

  * cast (_Material.MaterialNetWeight as abap.quan(14,3) )
  as MatlWrhsStockNetWeight
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIAL",
"I_MATERIALSTOCKTIMESERIES"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_FISCALYEARVARIANT",
"I_INVENTORYSPECIALSTOCKTYPE",
"I_INVENTORYSTOCKTYPE",
"I_MATERIAL",
"I_PLANT",
"I_STORAGELOCATION",
"I_SUPPLIER",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_MATERIAL",
"I_MATERIALSTOCKTIMESERIES"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/