I_MaintItemObjectListItem

DDL: I_MAINTITEMOBJECTLISTITEM SQL: IMTITMOBJLTITM Type: view COMPOSITE

Maintenance Item Object List Item

I_MaintItemObjectListItem is a Composite CDS View that provides data about "Maintenance Item Object List Item" in SAP S/4HANA. It reads from 2 data sources (I_MaintenanceItemBasic, I_MaintenanceObjectListItem) and exposes 31 fields with key fields MaintenanceItem, MaintenanceItemObjectList, MaintenanceObjectListItem. It has 1 association to related views.

2 data source(s) 31 fields

Data Sources (2)

SourceAliasJoin Type
I_MaintenanceItemBasic MaintenanceItem from
I_MaintenanceObjectListItem MaintenanceItemObjectListItem inner

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_FunctionalLocation _FunctionalLocation $projection.FunctionalLocation = _FunctionalLocation.FunctionalLocation

Annotations (10)

NameValueLevelField
AbapCatalog.sqlViewName IMTITMOBJLTITM view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
ClientHandling.algorithm #SESSION_VARIABLE view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Maintenance Item Object List Item view
VDM.viewType #COMPOSITE view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MASTER view

Fields (31)

KeyFieldSource TableSource FieldDescription
KEY MaintenanceItem I_MaintenanceItemBasic MaintenanceItem
KEY MaintenanceItemObjectList I_MaintenanceObjectListItem MaintenanceObjectList
KEY MaintenanceObjectListItem I_MaintenanceObjectListItem MaintenanceObjectListItem
MaintenanceObjectListUsageCode I_MaintenanceObjectListItem MaintenanceObjectListUsageCode
Equipment I_MaintenanceObjectListItem Equipment
FunctionalLocation
MaintenanceNotification I_MaintenanceObjectListItem MaintenanceNotification
Assembly I_MaintenanceObjectListItem Assembly
MaintObjectLocAcctAssgmtNmbr I_MaintenanceObjectListItem MaintObjectLocAcctAssgmtNmbr
Material I_MaintenanceObjectListItem Material
SerialNumber I_MaintenanceObjectListItem SerialNumber
UniqueItemIdentifier I_MaintenanceObjectListItem UniqueItemIdentifier
CreationDate I_MaintenanceObjectListItem CreationDate
MaintObjectListItemSequence I_MaintenanceObjectListItem MaintObjectListItemSequence
MaintObjListEntryIsProcessed I_MaintenanceObjectListItem MaintObjListEntryIsProcessed
ServiceReferenceProduct I_MaintenanceObjectListItem ServiceReferenceProduct
MaintenancePlanCallObject I_MaintenanceItemBasic MaintenancePlanCallObject
MaintenancePlanningPlant I_MaintenanceItemBasic MaintenancePlanningPlant
MaintenancePlannerGroup I_MaintenanceItemBasic MaintenancePlannerGroup
MaintenancePlant
CostCenter
ControllingArea
_FunctionalLocation _FunctionalLocation
_MaintenancePlanningPlant I_MaintenanceItemBasic _MaintenancePlanningPlant
_Assembly I_MaintenanceObjectListItem _Assembly
_Equipment I_MaintenanceObjectListItem _Equipment
_Product I_MaintenanceObjectListItem _Product
_LocationAccountAssignment I_MaintenanceObjectListItem _LocationAccountAssignment
_PMNotifMaintenanceData I_MaintenanceObjectListItem _PMNotifMaintenanceData
_SerialNumber I_MaintenanceObjectListItem _SerialNumber
_UniqueItemIdentifier I_MaintenanceObjectListItem _UniqueItemIdentifier 
@AbapCatalog.sqlViewName: 'IMTITMOBJLTITM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Item Object List Item'
@VDM.viewType: #COMPOSITE

@ObjectModel: {
   usageType.serviceQuality: #C,
   usageType.sizeCategory: #L,
   usageType.dataClass: #MASTER
}


