I_MRPSafetyStockMethodText

@AbapCatalog.sqlViewName: 'IMRPSFTYSTKMETHT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.viewEnhancementCategory: [#NONE] 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataExtraction.enabled: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, 
                                     #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE,
                                     #SEARCHABLE_ENTITY, 
                                     #SQL_DATA_SOURCE]
@ObjectModel.representativeKey: 'MRPSafetyStockMethod' 
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #META}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API  
@VDM.viewType: #BASIC
@EndUserText.label: 'MRP Safety Stock Method - Text'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK", "KEY_CHECK" ]  } */
define view I_MRPSafetyStockMethodText 
  as select from dd07t 
  association to parent I_MRPSafetyStockMethod as _MRPSafetyStockMethod
    on $projection.MRPSafetyStockMethod = _MRPSafetyStockMethod.MRPSafetyStockMethod
  association [0..1] to I_Language as _Language      
    on $projection.Language = _Language.Language  
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language, 
      @ObjectModel.foreignKey.association: '_MRPSafetyStockMethod'
      @ObjectModel.text.element: ['MRPSafetyStockMethodText']
  key cast( dd07t.domvalue_l as mrp_sstock_method )     as MRPSafetyStockMethod,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l as DomainValue,
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      @Semantics.text: true
      cast( dd07t.ddtext as val_text preserving type )  as MRPSafetyStockMethodText,

      // Associations

      _MRPSafetyStockMethod,
      _Language    
}
where
      domname  = 'MRP_SSTOCK_METHOD'
  and as4local = 'A'
  and as4vers  = '0000';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_MRPSAFETYSTOCKMETHOD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/