I_ManagementAccountingCube

@AbapCatalog.sqlViewName: 'IFIMGMTACCCUBE'
@EndUserText.label: 'Management Accounting - Cube'
@VDM.viewType: #COMPOSITE
@Analytics: { dataCategory: #CUBE } //, dataExtraction.enabled: true }

@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
                usageType: { sizeCategory: #XXL,
                             dataClass:  #MIXED,
                             serviceQuality: #D },
                supportedCapabilities: [#ANALYTICAL_PROVIDER],
                modelingPattern: #ANALYTICAL_CUBE }
@AccessControl.personalData.blocking: #REQUIRED

@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true


define view I_ManagementAccountingCube as select from I_JournalEntryItem
association [1..1] to I_CompanyCode                 as _CompanyCode                 on $projection.CompanyCode              = _CompanyCode.CompanyCode
association [1..1] to I_ControllingArea             as _ControllingArea             on $projection.ControllingArea          = _ControllingArea.ControllingArea
association [0..1] to I_GLAccountInChartOfAccounts  as _GLAccountInChartOfAccounts  on $projection.ChartOfAccounts          = _GLAccountInChartOfAccounts.ChartOfAccounts 
                                                                                        and $projection.GLAccount           = _GLAccountInChartOfAccounts.GLAccount 
association [0..*] to I_ProfitCenterDetail          as _ProfitCenterDetail          on $projection.ControllingArea          = _ProfitCenterDetail.ControllingArea  
                                                                                        and $projection.ProfitCenter        = _ProfitCenterDetail.ProfitCenter

association [0..*] to I_ProfitCenter                as _ProfitCenter                on $projection.ControllingArea          = _ProfitCenter.ControllingArea
                                                                                       and $projection.ProfitCenter         = _ProfitCenter.ProfitCenter
                                                                                       
association [0..1] to I_ProfitCenter                as _CurrentProfitCenter         on $projection.ControllingArea          = _CurrentProfitCenter.ControllingArea
                                                                                       and $projection.ProfitCenter         = _CurrentProfitCenter.ProfitCenter
                                                                                       and _CurrentProfitCenter.ValidityStartDate <= $session.system_date
                                                                                       and _CurrentProfitCenter.ValidityEndDate   >= $session.system_date                                                                                       
 

association [0..1] to I_Segment                     as _Segment                     on $projection.Segment                  = _Segment.Segment
association [0..*] to I_CostCenterDetail            as _CostCenterDetail            on $projection.ControllingArea          = _CostCenterDetail.ControllingArea  
                                                                                        and $projection.CostCenter          = _CostCenterDetail.CostCenter

association [0..*] to I_CostCenter                  as _CostCenter                  on $projection.ControllingArea          = _CostCenter.ControllingArea
                                                                                       and $projection.CostCenter           = _CostCenter.CostCenter
                                                                                       
association [0..1] to I_CostCenter                  as _CurrentCostCenter           on  $projection.ControllingArea         = _CurrentCostCenter.ControllingArea
                                                                                       and $projection.CostCenter           = _CurrentCostCenter.CostCenter
                                                                                       and _CurrentCostCenter.ValidityStartDate <= $session.system_date
                                                                                       and _CurrentCostCenter.ValidityEndDate   >= $session.system_date                                                                                       

association [0..1] to I_ChartOfAccounts             as _ChartOfAccounts             on $projection.ChartOfAccounts          = _ChartOfAccounts.ChartOfAccounts
association [0..1] to I_AccountingDocumentType      as _AccountingDocumentType      on $projection.AccountingDocumentType   = _AccountingDocumentType.AccountingDocumentType
association [0..1] to I_FinancialAccountType        as _FinancialAccountType        on $projection.FinancialAccountType     = _FinancialAccountType.FinancialAccountType
association [0..1] to I_DebitCreditCode             as _DebitCreditCode             on $projection.DebitCreditCode          = _DebitCreditCode.DebitCreditCode
association [0..1] to I_BusinessArea                as _BusinessArea                on $projection.BusinessArea             = _BusinessArea.BusinessArea
association [0..1] to I_Ledger                      as _Ledger                      on $projection.Ledger                   = _Ledger.Ledger

association [0..1] to I_GLAccount                   as _GLAccount                   on $projection.GLAccount                = _GLAccount.GLAccount
                                                                                       and $projection.CompanyCode          = _GLAccount.CompanyCode
association [0..1] to I_GLAccountInCompanyCode     as _GLAccountInCompanyCode       on $projection.CompanyCode              = _GLAccountInCompanyCode.CompanyCode
                                                                                       and $projection.GLAccount            = _GLAccountInCompanyCode.GLAccount
                                                                                       
association [0..1] to I_FunctionalArea              as _FunctionalArea              on $projection.FunctionalArea           = _FunctionalArea.FunctionalArea
association [0..1] to I_MaterialGroup               as _MaterialGroup               on $projection.MaterialGroup            = _MaterialGroup.MaterialGroup                                                                                  
association [0..1] to I_CustomerGroup               as _CustomerGroup               on $projection.CustomerGroup            = _CustomerGroup.CustomerGroup
association [0..1] to I_Order                       as _Order                       on $projection.OrderID                  = _Order.OrderID

association [0..1] to I_SalesDocument               as _SalesDocument               on $projection.SalesDocument            = _SalesDocument.SalesDocument
association [0..1] to I_Supplier                    as _Supplier                    on $projection.Supplier                 = _Supplier.Supplier

association [0..1] to I_FixedAsset                  as _FixedAsset                  on $projection.CompanyCode              = _FixedAsset.CompanyCode
                                                                                       and $projection.MasterFixedAsset     = _FixedAsset.MasterFixedAsset
                                                                                       and $projection.FixedAsset           = _FixedAsset.FixedAsset
association [0..1] to I_Customer                    as _Customer                    on  $projection.Customer                = _Customer.Customer
                                                                                  
association [0..1] to I_Currency                    as _BalanceTransactionCurrency  on $projection.BalanceTransactionCurrency = _BalanceTransactionCurrency.Currency
association [0..1] to I_Currency                    as _TransactionCurrency         on $projection.TransactionCurrency      = _TransactionCurrency.Currency
association [0..1] to I_Currency                    as _CompanyCodeCurrency         on $projection.CompanyCodeCurrency      = _CompanyCodeCurrency.Currency
association [0..1] to I_Order                       as _PartnerOrder_2              on  $projection.PartnerOrder            = _PartnerOrder_2.OrderID

{
    key Ledger,
    key CompanyCode,
    key FiscalYear,
    key AccountingDocument,
    key LedgerGLLineItem,
    LedgerFiscalYear,

    FinancialTransactionType,
    I_JournalEntryItem.BusinessTransactionType,
    AccountAssignmentType,
    AccountAssignment,
    ReferenceDocumentType,
    LogicalSystem,
    ReferenceDocumentContext,
    ReferenceDocument,
    GLAccount,
    @Analytics.internalName: #LOCAL 
    @ObjectModel.foreignKey.association: '_CostCenter'
    CostCenter,
    @Analytics.internalName: #LOCAL 
    @ObjectModel.foreignKey.association: '_ProfitCenter'
    ProfitCenter,
    FunctionalArea,
    BusinessArea,
    @Analytics.internalName: #LOCAL 
    @ObjectModel.foreignKey.association: '_ControllingArea'
    ControllingArea,
    Segment,
    PartnerCostCenter,
    PartnerProfitCenter,
    PartnerFunctionalArea,
    PartnerBusinessArea,
    PartnerCompany,
    PartnerSegment,
    
    @Semantics.currencyCode: true
    BalanceTransactionCurrency,
    
    @Semantics.currencyCode: true
    TransactionCurrency,
    
    @Semantics.currencyCode: true
    CompanyCodeCurrency,
    
    @Semantics.currencyCode: true
    ControllingObjectCurrency,

    @Semantics.currencyCode:true
    GlobalCurrency,

    @DefaultAggregation: #SUM
    @Semantics: { amount : {currencyCode: 'GlobalCurrency'} } AmountInGlobalCurrency,  

    @DefaultAggregation: #SUM
    @Semantics: { amount : {currencyCode: 'GlobalCurrency'} } FixedAmountInGlobalCrcy,
    
    @DefaultAggregation: #SUM
    @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
    AmountInTransactionCurrency,
    
    @DefaultAggregation: #SUM
    @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
    AmountInCompanyCodeCurrency,
    
    @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
    @DefaultAggregation: #SUM
      case DebitCreditCode 
        when 'S' then cast (AmountInCompanyCodeCurrency as fis_dr_hsl)
        else cast (cast( '0' as abap.curr( 23,2)) as fis_dr_hsl)
      end as DebitAmountInCoCodeCrcy,
    
    @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} } 
    @DefaultAggregation: #SUM
    case DebitCreditCode 
        when 'H' then cast (AmountInCompanyCodeCurrency as fis_cr_hsl)
        else cast (cast( '0' as abap.curr( 23,2)) as fis_cr_hsl)
    end as CreditAmountInCoCodeCrcy,
    
    @Semantics: { amount : {currencyCode: 'TransactionCurrency'} } 
    @DefaultAggregation: #SUM
    case DebitCreditCode 
        when 'S' then cast (AmountInTransactionCurrency as fis_dr_tsl)
        else cast (cast( '0' as abap.curr( 23,2)) as fis_dr_tsl)
    end as DebitAmountInTransCrcy,
    
    @Semantics: { amount : {currencyCode: 'TransactionCurrency'} } 
    @DefaultAggregation: #SUM
    case DebitCreditCode 
        when 'H' then cast (AmountInTransactionCurrency as fis_cr_tsl)
        else cast (cast( '0' as abap.curr( 23,2)) as fis_cr_tsl)
    end as CreditAmountInTransCrcy,

    @Semantics: { amount : {currencyCode: 'ControllingObjectCurrency'} }
    @DefaultAggregation: #SUM
    AmountInObjectCurrency,
    
    @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
    @DefaultAggregation: #SUM
    Quantity,
     
    BaseUnit,
    AdditionalQuantity1Unit,
    AdditionalQuantity2Unit,
    AdditionalQuantity3Unit,
    DebitCreditCode,
    FiscalPeriod,
    FiscalYearVariant,
    FiscalYearPeriod,
    PostingDate,
    DocumentDate,
    AccountingDocumentType,
    AccountingDocumentItem,
    AssignmentReference,
    PostingKey,
    TransactionTypeDetermination,
    AccountingDocCreatedByUser,
    LastChangeDateTime,
    ChartOfAccounts,
    AlternativeGLAccount,
    CountryChartOfAccounts,
    
    InvoiceReference,
    InvoiceReferenceFiscalYear,
    FollowOnDocumentType,
    InvoiceItemReference,
    ReferencePurchaseOrderCategory,
    PurchasingDocument,
    PurchasingDocumentItem,
    AccountAssignmentNumber,
    DocumentItemText,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    'SalesDocument'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'SalesDocument'       
    SalesOrder,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    'SalesDocumentItem'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'SalesDocumentItem'    
    SalesOrderItem,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    'Product'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'Product'     
    Material,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    'SoldProductGroup'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'SoldProductGroup'        
    MaterialGroup,
@Analytics.internalName: #LOCAL     
    Product,
@Analytics.internalName: #LOCAL     
    SoldProduct,
@Analytics.internalName: #LOCAL     
    SoldProductGroup,
    Plant,
    Supplier,
    Customer,
    CustomerGroup,
    FinancialAccountType,
//    SpecialGLIndicator,

    TaxCode,
    HouseBank,
    HouseBankAccount,
    IsOpenItemManaged,
    ClearingDate,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    'ClearingJournalEntry'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'ClearingJournalEntry'      
    ClearingAccountingDocument,
@Analytics.internalName: #LOCAL    
    I_JournalEntryItem.ClearingJournalEntry,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    'ClearingJournalEntryFiscalYear'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'ClearingJournalEntryFiscalYear'    
    ClearingDocFiscalYear,
@Analytics.internalName: #LOCAL    
    I_JournalEntryItem.ClearingJournalEntryFiscalYear,
    MasterFixedAsset,
    FixedAsset,
    AssetValueDate,
    AssetTransactionType,
    AssetAcctTransClassfctn,
    InvtrySpecialStockValnType_2 as InventorySpecialStockValnType,
    InventorySpecialStockType,
    InventoryValuationType,
    ValuationArea,
    ControllingObjectDebitType,
    QuantityIsIncomplete,
    OffsettingAccount,
    OffsettingAccountType,
    LineItemIsCompleted,
    PersonnelNumber,
    ControllingObjectClass,
    PartnerCompanyCode,
    PartnerControllingObjectClass,
    OriginCostCenter,
    OriginCostCtrActivityType,
    CostCtrActivityType,
    OrderID,
    OrderCategory,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    'WBSElementExternalID'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'WBSElementExternalID'        
    WBSElement,
@Analytics.internalName: #LOCAL     
    _WBSElementBasicData.WBSElementExternalID,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    'ProjectExternalID'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'ProjectExternalID'     
    Project,
@Analytics.internalName: #LOCAL     
    _ProjectBasicData.ProjectExternalID,
    OperatingConcern,
    PartnerCostCtrActivityType,
    PartnerOrder_2 as PartnerOrder,
    PartnerOrderCategory,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    'PartnerWBSElementExternalID'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'PartnerWBSElementExternalID'         
    PartnerWBSElement,
@Analytics.internalName: #LOCAL     
    _PartnerWBSElementBasicData.WBSElementExternalID as PartnerWBSElementExternalID,
@API.element.releaseState: #DEPRECATED
@API.element.successor:    'PartnerProjectExternalID'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'PartnerProjectExternalID'     
    PartnerProject,
@Analytics.internalName: #LOCAL     
    _PartnerProjectBasicData.ProjectExternalID as PartnerProjectExternalID,
    PartnerSalesDocument,
    PartnerSalesDocumentItem,
    BillingDocumentType,
    SalesOrganization,
    DistributionChannel,
    OrganizationDivision,
    SalesDocument,
@Analytics.internalName: #LOCAL     
    SalesDocumentItem,
    @Consumption.hidden: true
    ServiceDocument,
    @Consumption.hidden: true
    ServiceDocumentType,
    
    _CompanyCode,
    _ControllingArea,
    _GLAccountInChartOfAccounts,
    _ProfitCenterDetail,
    _Segment,
    _CostCenterDetail,
    _ChartOfAccounts,
    _AccountingDocumentType,
    _FinancialAccountType,
    _DebitCreditCode,
    _BusinessArea,
    _Ledger,
    _BalanceTransactionCurrency,
    _CompanyCodeCurrency,
    _TransactionCurrency,
    _FunctionalArea,
    _Material,
    _MaterialGroup,
    _CustomerGroup,
    _GLAccount,
    _Order,
    _SalesDocument,
    _Supplier,
    _GLAccountInCompanyCode,
    _FixedAsset,
    _Customer,
    _ProfitCenter,
    _CostCenter,
    _CurrentProfitCenter,
    _CurrentCostCenter,
    @Consumption.hidden: true
    _ServiceDocument,
    _PartnerOrder_2,

       // Just for Authorization Check!!! DO NOT USE!!! WILL BE DEPRECATED!!!

       cast( '' as brgru)  as GLAccountAuthorizationGroup,
       cast( '' as brgru)  as SupplierBasicAuthorizationGrp,
       cast( '' as brgru)  as CustomerBasicAuthorizationGrp,
       cast( '' as brgru)  as AcctgDocTypeAuthorizationGroup,
       cast( '' as aufart) as OrderType,
       cast( '' as auart)  as SalesOrderType,
       cast( '' as anlkl)  as AssetClass    

     
};                                                                                      
  
  
  
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRYITEM",
"I_PROJECTBASICDATA",
"I_WBSELEMENTBASICDATA"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTTYPE",
"I_BUSINESSAREA",
"I_CHARTOFACCOUNTS",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_COSTCENTERDETAIL",
"I_CURRENCY",
"I_CUSTOMER",
"I_CUSTOMERGROUP",
"I_DEBITCREDITCODE",
"I_FINANCIALACCOUNTTYPE",
"I_FIXEDASSET",
"I_FUNCTIONALAREA",
"I_GLACCOUNT",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_GLACCOUNTINCOMPANYCODE",
"I_LEDGER",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_ORDER",
"I_PROFITCENTER",
"I_PROFITCENTERDETAIL",
"I_SALESDOCUMENT",
"I_SEGMENT",
"I_SRVCDOCBYDOCUMENTTYPE",
"I_SUPPLIER"
],
"BASE":
[
"I_JOURNALENTRYITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/