I_MasterDataChangeProcessEnhcd

@AbapCatalog.sqlViewName: 'IMDCHGPROCENH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: { dataClass: #TRANSACTIONAL, sizeCategory: #M, serviceQuality: #C }
@ObjectModel.representativeKey: 'MasterDataChangeProcess'
@ObjectModel.semanticKey: 'MasterDataChangeProcess'
@VDM.viewType: #COMPOSITE
@Analytics.dataCategory: #FACT
@Search.searchable: true
@EndUserText.label: 'MD Change Process Enhanced'
define view I_MasterDataChangeProcessEnhcd

  as select from I_MasterDataChangeProcess
  association [0..1] to I_MDChgProcessStepEnhcd       as _MDChgProcessStepEnhcd       on  _MDChgProcessStepEnhcd.MasterDataChangeProcess = $projection.MasterDataChangeProcess
                                                                                      and _MDChgProcessStepEnhcd.MDChgProcessStep        = $projection.MDChgProcessCurrentStepNumber

  association [1..1] to I_MDChgProcessStatusState     as _MDChgProcessStatusState     on  _MDChgProcessStatusState.MDChgProcessStatusStateCode = $projection.mdchgprocessstatusstatecode
  association [1..1] to I_MDChgProcessStatusStateCode as _MDChgProcessStatusStateCode on  _MDChgProcessStatusStateCode.MasterDataChangeProcess = $projection.MasterDataChangeProcess
  association [1..1] to I_MDChgProcessType            as _MDChgProcessType            on  _MDChgProcessType.MDChgProcessTypeID = $projection.MDChgProcessTypeID
  association [1..1] to I_MDChangeProcStatus          as _MDChangeProcStatus          on  _MDChangeProcStatus.MDChgProcessStatus = $projection.MDChgProcessStatus
  association [1..1] to I_MDChangeProcGoal            as _MDChangeProcGoal            on  _MDChangeProcGoal.MDChgProcessGoal = $projection.MDChgProcessGoal
  association [0..1] to I_MDChgProcModifdObjectsEnhcd as _MDChgProcModifdObjectsEnhcd on  _MDChgProcModifdObjectsEnhcd.MasterDataChangeProcess = $projection.MasterDataChangeProcess
  association [0..1] to I_MDChangeProcessSourceEnhcd  as _MDChangeProcessSourceEnhcd  on  _MDChangeProcessSourceEnhcd.MasterDataChangeProcess = $projection.MasterDataChangeProcess
  association [0..1] to I_MDChangeProcValdtnRslts     as _MDChangeProcValdtnRslts     on  _MDChangeProcValdtnRslts.MasterDataChangeProcess = $projection.MasterDataChangeProcess
  association [0..1] to I_CalendarDate                as _MDChgProcCalendarDate       on  _MDChgProcCalendarDate.CalendarDate = $projection.MDChgProcessCreationDate
  association [0..*] to I_MDChgProcRAPBasedSwitch     as _MDChgProcRapBasedSwitch     on  _MDChgProcRapBasedSwitch.MDChgProcessSrceObjectTypeCode = $projection.MDChgProcessSrceObjectTypeCode
                                                                                      or  _MDChgProcRapBasedSwitch.MDChgProcessSuiteObjTypeCode   = $projection.MDChgProcessSrceObjectTypeCode
{
      //I_MasterDataChangeProcess

      @Search:{ defaultSearchElement: true, fuzzinessThreshold: 0.95, ranking: #HIGH }
  key MasterDataChangeProcess,
      @Search:{ defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #MEDIUM }
      MDChgProcessDescription,
      @EndUserText.label: 'Change Process Template'
      @Search:{ defaultSearchElement: true, fuzzinessThreshold: 0.95, ranking: #MEDIUM }
      MDChgProcessTypeID,
      @ObjectModel.foreignKey.association: '_MDChangeProcGoal'
      @Search:{ defaultSearchElement: true, fuzzinessThreshold: 0.95, ranking: #MEDIUM }
      MDChgProcessGoal,
      @ObjectModel.foreignKey.association: '_MDChangeProcStatus'
      @Search:{ defaultSearchElement: true, fuzzinessThreshold: 0.95, ranking: #MEDIUM }
      MDChgProcessStatus,
      MDChgProcessSrceObjectTypeCode,
      MDChgProcessWorkflowTemplate,
      @Search:{ defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #HIGH }
      MDChgProcessRequestor,
      MDChgProcessCreationDate,
      MDChgProcessCreationTime,

      MDChgProcessChangeDate,
      MDChgProcessChangeTime,
      MDChgProcessFinishDate,
      MDChgProcessFinishTime,
      MDChgProcessFinalDateTime,
      MDChgProcessNextStpAtDateTime,

      MDChgProcessCurrentStepNumber,
      MDChgProcessIsStarted,
      MDChgProcessLastActKey,

      MDChgProcessChkPointIsActive,

      MDChgProcessPredecessor,
      MDChgProcessDuplicateStrategy,

      @ObjectModel.foreignKey.association:'_MDChgProcessStatusState'
      _MDChgProcessStatusStateCode.MDChgProcessStatusStateCode,

      _MDChgProcRapBasedSwitch.MDChgProcRAPBsdSwitchIsActive,

      /* Associations */
      // I_MasterDataChangeProcessEnhcd

      _MDChgProcessStepEnhcd,
      _MDChgProcessStatusState,
      //      _MDChgProcessType,

      _MDChangeProcStatus,
      _MDChangeProcGoal,
      _MDChangeProcValdtnRslts,
      _MDChangeProcessSourceEnhcd,
      _MDChgProcModifdObjectsEnhcd,
      _MDChgProcCalendarDate

}
where
      MDChgProcessGoal != 'R'
  and MDChgProcessGoal != 'Q'
  and MDChgProcessGoal != 'T'
  and MDChgProcessIsErased != 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MASTERDATACHANGEPROCESS",
"I_MDCHGPROCESSSTATUSSTATECODE",
"I_MDCHGPROCRAPBASEDSWITCH"
],
"ASSOCIATED":
[
"I_CALENDARDATE",
"I_MDCHANGEPROCESSSOURCEENHCD",
"I_MDCHANGEPROCGOAL",
"I_MDCHANGEPROCSTATUS",
"I_MDCHANGEPROCVALDTNRSLTS",
"I_MDCHGPROCESSSTATUSSTATE",
"I_MDCHGPROCESSSTATUSSTATECODE",
"I_MDCHGPROCESSSTEPENHCD",
"I_MDCHGPROCESSTYPE",
"I_MDCHGPROCMODIFDOBJECTSENHCD",
"I_MDCHGPROCRAPBASEDSWITCH"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/