I_MaintenanceObjectLink

@AbapCatalog.sqlViewName: 'IMAINTOBJLINK'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Object Link'
@Search.searchable: true
@VDM.viewType: #BASIC

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.representativeKey: 'ObjectLink'
@AccessControl.privilegedAssociations:['_CreatedByUser','_LastChangedByUser']
@Metadata.ignorePropagatedAnnotations: true
define view I_MaintenanceObjectLink
  as select from inet
  association [0..1] to I_Language                  as _Language                   on _Language.Language = $projection.Language
  association [0..1] to I_Product                   as _Product                    on $projection.Product = _Product.Product
  association [0..1] to I_User                      as _CreatedByUser              on _CreatedByUser.UserID = $projection.CreatedByUser
  association [0..1] to I_User                      as _LastChangedByUser          on _LastChangedByUser.UserID = $projection.LastChangedByUser
  association [0..1] to I_Equipment                 as _LinkFromEquipment          on $projection.ObjectLinkFromEquipment = _LinkFromEquipment.Equipment
  association [0..1] to I_Equipment                 as _LinkToEquipment            on $projection.ObjectLinkToEquipment = _LinkToEquipment.Equipment
  association [0..1] to I_FunctionalLocation        as _LinkFromFunctionalLocation on $projection.ObjLinkFromFunctionalLocation = _LinkFromFunctionalLocation.FunctionalLocation
  association [0..1] to I_FunctionalLocation        as _LinkToFunctionalLocation   on $projection.ObjectLinkToFunctionalLocation = _LinkToFunctionalLocation.FunctionalLocation
  association [0..*] to I_MaintenanceObjectLinkText as _LinkText                   on _LinkText.ObjectLink = $projection.ObjectLink
{
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @ObjectModel.text.association:'_LinkText'
  key kante                                                                                                             as  ObjectLink,
      @ObjectModel.foreignKey.association: '_Language'
      mlang                                                                                                             as  Language,
      netid                                                                                                             as  ObjectNetwork,
      kantyp                                                                                                            as  ObjectLinkIsEquipOrFuncnlLoc,
      @ObjectModel.foreignKey.association:'_LinkFromFunctionalLocation'
      tpvon                                                                                                             as  ObjLinkFromFunctionalLocation,
      @ObjectModel.foreignKey.association: '_LinkFromEquipment'
      eqvon                                                                                                             as  ObjectLinkFromEquipment,
      @ObjectModel.foreignKey.association:'_LinkToFunctionalLocation'
      tpnach                                                                                                            as  ObjectLinkToFunctionalLocation,
      @ObjectModel.foreignKey.association: '_LinkToEquipment'
      eqnach                                                                                                            as  ObjectLinkToEquipment,
      lfdknr                                                                                                            as  NumberOfParallelLinks,
      @Semantics.businessDate.from: true
      datva                                                                                                             as  ObjectLinkValidityStartDate,
      zeitva                                                                                                            as  ObjectLinkValidityStartTime,
      @Semantics.businessDate.to: true
      datvb                                                                                                             as  ObjectLinkValidityEndDate,
      zeitvb                                                                                                            as  ObjectLinkValidityEndTime,
      status                                                                                                            as  MaintObjectInternalID,
      tpkant                                                                                                            as  ObjectLinkIsFunctionalLocation,
      eqkant                                                                                                            as  ObjectLinkIsEquipment,
      mediu                                                                                                             as  ObjectLinkMedium,
      bezarp                                                                                                            as  MaintObjLinkPossibleRelshpType,
      bezarl                                                                                                            as  MaintObjLinkUsedRelshpType,
      @Semantics.systemDate.createdAt: true
      erdat                                                                                                             as  CreationDate,
      @Semantics.systemDate.lastChangedAt: true
      aedat                                                                                                             as  LastChangeDate,
      @Semantics.user.createdBy: true
      ernam                                                                                                             as  CreatedByUser,
      @Semantics.user.lastChangedBy: true
      aenam                                                                                                             as  LastChangedByUser,
      begru                                                                                                             as  AuthorizationGroup,
      lvorm                                                                                                             as  ObjectLinkIsMarkedForDeletion,
      netyp                                                                                                             as  ObjectLinkCategory,
      @ObjectModel.foreignKey.association: '_Product'
      matnr                                                                                                             as  Product,
      // Propagate associations

      _Language,
      _Product,
      _CreatedByUser,
      _LastChangedByUser,
      _LinkFromEquipment,
      _LinkToEquipment,
      _LinkFromFunctionalLocation,
      _LinkToFunctionalLocation,
      _LinkText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"INET"
],
"ASSOCIATED":
[
"I_EQUIPMENT",
"I_FUNCTIONALLOCATION",
"I_LANGUAGE",
"I_MAINTENANCEOBJECTLINKTEXT",
"I_PRODUCT",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/