I_MaterialSampleDetails

@AbapCatalog.sqlViewName: 'ISAMPLEDETAIL'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck:  #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'CDS View for Material Sample Details'
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType: { dataClass: #MIXED, sizeCategory: #L, serviceQuality: #C }
define view I_MaterialSampleDetails
  as select from    I_MaterialSample
    left outer join I_InspectionLot _InspectionLot                 on I_MaterialSample.InspectionLot = _InspectionLot.InspectionLot
    left outer join I_MaterialSampleDrawing _MaterialSampleDrawing on I_MaterialSample.MaterialSampleDrawing = _MaterialSampleDrawing.MaterialSampleDrawing
    left outer join I_Supplier _Supplier                           on _MaterialSampleDrawing.Supplier = _Supplier.Supplier
    left outer join I_Supplier _Manufacturer                       on _MaterialSampleDrawing.Manufacturer = _Manufacturer.Supplier
    left outer join I_Customer _Customer                           on _MaterialSampleDrawing.Customer = _Customer.Customer
    left outer join I_User _UserCreatedBy                          on _UserCreatedBy.UserID = _MaterialSampleDrawing.CreatedByUser
{
  key I_MaterialSample.MaterialSample,
      I_MaterialSample.InspectionLot,
      I_MaterialSample.MaterialSampleDrawing,
      I_MaterialSample.Plant,
      I_MaterialSample.MatlQualityAuthorizationGroup,
      _MaterialSampleDrawing.Supplier      as Supplier,
      _Supplier.SupplierName               as SupplierName,
      _MaterialSampleDrawing.Manufacturer  as Manufacturer,
      _Manufacturer.SupplierName           as ManufacturerName,
      _MaterialSampleDrawing.Customer      as Customer,
      _Customer.CustomerName               as CustomerName,      
      _MaterialSampleDrawing.CreatedByUser as CreatedByUser,
      _MaterialSampleDrawing.CreationDate,
      _MaterialSampleDrawing.CreationTime,

      _UserCreatedBy.UserDescription       as FullName,
      
      // Fields for authorization check

      @Consumption.hidden: true
      _MaterialSampleDrawing.IsBusinessPurposeCompleted
} 
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMER",
"I_INSPECTIONLOT",
"I_MATERIALSAMPLE",
"I_MATERIALSAMPLEDRAWING",
"I_SUPPLIER",
"I_USER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/