I_MaintenanceItemTP

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:           true
@AbapCatalog.sqlViewName: 'IMAINTITEMTP'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maintenance Item (Transactional Processing)'
@ObjectModel: {
    compositionRoot: true,
    representativeKey: [ 'MaintenanceItem' ],
    semanticKey:  [ 'MaintenanceItem'],
    usageType: {
        dataClass: #MASTER,
        serviceQuality: #D,
        sizeCategory: #L
    },
    transactionalProcessingEnabled: true,
    writeActivePersistence: 'IMAINTITEMTP'
}
@VDM: {
    lifecycle.contract.type: #SAP_INTERNAL_API,
    viewType: #TRANSACTIONAL
}
@ObjectModel.sapObjectNodeType.name: 'MaintenanceItem'

define view I_MaintenanceItemTP
  as select from I_MaintenanceItem

  -- Extensions, do not expose as association:
  association [0..1] to E_MaintenanceItemBasic as _MaintenanceItemExtension on _MaintenanceItemExtension.MaintenanceItem = $projection.MaintenanceItem

  association [0..1] to I_MaintTaskListForKeyDate as _MaintTaskListForKeyDate  on  $projection.TaskListType         = _MaintTaskListForKeyDate.TaskListType
                                                                                   and $projection.TaskListGroup        = _MaintTaskListForKeyDate.TaskListGroup
                                                                                   and $projection.TaskListGroupCounter = _MaintTaskListForKeyDate.TaskListGroupCounter
{

  key MaintenanceItem,
      MaintObjectLocAcctAssgmtNmbr,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      MaintenancePlannerGroup,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      MaintenancePlanningPlant,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      case ltrim( _MaintTaskListForKeyDate(P_KeyDate:$session.system_date).TaskListGroup, '0')
           when '' then case ltrim( _MaintTaskListForKeyDate(P_KeyDate:$session.system_date).TaskListGroupCounter, '0')
                           when '' then concat( _MaintTaskListForKeyDate(P_KeyDate:$session.system_date).TaskListType, '/0/0' )
                           else concat( concat( _MaintTaskListForKeyDate(P_KeyDate:$session.system_date).TaskListType, '/0/' ), ltrim( _MaintTaskListForKeyDate(P_KeyDate:$session.system_date).TaskListGroupCounter, '0') )
                        end
           else case ltrim( TaskListGroupCounter, '0')
                   when '' then concat( concat( concat( _MaintTaskListForKeyDate(P_KeyDate:$session.system_date).TaskListType, '/' ), ltrim( _MaintTaskListForKeyDate(P_KeyDate:$session.system_date).TaskListGroup, '0') ), '/0' )
                   else concat( concat( concat( concat( _MaintTaskListForKeyDate(P_KeyDate:$session.system_date).TaskListType, '/' ), ltrim( _MaintTaskListForKeyDate(P_KeyDate:$session.system_date).TaskListGroup, '0') ), '/' ), ltrim( _MaintTaskListForKeyDate(P_KeyDate:$session.system_date).TaskListGroupCounter, '0') )
                end
      end                        as TaskList,
      TaskListType,
      TaskListGroup,
      TaskListGroupCounter,
      Equipment,
      FunctionalLocation,
      MaintenanceItemDescription,
      MaintenancePlan,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      MaintenanceStrategy,
      MaintenancePlanCategory,
      NotificationType,
      MaintenanceNotification,
      MaintPriorityType,
      MaintPriority,
      MaintenanceOrder,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      BusinessArea,
      MainWorkCenterInternalID,
      WorkCenterTypeCode,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      Assembly,
      CreationDate,
      CreatedByUser,
      LastChangeDate,
      LastChangedByUser,
      MaintenancePlanItemPosition,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      MaintenanceActivityType,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      MaintenanceOrderType,
      SerialNumber,
      Material,
      MaintenanceItemObjectList,
      ImmediateReleaseIsBlocked,
      OperationSystemCondition,
      NumberOfTaskListExecutions,
      ObjectInternalID,
      SalesDocument,
      PurchaseOrder,
      PurchaseOrderItem,
      SettlementOrder,
      LastChangeDateTime,
      CycleSetSequence,
      ReferenceElement,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      ServiceDocumentType,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      ServiceContract,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      ServiceContractItem,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      ServiceOrderTemplate,
      @ObjectModel.enabled: 'EXTERNAL_CALCULATION'
      Product,
      ServiceDocumentPriority,
      MaintNotifTskIsAutomlyDtmnd,
      AdditionalDeviceData,

      @ObjectModel: {
         //foreignKey.association: '_WorkCenter',

           enabled:'EXTERNAL_CALCULATION'
                 }
      _MainWorkCenter.WorkCenter as MainWorkCenter,

      @ObjectModel: { enabled:'EXTERNAL_CALCULATION' }
      _MainWorkCenter.Plant      as MainWorkCenterPlant,

      /* Associations */
      _Equipment,
      _FunctionalLocation,
      _LocationAccountAssignment,
      _MaintenanceActivityType,
      _MaintenanceNotification,
      _MaintenanceOrder,
      _MaintenancePlan,
      _MaintenancePlanCatParam,
      _MaintenancePlannerGroup,
      _MaintenancePlanningPlant,
      _MaintenanceStrategy,
      _PMNotificationPriority,
      _PMNotificationPriorityType,
      _MaintenanceOrderType,
      _MainWorkCenter,
      _WorkCenterType,
      _MaintenanceTaskList,
      _TaskListType,
      _TaskListGroup,
      _TaskListGroupCounter,
      _MaintTaskListForKeyDate,
      _SettlementOrder,
      _Material,
      _Assembly,
      _SalesDocument,
      _PurchaseOrder,
      _PurchaseOrderItem,
      _MaintOperationSystCondition,
      _MaintenanceItemObject,
      _PMReferenceElement,
      _BusinessArea,
      _ImmediateReleaseIsBlocked,
      _ServiceDocumentType,
      _Product,
      _ServiceContract,
      _ServiceContractItem

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTENANCEITEM",
"I_MAINTTASKLISTFORKEYDATE",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"E_MAINTENANCEITEMBASIC",
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSGROUP",
"I_BUSINESSAREA",
"I_EQUIPMENT",
"I_FUNCTIONALLOCATION",
"I_INDICATOR",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCEACTIVITYTYPE",
"I_MAINTENANCEITEMOBJECT",
"I_MAINTENANCENOTIFICATION",
"I_MAINTENANCEORDER",
"I_MAINTENANCEPLANBASIC",
"I_MAINTENANCEPLANCATPARAM",
"I_MAINTENANCEPLANNERGROUP",
"I_MAINTENANCESTRATEGY",
"I_MAINTENANCETASKLIST",
"I_MAINTENANCETASKLISTTYPE",
"I_MAINTOPERATIONSYSTCONDITION",
"I_MAINTTASKLISTFORKEYDATE",
"I_MATERIAL",
"I_ORDER",
"I_ORDERTYPE",
"I_PLANT",
"I_PMNOTIFICATIONPRIORITY",
"I_PMNOTIFICATIONPRIORITYTYPE",
"I_PMREFERENCEELEMENT",
"I_PRODUCT",
"I_PURCHASEORDERAPI01",
"I_PURCHASEORDERITEMAPI01",
"I_SALESDOCUMENT",
"I_SERVICEDOCUMENT",
"I_SERVICEDOCUMENTITEM",
"I_SERVICEDOCUMENTTYPE",
"I_WORKCENTER",
"I_WORKCENTERTYPE"
],
"BASE":
[
"I_MAINTENANCEITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/