I_MaintenanceOrderObjectList

@AbapCatalog.sqlViewName: 'IMTORDOBJ'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_LocationAccountAssignment']
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'CDS view to retrieve object list of a maintenance order'
@ObjectModel.representativeKey: 'MaintenanceOrderObjectListItem'
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #B,
        sizeCategory: #XL
    }
}
@VDM.viewType: #BASIC
@AbapCatalog.preserveKey:true

define view I_MaintenanceOrderObjectList
  as select from objk
  association [0..1] to I_MaintenanceItem           as _MaintenanceItem           on _MaintenanceItem.MaintenanceItemObjectList = $projection.MaintenanceOrderObjectList
  association [0..1] to I_LocationAccountAssignment as _LocationAccountAssignment on _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr = $projection.MaintObjectLocAcctAssgmtNmbr
  association [0..1] to I_PMNotifMaintenanceData    as _PMNotifMaintenanceData    on _PMNotifMaintenanceData.MaintenanceNotification = $projection.MaintenanceNotification
  association [0..1] to I_MaintenanceNotification   as _MaintenanceNotification   on _MaintenanceNotification.MaintenanceNotification = $projection.MaintenanceNotification
  association [0..1] to I_Equipment                 as _Equipment                 on _Equipment.Equipment = $projection.Equipment
  association [0..1] to I_FunctionalLocation        as _FunctionalLocation        on _FunctionalLocation.FunctionalLocation = $projection.FunctionalLocation
  association [0..1] to I_Material                  as _Assembly                  on _Assembly.Material = $projection.Assembly
  association [0..1] to I_Material                  as _Material                  on _Material.Material = $projection.Material
{
  key objk.obknr                                                                                                                       as MaintenanceOrderObjectList,

  key objk.obzae                                                                                                                       as MaintenanceOrderObjectListItem,

      @ObjectModel.foreignKey.association: '_Equipment' 
      coalesce( _PMNotifMaintenanceData.Equipment, objk.equnr )                                                                        as Equipment,

      @ObjectModel.foreignKey.association: '_FunctionalLocation'
      coalesce( _LocationAccountAssignment.FunctionalLocation, _PMNotifMaintenanceData._LocationAccountAssignment.FunctionalLocation ) as FunctionalLocation,

      @Consumption.valueHelpDefinition: [{
        entity: {
            name: 'I_MaterialStdVH',
            element: 'Material'
        }
      }]
      @ObjectModel.foreignKey.association: '_Assembly'
      coalesce( _PMNotifMaintenanceData.Assembly, objk.bautl )                                                                         as Assembly,

      objk.sernr                                                                                                                       as SerialNumber,

      @Consumption.valueHelpDefinition: [{
        entity: {
            name: 'I_MaterialStdVH',
            element: 'Material'
        }
      }]
      @ObjectModel.foreignKey.association: '_Material'
      objk.matnr                                                                                                                       as Material,

      @ObjectModel.foreignKey.association: '_MaintenanceNotification'
      objk.ihnum                                                                                                                       as MaintenanceNotification,

      @ObjectModel.foreignKey.association: '_LocationAccountAssignment'
      objk.iloan                                                                                                                       as MaintObjectLocAcctAssgmtNmbr,

      //objk.sortf                                                                                                                     as SortField,


      objk.bearb                                                                                                                       as MaintObjListEntryIsProcessed,
      
      objk.product                                                                                                                     as Product,

      // Associations

      _MaintenanceItem,
      _Assembly,
      _Equipment,
      _FunctionalLocation,
      _LocationAccountAssignment,
      _MaintenanceNotification,
      _Material
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOCATIONACCOUNTASSIGNMENT",
"I_PMNOTIFMAINTENANCEDATA",
"OBJK"
],
"ASSOCIATED":
[
"I_EQUIPMENT",
"I_FUNCTIONALLOCATION",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCEITEM",
"I_MAINTENANCENOTIFICATION",
"I_MATERIAL",
"I_PMNOTIFMAINTENANCEDATA"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/