I_MaintenancePlanTP

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'IMAINTPLANTP'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maintenance Plan (Transactional Processing)'
@ObjectModel: {
   compositionRoot:                true,
   createEnabled: false,
   updateEnabled: false,
   deleteEnabled: false,
   draftEnabled: false,
   representativeKey: [ 'MaintenancePlan' ],
   semanticKey:  [ 'MaintenancePlan'],
   transactionalProcessingEnabled: true,
   usageType.serviceQuality: #B,
   usageType.sizeCategory: #S,
   usageType.dataClass: #MASTER,
   writeActivePersistence:         'IMAINTPLANTP'
}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.sapObjectNodeType.name: 'MaintenancePlan'

define view I_MaintenancePlanTP
  as select from I_MaintenancePlan
  association [0..1] to I_MaintenanceSingleCycleTP as _MaintenanceSingleCycleTP on _MaintenanceSingleCycleTP.MaintenancePlan = $projection.MaintenancePlan
  association [0..*] to I_MaintPlanMaintCallTP     as _MaintenanceCallTP        on _MaintenanceCallTP.MaintenancePlan = $projection.MaintenancePlan
 
  -- Extensions, do not expose as association:
  association [0..1] to E_MaintenancePlan          as _MaintenancePlanExtension on $projection.MaintenancePlan = _MaintenancePlanExtension.MaintenancePlan
{
   
      //I_MaintenancePlan

      
  key MaintenancePlan,
      MaintenancePlanDesc,
      CreationDate,
      CreatedByUser,
      LastChangeDate,
      LastChangedByUser,

      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      MaintenanceStrategy,
      SchedulingDuration,
      SchedulingDurationUnit,
      Equipment,
      FunctionalLocation,
      Customer,
      NumberOfMaintenanceItems,
      Language,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      CycleModificationRatio,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      MaintPlanSchedgIndicator,
      CallHorizonPercent,
      CallHorizonInDays,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast( '' as fti_mnomzins)                            as CallHorizonValue,
      MaintenanceCallHorizonCalcType,
      AuthorizationGroup,
      MaintenancePlanInternalID,
      MaintenanceCall,
      MaintenancePlanCategory,
      MaintPlanFreeDefinedAttrib,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BasicStartDate,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      SchedulingStartDate,
      SchedulingStartTime,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      MaintSchedulingStartCounter,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast(MaintPlanStartBufferQuantity as fti_mnomzins)   as MaintPlanStartBufferQuantity,
      MaintPlanStartBufferUnit,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      FactoryCalendar,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast(LateCompletionShiftFactor as fti_mnomzins)      as LateCompletionShiftFactor,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast(LateCompletionTolerancePercent as fti_mnomzins) as LateCompletionTolerancePercent,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast(EarlyCompletionShiftFactor as fti_mnomzins)     as EarlyCompletionShiftFactor,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast(EarlyCompletionTolerancePct as fti_mnomzins)    as EarlyCompletionTolerancePct,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      PrdcssrCallObjCompltnIsRqd,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      LogicalOperator,
      MaintPlanIsLockedAgainstCalls,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      SchedulingEndDate,
      MaintSchedulingEndCounter,

      /* Associations */
      _StatusObjectActiveStatus,
      _Customer,
      _Equipment,
      _FunctionalLocationLabel,
      _MaintenanceItem,
      _MaintenancePlanCatParam,
      _MaintenanceStrategy,
      _MaintenanceCycle,
      _FactoryCalendar,
      _SchedulingIndicator,
      _MaintPlanCallHistory,
      _SchedulingDurationUnit,
      _LogicalOperator,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _MaintenanceSingleCycleTP,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _MaintenanceCallTP,
      _AuthorizationGroup,
      _MaintCallConfIsRequired,
      _MaintenancePlanSortField,
      _MaintPlanStartBufferUnit
 
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTENANCEPLAN"
],
"ASSOCIATED":
[
"E_MAINTENANCEPLAN",
"I_CUSTOMER",
"I_EQUIPMENT",
"I_FACTORYCALENDAR",
"I_FUNCTIONALLOCATIONLABEL",
"I_INDICATOR",
"I_MAINTENANCECYCLE",
"I_MAINTENANCEITEM",
"I_MAINTENANCEPLANCATPARAM",
"I_MAINTENANCEPLANSORTFIELD",
"I_MAINTENANCESINGLECYCLETP",
"I_MAINTENANCESTRATEGY",
"I_MAINTPLANCALLHISTORY",
"I_MAINTPLANLGCLOPTR",
"I_MAINTPLANMAINTCALLTP",
"I_MAINTPLANSCHEDGIND",
"I_STATUSOBJECTACTIVESTATUS",
"I_TECHOBJAUTHZNGRP",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_MAINTENANCEPLAN"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/