I_MaintNotifLongText

@AbapCatalog.sqlViewName: 'IMAINTNOTIFLTXT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'PM: Maintenance  Notification  Long Text'

@ObjectModel.semanticKey:  [ 'MaintenanceNotification' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

define view I_MaintNotifLongText
  as select from I_MaintenanceNotification
  association [0..1] to I_TextObject              as _TextObjectInSessionLanguage on  _TextObjectInSessionLanguage.TextObjectKey      = $projection.MaintenanceNotification
                                                                                  and _TextObjectInSessionLanguage.TextObjectType     = 'LTXT'
                                                                                  and _TextObjectInSessionLanguage.TextObjectCategory = 'QMEL'
                                                                                  and _TextObjectInSessionLanguage.Language           = $session.system_language
  association [0..1] to I_TextObject              as _TextObjectInNotifLanguage   on  _TextObjectInNotifLanguage.TextObjectKey      = $projection.MaintenanceNotification
                                                                                  and _TextObjectInNotifLanguage.TextObjectType     = 'LTXT'
                                                                                  and _TextObjectInNotifLanguage.TextObjectCategory = 'QMEL'
                                                                                  and _TextObjectInNotifLanguage.Language           = I_MaintenanceNotification.LongTextLanguage
  association [1..1] to I_MaintenanceNotification as _MaintenanceNotification     on  $projection.MaintenanceNotification = _MaintenanceNotification.MaintenanceNotification
  association [0..1] to I_Language                as _Language                    on  _Language.Language = $projection.Language
  association [0..1] to I_Indicator               as _LongTextIsNotChangeable     on  $projection.LongTextIsNotChangeable = _LongTextIsNotChangeable.IndicatorValue
  association [0..1] to I_TextObjectPlainLongText as _TextObjectPlainLongText     on  _TextObjectPlainLongText.TextObjectKey      = $projection.MaintenanceNotification
                                                                                  and _TextObjectPlainLongText.TextObjectType     = 'LTXT'
                                                                                  and _TextObjectPlainLongText.TextObjectCategory = 'QMEL'
                                                                                  and _TextObjectPlainLongText.Language           = $projection.Language
{

         //        @ObjectModel.foreignKey.association: '_MaintNotificationTechObj'

  key    MaintenanceNotification,

         cast( MaintenanceNotification as tdobname )                                      as TextObjectKey,

         @Semantics.language: true
         @ObjectModel.foreignKey.association: '_Language'
         cast( coalesce( _TextObjectInSessionLanguage.Language,
                         _TextObjectInNotifLanguage.Language ) as spras preserving type ) as Language,

         cast( 'QMEL' as tdobject )                                                       as TextObjectCategory,

         cast( 'LTXT' as tdid preserving type )                                           as TextObjectType,

         @Semantics.text: true
         @UI.multiLineText: true
         cast('' as eams_ltext )                                                          as MaintNotificationLongText,

         @Semantics.text: true
         @UI.multiLineText: true
         cast('' as eams_ltext )                                                          as MaintNotifLongTextForEdit,

         @ObjectModel.foreignKey.association: '_LongTextIsNotChangeable'
         //         cast( _MaintenanceNotification._PMNotificationType.LongTextIsNotChangeable as boole_d ) as LongTextIsNotChangeable,

         cast( _PMNotificationType.LongTextIsNotChangeable as boole_d )                   as LongTextIsNotChangeable,

         _MaintenanceNotification,
         _Language,
         _LongTextIsNotChangeable,
         _TextObjectPlainLongText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTENANCENOTIFICATION",
"I_PMNOTIFICATIONTYPE",
"I_TEXTOBJECT"
],
"ASSOCIATED":
[
"I_INDICATOR",
"I_LANGUAGE",
"I_MAINTENANCENOTIFICATION",
"I_TEXTOBJECT",
"I_TEXTOBJECTPLAINLONGTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/