I_MaterialPlantPRTRegnControl

DDL: I_MATERIALPLANTPRTREGNCONTROL Type: view_entity COMPOSITE

PRT Regn Control of Material in Plant

I_MaterialPlantPRTRegnControl is a Composite CDS View that provides data about "PRT Regn Control of Material in Plant" in SAP S/4HANA. It reads from 1 data source (P_ProductPlantBasic) and exposes 8 fields with key fields Product, Plant. It has 2 associations to related views.

1 data source(s) 8 fields

Data Sources (1)

SourceAliasJoin Type
P_ProductPlantBasic ProductPlant from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_PRTRegistrationControl _PRTRegistrationControl $projection.PRTRegistrationControl = _PRTRegistrationControl.PRTRegistrationControl
[1..1] I_Product _Product $projection.Product = _Product.Product

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label PRT Regn Control of Material in Plant view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MASTER view
VDM.viewType #COMPOSITE view

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY Product P_ProductPlantBasic Product
KEY Plant P_ProductPlantBasic Plant
SerialNumberProfile P_ProductPlantBasic SerialNumberProfile
SerialNumberProcedure PRTSrlNmbrPrflProcedSttg SerialNumberProcedure
SerialNumberUsageInAssignment PRTSrlNmbrPrflProcedSttg SerialNumberUsageInAssignment
SerialNumberEquipCreationRqmt PRTSrlNmbrPrflProcedSttg SerialNumberEquipCreationRqmt
_PRTRegistrationControl _PRTRegistrationControl
_Product _Product 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'PRT Regn Control of Material in Plant'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MASTER}
@VDM.viewType: #COMPOSITE
define view entity I_MaterialPlantPRTRegnControl
  as select from           P_ProductPlantBasic        as ProductPlant
    left outer to one join P_PRTSrlNmbrPrflProcedSttg as PRTSrlNmbrPrflProcedSttg on PRTSrlNmbrPrflProcedSttg.SerialNumberProfile = ProductPlant.SerialNumberProfile

  association [1..1] to I_PRTRegistrationControl as _PRTRegistrationControl on $projection.PRTRegistrationControl = _PRTRegistrationControl.PRTRegistrationControl
  association [1..1] to I_Product                as _Product                on $projection.Product = _Product.Product
{
      @ObjectModel.foreignKey.association: '_Product'
  key ProductPlant.Product                                   as Product,
  key ProductPlant.Plant                                     as Plant,
      ProductPlant.SerialNumberProfile                       as SerialNumberProfile,
      PRTSrlNmbrPrflProcedSttg.SerialNumberProcedure         as SerialNumberProcedure,
      PRTSrlNmbrPrflProcedSttg.SerialNumberUsageInAssignment as SerialNumberUsageInAssignment,
      PRTSrlNmbrPrflProcedSttg.SerialNumberEquipCreationRqmt as SerialNumberEquipCreationRqmt,
      cast(case
      -- Registration is quantity based exactly if material is not serialized or if  procedure PPTR does not allow serial numbers
        when ProductPlant.SerialNumberProfile = '' or PRTSrlNmbrPrflProcedSttg.SerialNumberUsageInAssignment = '01' then 0  -- Quantity-based
        else 1  -- Serialized
      end as mpe_prt_registration_control preserving type )  as PRTRegistrationControl,

      _PRTRegistrationControl,
      _Product

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_PRODUCTPLANTBASIC",
"P_PRTSRLNMBRPRFLPROCEDSTTG"
],
"ASSOCIATED":
[
"I_PRODUCT",
"I_PRTREGISTRATIONCONTROL"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More