I_MaintObjectPhaseControl

@EndUserText.label: 'Maintenance Object Phase Control Code'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'IMOBJPHCTL'

@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
   usageType.serviceQuality: #C,
   usageType.sizeCategory: #XL,
   usageType.dataClass: #MIXED
}

define view I_MaintObjectPhaseControl
  as select from           I_StatusObjectStatus           as _StatusObjectStatus
    inner join             I_MaintPhaseControlCode        as _MaintPhaseControlCode        on _StatusObjectStatus.StatusCode = _MaintPhaseControlCode.MaintenanceUserStatusCode

    left outer to one join I_MaintPhseCtrlActvtnProcValue as _MaintPhseCtrlActvtnProcValue on  _MaintPhseCtrlActvtnProcValue.MaintenanceOrderType         = _MaintPhaseControlCode.MaintenanceOrderType
                                                                                           and _MaintPhseCtrlActvtnProcValue.EAMBlockerCodeEntityType     = _MaintPhaseControlCode.EAMBlockerCodeEntityType
                                                                                           and _MaintPhseCtrlActvtnProcValue.EAMBlockerCode               = _MaintPhaseControlCode.MaintenancePhaseControlName
                                                                                           and _MaintPhseCtrlActvtnProcValue.MaintProcgPhseCtrlActvtnCode = '02' //Filter Blocks (Endphase) only


  association [0..1] to I_MaintObjPhseCtrlCodeChgHist as _MaintObjPhseCtrlCodeChgSet   on  _StatusObjectStatus.StatusObject             = _MaintObjPhseCtrlCodeChgSet.StatusObject
                                                                                       and _StatusObjectStatus.StatusCode               = _MaintObjPhseCtrlCodeChgSet.StatusCode
                                                                                       and _MaintObjPhseCtrlCodeChgSet.StatusIsInactive = ''
  association [0..1] to I_MaintObjPhseCtrlCodeChgHist as _MaintObjPhseCtrlCodeChgReset on  _StatusObjectStatus.StatusObject               = _MaintObjPhseCtrlCodeChgReset.StatusObject
                                                                                       and _StatusObjectStatus.StatusCode                 = _MaintObjPhseCtrlCodeChgReset.StatusCode
                                                                                       and _MaintObjPhseCtrlCodeChgReset.StatusIsInactive = 'X'

  association [0..1] to I_MaintPhseCtrlActivationCode as _MaintPhseCtrlActivationCode  on  _MaintPhseCtrlActivationCode.MaintProcgPhseCtrlActvtnCode = $projection.MaintProcgPhseCtrlActvtnCode
  association [0..1] to I_MaintObjPhaseControlState   as _MaintObjPhaseControlState    on  _MaintObjPhaseControlState.MaintObjPhaseControlStateCode = $projection.MaintObjPhaseControlStateCode
{
  key _StatusObjectStatus.StatusObject,

  key _MaintPhaseControlCode.MaintenanceOrderType,
  key _MaintPhaseControlCode.EAMBlockerCodeEntityType,
  key _MaintPhaseControlCode.MaintenancePhaseControlName,

      _MaintPhaseControlCode.MaintUserStatusProfileCode,
      _MaintPhaseControlCode.MaintenanceUserStatusCode,
      _MaintPhaseControlCode.MaintenancePhaseControlText,
      _MaintPhaseControlCode.MaintPhseCtrlIsSetAutomly,
      _MaintPhaseControlCode.EAMOverallStatusProfile,
      _MaintPhaseControlCode.MaintPhaseControlAuthorityCode,
      _MaintPhaseControlCode.ConfigDeprecationCode,

      @ObjectModel.foreignKey.association: '_MaintPhseCtrlActivationCode'
      _MaintPhseCtrlActvtnProcValue.MaintProcgPhseCtrlActvtnCode,

      _MaintPhseCtrlActvtnProcValue.EAMProcessPhaseCode,
      _MaintPhseCtrlActvtnProcValue.EAMProcessSubPhaseCode,

      @ObjectModel.foreignKey.association: '_MaintObjPhaseControlState'
      cast(
        case
          when _StatusObjectStatus.StatusIsActive = 'X' then
            'X'
          when _StatusObjectStatus.StatusIsInactive = 'X' then
            'Y'
          else
            ''
        end as eam_bo_blkcd_status preserving type)                                                           as MaintObjPhaseControlStateCode,

      cast( _MaintObjPhseCtrlCodeChgSet.LastChangedByUser as eam_bo_blkcd_set_userid preserving type )        as MaintObjPhaseCtrlCodeSetBy,

      cast( dats_tims_to_tstmp( _MaintObjPhseCtrlCodeChgSet.LastChangeDate,
                          _MaintObjPhseCtrlCodeChgSet.LastChangeTime,
                          abap_system_timezone($session.client, 'NULL'),
                          $session.client, 'NULL') as eam_bo_blkcd_set_on preserving type )                   as MaintObjPhseCtrlCodeSetDteTime,

      cast( _MaintObjPhseCtrlCodeChgReset.LastChangedByUser as eam_bo_blkcd_resolved_userid preserving type ) as MaintObjPhaseCtrlCodeResetBy,

      cast( dats_tims_to_tstmp( _MaintObjPhseCtrlCodeChgReset.LastChangeDate,
                          _MaintObjPhseCtrlCodeChgReset.LastChangeTime,
                          abap_system_timezone($session.client, 'NULL'),
                          $session.client, 'NULL') as eam_bo_blkcd_resolved_on preserving type )              as MaintObjPhseCtrlCodeRsetDteTme,

      /* Propagated associations */
      _StatusObjectStatus._StatusObject,
      _MaintPhaseControlCode._StatusCode,
      _MaintPhaseControlCode._StatusProfile,

      _MaintPhseCtrlActvtnProcValue._ProcessingPhase,
      _MaintPhseCtrlActvtnProcValue._ProcessingSubPhase,

      _MaintPhseCtrlActivationCode,
      _MaintObjPhaseControlState,
      _MaintPhaseControlCode._ConfignDeprecationCode,

      _MaintObjPhseCtrlCodeChgSet._LastChangedByUser                                                          as _LastSetByUser,
      _MaintObjPhseCtrlCodeChgReset._LastChangedByUser                                                        as _LastResetByUser
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTOBJPHSECTRLCODECHGHIST",
"I_MAINTPHASECONTROLCODE",
"I_MAINTPHSECTRLACTVTNPROCVALUE",
"I_STATUSOBJECTSTATUS"
],
"ASSOCIATED":
[
"I_CONFIGNDEPRECATIONCODE",
"I_EAMPROCESSPHASE",
"I_EAMPROCESSSUBPHASE",
"I_MAINTOBJPHASECONTROLSTATE",
"I_MAINTOBJPHSECTRLCODECHGHIST",
"I_MAINTPHSECTRLACTIVATIONCODE",
"I_STATUSCODE",
"I_STATUSOBJECT",
"I_STATUSPROFILE",
"I_USER"
],
"BASE":
[
"I_MAINTOBJPHSECTRLCODECHGHIST",
"I_MAINTPHASECONTROLCODE",
"I_MAINTPHSECTRLACTVTNPROCVALUE",
"I_STATUSOBJECTSTATUS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/