I_MaintenanceOrderConfirmation

@AbapCatalog.sqlViewName: 'IMAINTORDCONF'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Order Confirmation'
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'MaintOrderConfCntrValue'
@ObjectModel.semanticKey:  [ 'MaintOrderConf'  , 'MaintOrderConfCntrValue'   ]

@ObjectModel: {
   usageType.serviceQuality: #C,
   usageType.sizeCategory: #XL,
   usageType.dataClass: #MIXED,
   compositionRoot,
   createEnabled:   false,
   deleteEnabled:   false,
   updateEnabled:   false
}
define view I_MaintenanceOrderConfirmation
  as select from P_MaintenanceOrderConfirmation
  association [0..*] to I_MaintOrderConfGoodsMovement as _MaintOrderConfGoodsMovement  on  _MaintOrderConfGoodsMovement.MaintOrderConf          = $projection.MaintOrderConf
                                                                                       and _MaintOrderConfGoodsMovement.MaintOrderConfCntrValue = $projection.MaintOrderConfCntrValue
  association [0..1] to I_WorkCenter                  as _ActualWorkCenter             on  $projection.WorkCenterInternalID     = _ActualWorkCenter.WorkCenterInternalID
                                                                                       and _ActualWorkCenter.WorkCenterTypeCode = 'A'
  association [0..1] to I_MaintenanceOrder            as _MaintenanceOrder             on  _MaintenanceOrder.MaintenanceOrder = $projection.MaintenanceOrder
  association [0..1] to I_ConfirmationGroup           as _ConfirmationGroup            on  _ConfirmationGroup.ConfirmationGroup = $projection.MaintOrderConf
  association [0..1] to I_User                        as _EnteredByUser                on  _EnteredByUser.UserID = $projection.EnteredByUser
  association [0..1] to I_User                        as _LastChangeByUser             on  _LastChangeByUser.UserID = $projection.LastChangedByUser
  association [0..1] to I_Indicator                   as _IsReversed                   on  _IsReversed.IndicatorValue = $projection.IsReversed
  association [0..1] to I_Indicator                   as _IsReversal                   on  _IsReversal.IndicatorValue = $projection.IsReversal
  association [0..1] to I_Indicator                   as _IsFinalConfirmation          on  _IsFinalConfirmation.IndicatorValue = $projection.IsFinalConfirmation
  association [0..1] to I_Indicator                   as _OpenReservationsIsCleared    on  _OpenReservationsIsCleared.IndicatorValue = $projection.OpenReservationsIsCleared
  association [0..1] to I_Indicator                   as _NoFurtherWorkQuantityIsExpd  on  _NoFurtherWorkQuantityIsExpd.IndicatorValue = $projection.NoFurtherWorkQuantityIsExpd
  association [0..1] to I_Indicator                   as _LongTextExists               on  _LongTextExists.IndicatorValue = $projection.LongTextExists
  association [0..1] to I_VarianceReason              as _VarianceReason               on  $projection.Plant              = _VarianceReason.Plant
                                                                                       and $projection.VarianceReasonCode = _VarianceReason.VarianceReasonCode
  association [0..1] to I_WorkforcePerson             as _PersonnelName                on  $projection.PersonnelNumber = _PersonnelName.PersonExternalID
  association [0..1] to I_PersonWorkAgreement_1       as _PersonResponsible            on  $projection.PersonnelNumber = _PersonResponsible.PersonWorkAgreement
  association [0..1] to I_MaintenanceOrderOperation   as _MaintenanceOrderOperation    on  _MaintenanceOrderOperation.MaintenanceOrder           = $projection.MaintenanceOrder
                                                                                       and _MaintenanceOrderOperation.MaintOrderOperationCounter = $projection.MaintOrderOperationCounter
  association [0..1] to I_UnitOfMeasure               as _ActualWorkExtQuantityUnit    on  _ActualWorkExtQuantityUnit.UnitOfMeasure = $projection.ActualWorkExternalQuantityUnit
  association [0..1] to I_UnitOfMeasure               as _RemainingWorkExtQuantityUnit on  _RemainingWorkExtQuantityUnit.UnitOfMeasure = $projection.RemainingWorkExtQuantityUnit
  association [0..1] to I_OrderConfLongText           as _OrderConfLongText            on  _OrderConfLongText.ConfirmationGroup = $projection.MaintOrderConf
                                                                                       and _OrderConfLongText.OrderConfirmation = $projection.MaintOrderConfCntrValue
{
      @ObjectModel.foreignKey.association: '_ConfirmationGroup'
  key P_MaintenanceOrderConfirmation.MaintOrderConf,
  key P_MaintenanceOrderConfirmation.MaintOrderConfCntrValue,
      P_MaintenanceOrderConfirmation.MaintOrderConfirmationEntryDte,
      P_MaintenanceOrderConfirmation.MaintOrderOperationCounter,
      P_MaintenanceOrderConfirmation.EnteredByUser,
      P_MaintenanceOrderConfirmation.LastChangeDate,
      P_MaintenanceOrderConfirmation.LastChangedByUser,
      P_MaintenanceOrderConfirmation.PostingDate,
      P_MaintenanceOrderConfirmation.WorkCenterInternalID,
      P_MaintenanceOrderConfirmation.ConfirmationText,
      P_MaintenanceOrderConfirmation.Language,
      @ObjectModel.foreignKey.association: '_LongTextExists'
      P_MaintenanceOrderConfirmation.LongTextExists,
      @Semantics.quantity.unitOfMeasure: 'ActualWorkQuantityUnit'
      P_MaintenanceOrderConfirmation.ActualWorkQuantity,
      P_MaintenanceOrderConfirmation.ActualWorkQuantityUnit,
      P_MaintenanceOrderConfirmation.ActivityType,
      @Semantics.quantity.unitOfMeasure: 'ActualDurationUnit'
      P_MaintenanceOrderConfirmation.ActualDuration,
      P_MaintenanceOrderConfirmation.ActualDurationUnit,
      P_MaintenanceOrderConfirmation.EmployeeWageType,
      P_MaintenanceOrderConfirmation.ConfirmationYieldQuantity,
      P_MaintenanceOrderConfirmation.ConfirmationScrapQuantity,
      P_MaintenanceOrderConfirmation.ConfirmationUnit,
      P_MaintenanceOrderConfirmation.VarianceReasonCode,
      @ObjectModel.foreignKey.association: '_PersonResponsible'
      P_MaintenanceOrderConfirmation.PersonnelNumber,
      P_MaintenanceOrderConfirmation.OperationConfirmedStartDate,
      P_MaintenanceOrderConfirmation.OperationConfirmedStartTime,
      P_MaintenanceOrderConfirmation.MaintOrderRoutingNumber,
      @Semantics.dateTime: true
      dats_tims_to_tstmp( P_MaintenanceOrderConfirmation.OperationConfirmedStartDate,
                          P_MaintenanceOrderConfirmation.OperationConfirmedStartTime,
                          AddressTimeZone,
                          $session.client,
                         'NULL' )                                                                      as MaintOrdOpWrkExecStartDateTime,
      //  cast( cast( concat(P_MaintenanceOrderConfirmation.OperationConfirmedStartDate, P_MaintenanceOrderConfirmation.OperationConfirmedStartTime) as abap.numc( 15 )) as tzntstmpl) as OperationConfirmedStart,

      P_MaintenanceOrderConfirmation.OperationConfirmedEndDate,
      P_MaintenanceOrderConfirmation.OperationConfirmedEndTime,
      @Semantics.dateTime: true
      dats_tims_to_tstmp( P_MaintenanceOrderConfirmation.OperationConfirmedEndDate,
                          P_MaintenanceOrderConfirmation.OperationConfirmedEndTime,
                          AddressTimeZone,
                          $session.client,
                         'NULL' )                                                                      as MaintOrdOpWrkExecEndDateTime,

      //  cast( cast( concat(P_MaintenanceOrderConfirmation.OperationConfirmedEndDate, P_MaintenanceOrderConfirmation.OperationConfirmedEndTime) as abap.numc( 15 )) as tzntstmpl)     as OperationConfirmedEnd,

      //  dats_tims_to_tstmp( P_MaintenanceOrderConfirmation.OperationConfirmedEndDate, P_MaintenanceOrderConfirmation.OperationConfirmedEndTime, abap_system_timezone($session.client, 'NULL'), $session.client, 'NULL') as OperationConfirmedEnd,

      P_MaintenanceOrderConfirmation.ActyConfFcstdEndDate,
      P_MaintenanceOrderConfirmation.ActyConfFcstdEndTime,

      @Semantics.dateTime: true
      dats_tims_to_tstmp( P_MaintenanceOrderConfirmation.ActyConfFcstdEndDate,
                          P_MaintenanceOrderConfirmation.ActyConfFcstdEndTime,
                          AddressTimeZone,
                          $session.client,
                         'NULL' )                                                                      as MaintOrdOpFcstdEndDateTime,

      //  cast( cast( concat(P_MaintenanceOrderConfirmation.ActyConfFcstdEndDate, P_MaintenanceOrderConfirmation.ActyConfFcstdEndTime) as abap.numc( 15 )) as tzntstmpl)               as ActyConfFcstdEnd,

      @ObjectModel.foreignKey.association: '_IsFinalConfirmation'
      P_MaintenanceOrderConfirmation.IsFinalConfirmation,
      @ObjectModel.foreignKey.association: '_OpenReservationsIsCleared'
      P_MaintenanceOrderConfirmation.OpenReservationsIsCleared,
      P_MaintenanceOrderConfirmation.MaintenanceOrder,
      P_MaintenanceOrderConfirmation.MaintenanceOrderOperation,
      P_MaintenanceOrderConfirmation.MaintenanceOrderSubOperation,
      @Semantics.quantity.unitOfMeasure: 'RemainingWorkQuantityUnit'
      P_MaintenanceOrderConfirmation.RemainingWorkQuantity,
      P_MaintenanceOrderConfirmation.RemainingWorkQuantityUnit,
      @ObjectModel.foreignKey.association: '_NoFurtherWorkQuantityIsExpd'
      P_MaintenanceOrderConfirmation.NoFurtherWorkQuantityIsExpd,
      @ObjectModel.foreignKey.association: '_IsReversed'
      P_MaintenanceOrderConfirmation.IsReversed,
      @ObjectModel.foreignKey.association: '_IsReversal'
      P_MaintenanceOrderConfirmation.IsReversal,
      P_MaintenanceOrderConfirmation.CancldMaintOrderConfCntrValue,
      P_MaintenanceOrderConfirmation.ConfirmationReworkQuantity,
      P_MaintenanceOrderConfirmation.MaintOrderConfirmationEntryTme,
      P_MaintenanceOrderConfirmation.AccountingIndicatorCode,
      P_MaintenanceOrderConfirmation.EnteredByExternalUser,
      P_MaintenanceOrderConfirmation.ConfirmationExternalEntryDate,
      P_MaintenanceOrderConfirmation.ConfirmationExternalEntryTime,
      @Semantics.unitOfMeasure
      @ObjectModel.foreignKey.association: '_ActualWorkExtQuantityUnit'
      ActualWorkExternalQuantityUnit,
      @Semantics.unitOfMeasure
      @ObjectModel.foreignKey.association: '_RemainingWorkExtQuantityUnit'
      RemainingWorkExtQuantityUnit,

      P_MaintenanceOrderConfirmation.Plant,

      P_MaintenanceOrderConfirmation._Plant.FactoryCalendar,
      P_MaintenanceOrderConfirmation.MaintOrderOperationInternalID,
      P_MaintenanceOrderConfirmation.CapacityInternalID,
      P_MaintenanceOrderConfirmation.EmployeeWageGroup,
      P_MaintenanceOrderConfirmation.NmbrOfMaintTechnicianCapSplits,
      P_MaintenanceOrderConfirmation.MaterialDocument,

      @Semantics.timeZone: true
      AddressTimeZone,

      @Semantics.timeZone: true
      cast( abap_user_timezone(   $session.user,$session.client,'NULL' )   as tzonso preserving type ) as UserEnteredTimeZone,

      @Semantics.timeZone: true
      _Plant._OrganizationAddress[1:AddressRepresentationCode = ''].AddressTimeZone                    as PlantTimeZone,

      /* Associations */
      _Plant,
      _MaintOrderConfGoodsMovement,
      _Language,
      _ActualWorkCenter,
      _MaintenanceOrder,
      _MaintenanceOrderOperation,
      _ConfirmationGroup,
      _EnteredByUser,
      _LastChangeByUser,
      _PersonnelName,
      _LongTextExists,
      _IsReversed,
      _IsReversal,
      _IsFinalConfirmation,
      _OpenReservationsIsCleared,
      _NoFurtherWorkQuantityIsExpd,
      _VarianceReason,
      _ActualWorkExtQuantityUnit,
      _RemainingWorkExtQuantityUnit,
      _PersonResponsible,
      _OrderConfLongText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ORGANIZATIONADDRESS",
"I_PLANT",
"P_MAINTENANCEORDERCONFIRMATION"
],
"ASSOCIATED":
[
"I_CONFIRMATIONGROUP",
"I_INDICATOR",
"I_LANGUAGE",
"I_MAINTENANCEORDER",
"I_MAINTENANCEORDEROPERATION",
"I_MAINTORDERCONFGOODSMOVEMENT",
"I_ORDERCONFLONGTEXT",
"I_PERSONWORKAGREEMENT_1",
"I_PLANT",
"I_UNITOFMEASURE",
"I_USER",
"I_VARIANCEREASON",
"I_WORKCENTER",
"I_WORKFORCEPERSON"
],
"BASE":
[
"P_MAINTENANCEORDERCONFIRMATION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/