I_MaintenanceRevision

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IMAINTREVISION'
@AccessControl.authorizationCheck: #CHECK
-- @Analytics: { dataCategory: #DIMENSION }
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maintenance Revision'
@ObjectModel.representativeKey: 'MaintenanceRevision'
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@VDM.viewType: #BASIC


define view I_MaintenanceRevision
  as select from t352r
  association [0..1] to I_Plant                    as _MaintenancePlanningPlant on  $projection.MaintenancePlanningPlant = _MaintenancePlanningPlant.Plant
  association [0..1] to I_User                     as _CreatedByUser            on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                     as _LastChangedByUser        on  $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_Indicator                as _IsCompleted              on  _IsCompleted.IndicatorValue = $projection.RevisionIsCompleted
  association [0..1] to I_MaintenancePlanPlant     as _MaintenancePlanPlant     on  $projection.MaintenancePlanningPlant = _MaintenancePlanPlant.MaintenancePlanningPlant
  association [0..1] to nriv                       as _NumberRangeIntervals     on  _NumberRangeIntervals.nrrangenr = '01'
                                                                                and _NumberRangeIntervals.object    = 'WPS_REV'
                                                                                and _NumberRangeIntervals.subobject = $projection.MaintenancePlanningPlant
  association [0..1] to diwps_revty_t              as _RevisionType             on  $projection.MaintenanceEventType =  _RevisionType.revty                                                                            
                                                                                

{
      // Key

      @ObjectModel.foreignKey.association: '_MaintenancePlanPlant'
  key t352r.iwerk                                                                                                      as MaintenancePlanningPlant,
      @ObjectModel.text.element:  [ 'MaintenanceRevisionDesc' ]
  key t352r.revnr                                                                                                      as MaintenanceRevision,

      // Text

      @Semantics.text: true
      t352r.revtx                                                                                                      as MaintenanceRevisionDesc,

      @Semantics.text: true
      t352r.revty                                                                                                      as MaintenanceEventType,

      // Revision

      cast( t352r.revbd as eam_revision_start_date preserving type )                                                   as RevisionStartDate,
      cast( case when t352r.revbz = '' then '000000' else t352r.revbz end as eam_revision_start_time preserving type ) as RevisionStartTime,
      cast( t352r.reved as eam_revision_end_date preserving type )                                                     as RevisionEndDate,
      cast( case when t352r.revez = '' then '000000' else t352r.revez end as eam_revision_end_time preserving type )   as RevisionEndTime,

      @EndUserText.label: 'Is Completed'
      @EndUserText.quickInfo: 'Indicator: Revision is Completed'
      @ObjectModel.foreignKey.association: '_IsCompleted'
      cast( t352r.revab as xfeld )                                                                                     as RevisionIsCompleted,

      /*
            t352r.pm_objty,
            t352r.gewrk,
            t352r.equnr,
            t352r.tplnr,
            t352r.pspel,
            t352r.aufnr,
      */

      // Admin

      @Semantics.businessDate.createdAt: true
      t352r.erdat                                                                                                      as CreationDate,
      t352r.ernam                                                                                                      as CreatedByUser,
      @Semantics.businessDate.lastChangedAt: true
      t352r.aedat                                                                                                      as LastChangeDate,
      t352r.aenam                                                                                                      as LastChangedByUser,
      _NumberRangeIntervals.externind                                                                                  as IsExternalNumberRange,
      _RevisionType.wps_control                                                                                        as MaintenanceEventTypeCategory,
      /*
            t352r.objnr,
            t352r.revty,
            t352r.objid,
            t352r.vaplz,
            t352r.vawrk,
            t352r.extappl,
            t352r.extref
      */

      // Associations

      _MaintenancePlanningPlant,
      _CreatedByUser,
      _LastChangedByUser,
      @Consumption.filter.hidden: true
      _IsCompleted,
      _MaintenancePlanPlant
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DIWPS_REVTY_T",
"NRIV",
"T352R"
],
"ASSOCIATED":
[
"I_INDICATOR",
"I_MAINTENANCEPLANPLANT",
"I_PLANT",
"I_USER",
"DIWPS_REVTY_T",
"NRIV"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/