I_MaintJobAndWorkItemForUser

@AbapCatalog.sqlViewName: 'IMTJOBWKITMUSR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Current Users Maintenance Jobs and Work Items'
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
   usageType.serviceQuality: #C,
   usageType.sizeCategory: #XL,
   usageType.dataClass: #TRANSACTIONAL
}

-- Selection is limited to logon user's employee ID!
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

define view I_MaintJobAndWorkItemForUser
  as select from I_MaintenanceJobAndWorkItem
  --association [0..1] to I_EAMObjectUsrStatusWithNumber as _ObjectUserStatusWithNumber on  _ObjectUserStatusWithNumber.StatusObject = $projection.StatusObject
    inner join   I_BusinessUserBasic as BusUser on BusUser.UserID = $session.user
  association [0..1] to I_PersonWorkAgreement_1      as _PersonWorkAgreement on  _PersonWorkAgreement.PersonWorkAgreement = I_MaintenanceJobAndWorkItem.PersonResponsible
  association [0..1] to I_EAMObjectOverallStatus     as _ObjectOverallStatus on  _ObjectOverallStatus.StatusObject = I_MaintenanceJobAndWorkItem.StatusObject
  association [0..*] to I_EAMOvrlStatusNextViaAction as _NextViaAction       on  _NextViaAction.EAMOverallStatusProfile = $projection.eamoverallobjectstatusprofile
                                                                             and _NextViaAction.EAMOverallStatus        = $projection.eamoverallobjectstatus
  association [0..1] to I_WorkforcePerson            as _PersonResponsible   on  _PersonResponsible.PersonExternalID = $projection.PersonResponsible

{
  key I_MaintenanceJobAndWorkItem.MaintenanceJobInternalID,
  key I_MaintenanceJobAndWorkItem.StatusObject,
  key I_MaintenanceJobAndWorkItem.ObjectType,
      I_MaintenanceJobAndWorkItem.PersonResponsible,
      StatusCode,

      _ObjectOverallStatus.EAMOverallObjectStatusProfile,
      _ObjectOverallStatus.EAMOverallObjectStatus,

      _ObjectOverallStatus._ConfirmationUsage.EAMOvrlStsIsCoveredByEvent as MaintWkItmIsInConfirmationMode,
      _ObjectOverallStatus._NextPrimaryStatus.EAMNextPrimaryOverallStatus,

      _ObjectOverallStatus._OverallStatus,
      _NextViaAction,
      _PersonResponsible
}
where
  BusUser.BusinessPartner = _PersonWorkAgreement.Person
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSUSERBASIC",
"I_EAMOBJECTOVERALLSTATUS",
"I_EAMOVERALLSTATUSNEXTPRIMARY",
"I_EAMOVERALLSTATUSUSAGE",
"I_MAINTENANCEJOBANDWORKITEM",
"I_PERSONWORKAGREEMENT_1"
],
"ASSOCIATED":
[
"I_EAMOBJECTOVERALLSTATUS",
"I_EAMOVERALLSTATUS",
"I_EAMOVRLSTATUSNEXTVIAACTION",
"I_PERSONWORKAGREEMENT_1",
"I_WORKFORCEPERSON"
],
"BASE":
[
"I_EAMOBJECTOVERALLSTATUS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/