I_MaintTaskListOperation

@AbapCatalog.sqlViewName: 'IMAINTTLOP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maintenance Task List Operation'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #COMPOSITE

define view I_MaintTaskListOperation
  as select from    I_BillOfOperationsOpBasic     as plpo
    inner join      I_BOOSqncOperationAssgmtChgSt as plas     on  plpo.BillOfOperationsType             = plas.BillOfOperationsType
                                                              and plpo.BillOfOperationsGroup            = plas.BillOfOperationsGroup
                                                              and (
                                                                 (   // Operation

                                                                   plpo.BOOOperationInternalID          = plas.BOOOperationInternalID
                                                                   and plpo.SuperiorOperationInternalID = '00000000'
                                                                 )
                                                                 or( // Sub-Operation

                                                                   plpo.SuperiorOperationInternalID     = plas.BOOOperationInternalID
                                                                 )
                                                               )
    left outer join I_BillOfOperationsOpBasic     as superior on  plpo.BillOfOperationsType        = superior.BillOfOperationsType
                                                              and plpo.BillOfOperationsGroup       = superior.BillOfOperationsGroup
                                                              and plpo.SuperiorOperationInternalID = superior.BOOOperationInternalID

  association [1..1] to I_MaintenanceTaskList     as _MaintenanceTaskList on  _MaintenanceTaskList.TaskListType         = $projection.TaskListType
                                                                          and _MaintenanceTaskList.TaskListGroup        = $projection.TaskListGroup
                                                                          and _MaintenanceTaskList.TaskListGroupCounter = $projection.TaskListGroupCounter

  association [0..1] to I_MaintenanceTaskListType as _TaskListType        on  _TaskListType.TaskListType = $projection.TaskListType
{
      //      @ObjectModel.foreignKey.association: '_TaskListType'

      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plas.BillOfOperationsType           as TaskListType,

      //      @ObjectModel.foreignKey.association: '_TaskListGroup'

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plas.BillOfOperationsGroup          as TaskListGroup,

      //      @ObjectModel.foreignKey.association: '_TaskListGroupCounter'

      //      @ObjectModel.foreignKey.association: '_BillOfOperationsVariant'

  key plas.BillOfOperationsVariant        as TaskListGroupCounter,

      //            @ObjectModel.foreignKey.association: '_TaskListSequence'

      @ObjectModel.foreignKey.association: '_BillOfOperationsSequence'
  key plas.BillOfOperationsSequence       as TaskListSequence,

      @ObjectModel.foreignKey.association: '_BOOOperationInternalID'
      //  key plas.BOOOperationInternalID         as TaskListOperationInternalId,

  key plpo.BOOOperationInternalID         as TaskListOperationInternalId,

      //      plas.BOOSqncOpAssgmtIntVersionCntr  as TaskListOpBOMItmIntVersCounter,

      plpo.BOOOpInternalVersionCounter    as TaskListOpBOMItmIntVersCounter,
      @Semantics.systemDate.createdAt: true
      plas.CreationDate,

      @Semantics.systemDate.lastChangedAt: true
      plas.LastChangeDate,

      case when superior.Operation is not null
        then superior.Operation
        else plpo.Operation
      end                                 as MaintenanceTaskListOperation,

      case when plpo.SuperiorOperationInternalID <> '00000000'
        then plpo.Operation
        else ''
      end                                 as MaintTaskListSubOperation,

      @Semantics.text:true
      plpo.OperationText,

      @ObjectModel.foreignKey.association: '_OperationControlProfile'
      plpo.OperationControlProfile,

      @ObjectModel.foreignKey.association: '_WorkCenter'
      plpo.WorkCenterInternalID,

      @ObjectModel.foreignKey.association: '_WorkCenterType'
      plpo.WorkCenterTypeCode,

      @ObjectModel.foreignKey.association: '_Plant'
      plpo.Plant,

      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit'
      plpo.OpPlannedWorkQuantity,

      @Semantics.unitOfMeasure: true
      plpo.OpWorkQuantityUnit,

      @ObjectModel.foreignKey.association: '_ChangeMaster'
      plpo.ChangeNumber,

      @Semantics.businessDate.from: true
      plpo.ValidityStartDate,

      @Semantics.businessDate.to: true
      case plpo.ValidityEndDate
        when '00000000' then cast ('99991231' as datub)
        else plpo.ValidityEndDate
      end                                 as ValidityEndDate,

      @ObjectModel.foreignKey.association: '_OperationStandardText'
      plpo.OperationStandardTextCode,

      plpo.PurchasingInfoRecdAddlGrpgName,

      @DefaultAggregation: #NONE
      @Semantics.amount.currencyCode: 'OpExternalProcessingCurrency'
      plpo.OpExternalProcessingPrice,

      plpo.NumberOfOperationPriceUnits,

      @ObjectModel.foreignKey.association: '_OpExternalProcessingCurrency'
      @Semantics.currencyCode: true
      plpo.OpExternalProcessingCurrency,

      @ObjectModel.foreignKey.association: '_PurchasingInfoRecord'
      plpo.PurchasingInfoRecord,

      @ObjectModel.foreignKey.association: '_Supplier'
      plpo.Supplier,

      @ObjectModel.foreignKey.association: '_PurchaseContract'
      plpo.PurchaseContract,

      @ObjectModel.foreignKey.association: '_PurchaseContractItem'
      plpo.PurchaseContractItem,

      @Semantics.quantity.unitOfMeasure: 'OperationStandardDurationUnit'
      plpo.OperationStandardDuration,

      @Semantics.unitOfMeasure: true
      plpo.OperationStandardDurationUnit,

      plpo.NumberOfCapacities,

      @ObjectModel.foreignKey.association: '_OperationSystemCondition'
      plpo.OperationSystemCondition,

      plpo.CostCtrActivityType,

      @ObjectModel.foreignKey.association: '_OperationCalculationControl'
      plpo.OperationCalculationControl,

      @ObjectModel.foreignKey.association: '_Assembly'
      plpo.Assembly,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      plpo.PurchaseOrderQty,

      @ObjectModel.foreignKey.association: '_PurchaseOrderQtyUnit'
      @Semantics.unitOfMeasure: true
      plpo.PurchaseOrderQuantityUnit,

      @ObjectModel.foreignKey.association: '_FunctionalLocation'
      plpo.FunctionalLocation,

      @ObjectModel.foreignKey.association: '_Equipment'
      plpo.Equipment,

      plpo.PurchasingInfoRecordCategory,

      plpo.PurchasingOrganization,

      case when plas.IsDeleted = 'X'
        then plas.IsDeleted
        else plpo.IsDeleted
      end                                 as IsDeleted,

      plas.IsImplicitlyDeleted,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_OperationUnit'
      plpo.OperationUnit,

      plpo.OpQtyToBaseQtyDnmntr,

      plpo.OpQtyToBaseQtyNmrtr,

      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @DefaultAggregation: #NONE
      plpo.OperationReferenceQuantity,

      plpo.PlannedDeliveryDuration,

      plpo.CostElement,

      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      plpo.PurchasingGroup,

      plpo.MaterialGroup,

      plpo.OperationCostingRelevancyType,

      @Semantics.quantity.unitOfMeasure: 'MinimumDurationUnit'
      plpo.MinimumDuration,

      @ObjectModel.foreignKey.association: '_MinimumDurationUnit'
      @Semantics.unitOfMeasure: true
      plpo.MinimumDurationUnit,

      plpo.OperationWorkPercent,

      plpo.CapRqmtsDistributionFunction,

      @ObjectModel.foreignKey.association: '_CompanyCode'
      plpo.CompanyCode,

      @ObjectModel.foreignKey.association: '_FactoryCalendar'
      plpo.FactoryCalendar,

      plpo.CapacityRequirementDistrKey,

      plpo.MaintOperationExecStageCode,

      plpo.MaintOperationalChecklistType,

      /* Technical Fields */
      concat(concat( concat( plas.BillOfOperationsType,
            plas.BillOfOperationsGroup ),
            plas.BillOfOperationsVariant ),
            plas.BOOOperationInternalID ) as TaskListOperationObjectKey,

      @Consumption.hidden: true
      plas.BOOOperationInternalID,
      @Consumption.hidden: true
      plpo.BillOfOperationsGroup,
      @Consumption.hidden: true
      plpo.BillOfOperationsType,
      /* Associations */
      plas._BillOfOperationsGroup         as _TaskListGroup,
      plas._BillOfOperations              as _TaskListGroupCounter,
      plas._BillOfOperationsSequence      as _TaskListSequence,
//      plas._BOOOperationInternalID        as _TaskListOperationInternalId,

      plpo._BOOOperationInternalID        as _TaskListOperationInternalId,

      plpo._BOOOperationInternalID,
      plas._BillOfOperationsGroup,
      plas._BillOfOperationsType,
      plas._BillOfOperationsSequence,

      plpo._Assembly,
      plpo._Equipment,
      plpo._FunctionalLocation,
      plpo._ChangeMaster,
      plpo._OperationCalculationControl,
      plpo._OperationControlProfile,
      plpo._OpExternalProcessingCurrency,
      plpo._OperationStandardText,
      plpo._OperationSystemCondition,
      plpo._Plant,
      plpo._PurchasingInfoRecord,
      plpo._PurchaseContract,
      plpo._PurchaseContractItem,
      plpo._PurchasingOrganization,
      plpo._Supplier,
      plpo._WorkCenter,
      plpo._WorkCenterType,
      plpo._OperationUnit,
      plpo._PurchasingGroup,
      plpo._OperationStandardDurationUnit,
      plpo._PurchaseOrderQtyUnit,
      plpo._MaterialGroup,
      plpo._MinimumDurationUnit,
      plpo._CompanyCode,
      plpo._FactoryCalendar,
      plpo._MaintOperationExecStageCode,

      //      _MaintenanceTaskList.TaskListUsage as TaskListUsage,  // Added for I_ROUT2


      /* Associations - locally defined */
      _MaintenanceTaskList,
      _TaskListType
}
where
     plpo.BillOfOperationsType = 'A'
  or plpo.BillOfOperationsType = 'E'
  or plpo.BillOfOperationsType = 'T'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONSOPBASIC",
"I_BOOSQNCOPERATIONASSGMTCHGST"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSSEQUENCE",
"I_BILLOFOPERATIONSTYPE",
"I_BOOOPERATIONINTERNALID",
"I_CHANGEMASTER",
"I_COMPANYCODE",
"I_CURRENCY",
"I_EQUIPMENT",
"I_FACTORYCALENDAR",
"I_FUNCTIONALLOCATION",
"I_MAINTENANCETASKLIST",
"I_MAINTENANCETASKLISTTYPE",
"I_MAINTOPERATIONEXECSTAGECODE",
"I_MAINTOPERATIONSYSTCONDITION",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_OPERATIONCALCULATIONCONTROL",
"I_OPERATIONCONTROLPROFILE",
"I_OPERATIONSTANDARDTEXT",
"I_PLANT",
"I_PURCHASECONTRACT",
"I_PURCHASECONTRACTITEM",
"I_PURCHASINGGROUP",
"I_PURCHASINGINFORECORDAPI01",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER",
"I_UNITOFMEASURE",
"I_WORKCENTER",
"I_WORKCENTERTYPE"
],
"BASE":
[
"I_BILLOFOPERATIONSOPBASIC",
"I_BOOSQNCOPERATIONASSGMTCHGST"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/