I_MaterialDocumentForPrint

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IMATDOCREC4PRINT'
@EndUserText.label: 'View for Material Document Print'

@AccessControl.authorizationCheck:#CHECK
@VDM.viewType : #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
    usageType: {
        sizeCategory: #XXL,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    }
} 
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking:#REQUIRED

define view I_MaterialDocumentForPrint 
  as select from I_MaterialDocumentRecord     as _MatDocRecord
  left outer join mard as _MatStorageLocation on _MatDocRecord.Material = _MatStorageLocation.matnr
                                              and _MatDocRecord.Plant = _MatStorageLocation.werks
                                              and _MatDocRecord.StorageLocation = _MatStorageLocation.lgort
  //1908 - Transfer Posting Generic FDP Service Changes - Start                                            

  left outer join mard as _IssgOrRcvgMatStorageLocation on _MatDocRecord.IssgOrRcvgMaterial = _IssgOrRcvgMatStorageLocation.matnr
                                              and _MatDocRecord.IssuingOrReceivingPlant = _IssgOrRcvgMatStorageLocation.werks
                                              and _MatDocRecord.IssuingOrReceivingStorageLoc = _IssgOrRcvgMatStorageLocation.lgort
  association [0..1] to I_ProductText                 as _IssgOrRcvgProductText           on  $projection.IssgOrRcvgMaterial = _IssgOrRcvgProductText.Product
                                                                                          and $projection.Language = _IssgOrRcvgProductText.Language
  association [0..1] to I_InventorySpecialStockTypeT  as _IssgOrRcvgInvtrySpclStkIndTxt   on  $projection.IssgOrRcvgSpclStockInd = _IssgOrRcvgInvtrySpclStkIndTxt.InventorySpecialStockType
                                                                                          and $projection.Language = _IssgOrRcvgInvtrySpclStkIndTxt.Language
  //1908 - Transfer Posting Generic FDP Service Changes - End                                                                                      

  association [0..1] to I_ProductText                 as _ProductText                     on  $projection.Material = _ProductText.Product
                                                                                          and $projection.Language = _ProductText.Language                                                                                                                                                                                                                                                                      
  association [0..1] to I_InventorySpecialStockTypeT  as _InventorySpecialStockTypeText   on  $projection.InventorySpecialStockType = _InventorySpecialStockTypeText.InventorySpecialStockType
                                                                                          and $projection.Language = _InventorySpecialStockTypeText.Language
  association [0..1] to I_GoodsMovementTypeT          as _GoodsMovementTypeText           on  $projection.GoodsMovementType = _GoodsMovementTypeText.GoodsMovementType
                                                                                          and $projection.Language = _GoodsMovementTypeText.Language                                                                                                                                                                            
{
 key  MaterialDocumentYear,
 key  MaterialDocument,
 key  MaterialDocumentItem,

 StockIdentifyingMaterial,
 Plant,
 StockIdfgStorageLocation,
 StockIdentifyingBatch,
 SpecialStockIdfgSupplier,
 SpecialStockIdfgSalesOrder,
 SpecialStockIdfgSalesOrderItem,
 SpecialStockIdfgWBSElement,
 SpecialStockIdfgCustomer,
 InventorySpecialStockType,
 InventoryStockType,
 SpecialStockIdfgStockOwner,
 ResourceID,

 Material,
 StorageLocation,
 Batch,
 Supplier,
 SalesOrder,
 SalesOrderItem,
 SalesOrderScheduleLine,
 Customer,
 StockOwner,
 WBSElementInternalID,

 IssgOrRcvgMaterial,
 IssuingOrReceivingPlant,
 IssuingOrReceivingStorageLoc,
 IssgOrRcvgBatch,
 IssgOrRcvgSpclStockInd,
 IssuingOrReceivingValType,
 IssuingOrReceivingStockType,
 IssgOrRcvgResourceID,

 GoodsMovementRefDocType,
 ConsumptionPosting,
 GoodsMovementReasonCode,
 NumberOfSlipsToBePrinted,
 NumberOfLabelsToBePrinted,
 GoodsMovementType,
 DebitCreditCode,
 InventoryUsabilityCode,
  @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
  @DefaultAggregation: #NONE
  QuantityInBaseUnit,
  @Semantics.unitOfMeasure: true
  MaterialBaseUnit,

  @DefaultAggregation:#NONE
  @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
  MatlStkChangeQtyInBaseUnit,

  @DefaultAggregation:#NONE
  @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
  MatlCnsmpnQtyInMatlBaseUnit,

  @Semantics.businessDate.at: true
  DocumentDate,
  AccountingDocumentType,
 InventoryTransactionType,
 InventorySpecialStockValnType,

 CreationDate,
 CreationTime,
 CreatedByUser,
 MaterialDocumentHeaderText,
 MaterialDocumentItemText,
 DeliveryInMatlDocumentHeader,
 BillOfLading,

 ShelfLifeExpirationDate,
 ManufactureDate,

  @Semantics.quantity.unitOfMeasure: 'EntryUnit'
  @DefaultAggregation: #NONE
 QuantityInEntryUnit,
  @Semantics.unitOfMeasure: true
 EntryUnit,
 InventoryValuationType,

  PurchaseOrder,
  PurchaseOrderItem,
 ProjectNetwork,
 ManufacturingOrder,
 ManufacturingOrderItem,
 OrderID,
 OrderItem,
 Reservation,
 ReservationItem,
 ReservationIsFinallyIssued,
 DeliveryDocument,
 DeliveryDocumentItem,
 IsCompletelyDelivered,

 ReversedMaterialDocumentYear,
 ReversedMaterialDocument,
 ReversedMaterialDocumentItem,
 RvslOfGoodsReceiptIsAllowed,
 IsReversalMovementType,
 GoodsMovementIsCancelled,
 GoodsMovementCancellationType,

 GoodsRecipientName,
 UnloadingPointName,
 CostCenter,
 GLAccount,
 CostObject,
 ProfitabilitySegment,
 ProfitCenter,
 CostEstimate,

 ReferenceDocument,
 ServicePerformer,
 EmploymentInternalID,
 AccountAssignmentCategory,
 WorkItem,
 ServicesRenderedDate,

 CompanyCode,
 BusinessArea,
 ControllingArea,
 FunctionalArea,
 OriginalMaterialDocumentItem,
 MultiAcctAssgmtOriglMatlDocItm,
 GoodsReceiptIsNonValuated,
 @VDM.lifecycle.status: #DEPRECATED
 @VDM.lifecycle.successor: 'MultipleAccountAssignmentCode'
 HasMultipleAccountAssignment,
 MultipleAccountAssignmentCode,
 MasterFixedAsset,
 FixedAsset,
  @Semantics.businessDate.at: true
 PostingDate,
  @Semantics.fiscal.yearPeriod: true
 FiscalYearPeriod,
  @Semantics.fiscal.yearVariant: true
 FiscalYearVariant,

 FundsCenter,
 Fund,
 CommitmentItemShortID, // replacement for CommitmentItem 

 GrantID,

 StorageType,
 StorageBin,

 YearDay,
  @Semantics.calendar.yearWeek: true
 YearWeek,
  @Semantics.calendar.yearMonth: true
 YearMonth,
  @Semantics.calendar.yearQuarter: true
 YearQuarter,
  @Semantics.calendar.year: true
 DocumentYear,
  @Semantics.calendar.quarter: true
 CalendarQuarter,
  @Semantics.calendar.month: true
 CalendarMonth,
  @Semantics.calendar.week: true
 CalendarWeek,
  @Semantics.calendar.dayOfYear: true
 CalendarDay,
 WeekDay,
 FiscalYear,
 YearPeriod,

  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  @DefaultAggregation: #NONE
 TotalGoodsMvtAmtInCCCrcy,
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  @DefaultAggregation: #NONE
 GoodsMovementStkAmtInCCCrcy,
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  @DefaultAggregation: #NONE
 GoodsMvtCnsmpnAmtInCCCrcy,
  @Semantics.currencyCode: true
 CompanyCodeCurrency,

  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  @DefaultAggregation: #NONE
 GdsMvtExtAmtInCoCodeCrcy,
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  @DefaultAggregation: #NONE
 SlsPrcAmtInclVATInCoCodeCrcy,
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  @DefaultAggregation: #NONE
 EnteredSlsAmtInCoCodeCrcy,

  @Consumption.hidden: true
 TransactionCode,

  @Consumption.hidden: true
 IsAutomaticallyCreated,
  @Consumption.hidden: true
 MaterialDocumentLine,
  @Consumption.hidden: true
 MaterialDocumentParentLine,
  @Consumption.hidden: true
 HierarchyNodeLevel,

  @Consumption.hidden: true
  MaterialDocumentRecordType,
  IsMaterialDocumentHeader,
  
  MaintOrderRoutingNumber,
  MaintOrderOperationCounter,
  ManufacturerMaterial,
  ActivityInWarehouseIsPending,
  IssgOrRcvgWBSElement,
  WarehouseNumber,
  TransferRequirementNumber,
  TransferPriority,
  VersionForPrintingSlip,
  IssgOrRcvgSalesOrder,
  IssgOrRcvgSalesOrderItem,
  ShippingInstruction,
  ShipgInstrnSupplierCompliance,
  @Semantics.quantity.unitOfMeasure: 'OrderPriceUnit' 
  QtyInPurchaseOrderPriceUnit,
  @Semantics.unitOfMeasure: true
  OrderPriceUnit,
  @DefaultAggregation: #NONE
  @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
  GoodsReceiptQtyInOrderUnit,
  @Semantics.unitOfMeasure: true
  OrderQuantityUnit,
  @DefaultAggregation:#NONE
  @Semantics.quantity.unitOfMeasure: 'DeliveryQuantityUnit'
  QuantityInDeliveryQtyUnit,
  @Semantics.unitOfMeasure: true
  DeliveryQuantityUnit,
  $session.system_language as Language,
  _Plant.PlantName,
  _Plant.PlantCategory,
  _Plant.AddressID,
  _StorageLocation.StorageLocationName,
  _IssuingOrReceivingStorageLoc.StorageLocationName as IssuingOrReceivingStorLocName,
  _Supplier.SupplierName,   
  _MatStorageLocation.lgpbe as WarehouseStorageBin,
  
//  @Consumption.hidden: true

  GoodsReceiptType,
  
  //1908 - Transfer Posting generic FDP Service Changes - Start

  _IssuingOrReceivingPlant.AddressID as IssgOrRcvgPlantAddressID,
  _IssuingOrReceivingPlant.PlantName as IssuingOrReceivingPlantName,
  _IssgOrRcvgMatStorageLocation.lgpbe as IssgOrRcvgWarehouseStorageBin,
  _IssgOrRcvgProductText,
  _IssgOrRcvgInvtrySpclStkIndTxt,
  //1908 - Transfer Posting generic FDP Service Changes - End

  
  _ProductText,
  _InventorySpecialStockTypeText,
  _GoodsMovementTypeText,
  
  //Exposed for DCL check

  _StorageLocation,
  _CustomerCompanyByPlant,
  _IssuingOrReceivingStorageLoc,
  _BPStockOwner,
  _Supplier,
  _SupplierCompanyByPlant,
  _Customer,
  _GoodsMvtTypeBySpclStkIndT
 
}

where MaterialDocumentRecordType = 'MDOC'

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALDOCUMENTRECORD",
"I_PLANT",
"I_STORAGELOCATION",
"I_SUPPLIER",
"MARD"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_CUSTOMERCOMPANYBYPLANT",
"I_GOODSMOVEMENTTYPET",
"I_GOODSMVTTYPEBYSPCLSTKINDT",
"I_INVENTORYSPECIALSTOCKTYPET",
"I_PRODUCTTEXT",
"I_STORAGELOCATION",
"I_SUPPLIER",
"I_SUPPLIERCOMPANYBYPLANT"
],
"BASE":
[
"I_MATERIALDOCUMENTRECORD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/