I_MaintenancePlanCycle

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IMAINTPLANCYCLE'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maintenance Plan Cycle'
@ObjectModel: {
  representativeKey: 'MaintenancePlanCycle',
  semanticKey:  [ 'MaintenancePlan','MaintenancePlanCycle' ],
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #B,
    sizeCategory: #M
  }
}

@VDM.viewType: #BASIC
@AbapCatalog.preserveKey:true

define view I_MaintenancePlanCycle
  as select from mmpt
  
  association [1..1] to I_MaintenancePlanBasic  as _MaintenancePlan on _MaintenancePlan.MaintenancePlan = $projection.MaintenancePlan
  association [0..1] to I_MeasuringPoint        as _MeasuringPoint  on _MeasuringPoint.MeasuringPoint   = $projection.MeasuringPoint
  association [0..1] to I_UnitOfMeasure         as _UnitOfMeasure   on _UnitOfMeasure.UnitOfMeasure     = $projection.MaintPlanCycRcrrcIntervalUnit
  association [0..1] to I_Language              as _Language        on _Language.Language               = $projection.Language
{
      @ObjectModel.foreignKey.association: '_MaintenancePlan'  
      key mmpt.warpl    as MaintenancePlan,
  
      key mmpt.nummer   as MaintenancePlanCycle,

      mmpt.operator     as ComparisonOperator,

      @Semantics.quantity.unitOfMeasure: 'MaintPlanCycRcrrcIntervalUnit'
      mmpt.zykl1        as MaintPlanCycRcrrcIntervalQty,

      @ObjectModel.foreignKey.association: '_UnitOfMeasure'
      @Semantics.unitOfMeasure: true
      mmpt.zeieh        as MaintPlanCycRcrrcIntervalUnit,

      mmpt.pak_text     as MaintPlanCycleDesc,

      @ObjectModel.foreignKey.association: '_Language'
      mmpt.langu        as Language,

      @ObjectModel.foreignKey.association: '_MeasuringPoint'
      mmpt.point        as MeasuringPoint,

      mmpt.offset       as MaintPlanCycleStartOffsetValue,

      mmpt.nzaeh        as MaintCycleNextPlndCntrRdng,

      mmpt.inaktiv      as MaintenancePlanCycleIsInactive,

      mmpt.cycleseqind  as CycleSetSequence,

      mmpt.setrepeatind as CycleSetSequenceRepeatFactor,

      /* Associations */
      _MaintenancePlan,
      _MeasuringPoint,
      _Language,
      _UnitOfMeasure

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MMPT"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_MAINTENANCEPLANBASIC",
"I_MEASURINGPOINT",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/