define view I_MaintItemObjectListItem
  as select from I_MaintenanceItemBasic      as MaintenanceItem
    inner join   I_MaintenanceObjectListItem as MaintenanceItemObjectListItem on MaintenanceItem.MaintenanceItemObjectList = MaintenanceItemObjectListItem.MaintenanceObjectList
  association [0..1] to I_FunctionalLocation as _FunctionalLocation on $projection.FunctionalLocation = _FunctionalLocation.FunctionalLocation
{

  key MaintenanceItem.MaintenanceItem,
  key MaintenanceItemObjectListItem.MaintenanceObjectList                                                                       as MaintenanceItemObjectList,
  key MaintenanceItemObjectListItem.MaintenanceObjectListItem,

      MaintenanceItemObjectListItem.MaintenanceObjectListUsageCode,

      @ObjectModel.foreignKey.association: '_Equipment'
      MaintenanceItemObjectListItem.Equipment,

      @ObjectModel.foreignKey.association: '_FunctionalLocation'
      cast ( MaintenanceItemObjectListItem._LocationAccountAssignment.FunctionalLocation as tplnr_unconverted preserving type ) as FunctionalLocation,

      @ObjectModel.foreignKey.association: '_PMNotifMaintenanceData'
      MaintenanceItemObjectListItem.MaintenanceNotification,

      @ObjectModel.foreignKey.association: '_Assembly'
      MaintenanceItemObjectListItem.Assembly,

      @ObjectModel.foreignKey.association: '_LocationAccountAssignment'
      MaintenanceItemObjectListItem.MaintObjectLocAcctAssgmtNmbr,

      @ObjectModel.foreignKey.association: '_Product'
      MaintenanceItemObjectListItem.Material,

      MaintenanceItemObjectListItem.SerialNumber,

      MaintenanceItemObjectListItem.UniqueItemIdentifier,

      @Semantics.systemDate.createdAt: true
      MaintenanceItemObjectListItem.CreationDate,

      MaintenanceItemObjectListItem.MaintObjectListItemSequence,

      @Semantics.booleanIndicator: true
      MaintenanceItemObjectListItem.MaintObjListEntryIsProcessed,

      MaintenanceItemObjectListItem.ServiceReferenceProduct,

      /* Auth Field */
      MaintenanceItem.MaintenancePlanCallObject,
      MaintenanceItem.MaintenancePlanningPlant,
      MaintenanceItem.MaintenancePlannerGroup,
      MaintenanceItem._LocationAccountAssignment.MaintenancePlant,
      MaintenanceItem._LocationAccountAssignment.CostCenter,
      MaintenanceItem._LocationAccountAssignment.ControllingArea,

      /* Local Associations */
      _FunctionalLocation,

      /* Associations */
      MaintenanceItem._MaintenancePlanningPlant,
      MaintenanceItemObjectListItem._Assembly,
      MaintenanceItemObjectListItem._Equipment,
      MaintenanceItemObjectListItem._Product,
      MaintenanceItemObjectListItem._LocationAccountAssignment,
      MaintenanceItemObjectListItem._PMNotifMaintenanceData,
      MaintenanceItemObjectListItem._SerialNumber,
      MaintenanceItemObjectListItem._UniqueItemIdentifier

}
where
  MaintenanceItemObjectListItem.MaintenanceObjectListUsageCode = 'W'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCEITEMBASIC",
"I_MAINTENANCEOBJECTLISTITEM"
],
"ASSOCIATED":
[
"I_EQUIPMENT",
"I_FUNCTIONALLOCATION",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MATERIAL",
"I_PLANT",
"I_PMNOTIFMAINTENANCEDATA",
"I_PRODUCT"
],
"BASE":
[
"I_MAINTENANCEITEMBASIC",
"I_MAINTENANCEOBJECTLISTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More