I_MRPOutboundDelivery

@AbapCatalog.sqlViewName: 'IMRPOUTBNDDEL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'MRP Outbound Delivery'

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED

@VDM.viewType: #COMPOSITE
@AccessControl.personalData.blocking: #REQUIRED

define view I_MRPOutboundDelivery
  as select from I_OutboundDeliveryItem
  association [1..1] to I_OutboundDelivery as _OutboundDelivery on $projection.Delivery = _OutboundDelivery.OutboundDelivery
  /* View name and Field names are changing. View is not released
     left outer join I_CustomerMaterialInfoRecd as CustomerMaterial
                                                on CustomerMaterial.SalesOrganization = _OutboundDelivery.SalesOrganization
                                               and CustomerMaterial.DistributionChannel = DistributionChannel
                                               and CustomerMaterial.SoldToParty = _OutboundDelivery.ShipToParty
                                               and CustomerMaterial.Material = Material
    */
  association [0..1] to I_UnitOfMeasure    as _BaseUnit         on $projection.BaseUnit = _BaseUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure    as _SalesUnit        on $projection.SalesUnit = _SalesUnit.UnitOfMeasure
  association [0..1] to I_WBSElement       as _WBSElement       on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
{
  key OutboundDelivery                                                                                              as Delivery,
  key OutboundDeliveryItem                                                                                          as DeliveryItem,
      _OutboundDelivery.DeliveryDocumentType                                                                        as DeliveryType,
      _OutboundDelivery.DocumentDate,
      ReferenceSDDocument                                                                                           as ReferenceDocument,
      ReferenceSDDocumentItem                                                                                       as ReferenceDocumentItem,
      Plant                                                                                                         as MRPPlant,
      _Plant.PlantName                                                                                              as MRPPlantName,
      Material,
      _Material._Text[1: Language = $session.system_language ].MaterialName,
      MaterialGroup,
      StorageLocation,
      Batch,
      InventorySpecialStockType,
      ReferenceSDDocumentCategory,
      // RelatedObjects group

      WBSElementInternalID,
      cast ( _WBSElement.WBSElement as   ps_posid_edit preserving type )   as WBSElementExternalID,
      _WBSElement.WBSElementObject,
      _WBSElement._WBSElementLangBsdDesc[1: Language = $session.system_language ].WBSElementLangBsdDescription as WBSElementDescription,
      _WBSElement.WBSDescription,
      cast ( _WBSElement.Project as ps_pspid_edit preserving type ) as ProjectExternalID,
      _WBSElement._Project.ProjectDescription,

       cast( case
         when _WBSElement.ResponsiblePerson = '00000000' or _WBSElement.ResponsiblePerson is null
            then _WBSElement._EntProjectResponsiblePerson.PersonWorkAgreement
          else
            _WBSElement.ResponsiblePerson
        end as ps_s4_vernr preserving type )                                                                        as ResponsiblePerson,
      cast( case
         when _WBSElement.ResponsiblePerson = '00000000' or _WBSElement.ResponsiblePerson is null
            then _WBSElement._EntProjectResponsiblePerson._WorkforcePerson.PersonFullName
          else
            _WBSElement.ResponsiblePersonName
        end as ad_namtext preserving type )                                                                         as ResponsiblePersonName,

      MaterialByCustomer,
      // Sales and Customer data

      ''                                                                                                            as SalesOrder,
      0                                                                                                             as SalesOrderItem,
      ''                                                                                                            as SalesOrderType,
      ''                                                                                                            as SalesOrderItemMaterial,
      /*    Sales Order (KDAUF, KDPOS) currently not provided by basic reuse view
            SalesOrder,
            SalesOrderItem,
            _SalesOrder.SalesOrderType,
            SalesOrderMaterial as SalesOrderItemMaterial, */
      _OutboundDelivery.SalesOrganization,
      DistributionChannel,
      Division,
      _OutboundDelivery.CustomerGroup,
      _OutboundDelivery.ShipToParty                                                                                 as Customer,
      _OutboundDelivery._ShipToParty.CustomerName,
      _OutboundDelivery._ShipToParty.CustomerFullName                                                               as ContactPersonName,
      _OutboundDelivery._ShipToParty._StandardAddress.PhoneNumber                                                   as ContactPersonPhoneNumber,
      //_OutboundDelivery._ShipToParty._StandardAddress._DefaultEmailAddress.EmailAddress                           as ContactPersonEmailAddress, // Commented out as prop is not needed and

                                                                                                                                                  // it leads to a full table scan of ADR6 table

      // Material By Customer

      /*
      CustomerMaterial.MaterialByCustomer,
      @Semantics.unitOfMeasure: true
      CustomerMaterial.BaseUnit as CustomerMaterialBaseUnit,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      CustomerMaterial.MinDeliveryQtyInBaseUnit,
      */

      // Delivery attributes

      _OutboundDelivery.DeliveryBlockReason,
      _OutboundDelivery._DeliveryBlockReason._Text[1: Language = $session.system_language ].DeliveryBlockReasonText as DeliveryBlockReasonText,
      case _OutboundDelivery.DeliveryBlockReason
        when '' then ''
        else 'X'
      end                                                                                                           as DeliveryIsBlocked,
      _OutboundDelivery.DeliveryPriority,
      _OutboundDelivery._DeliveryPriority._Text[1: Language = $session.system_language ].DeliveryPriorityDesc       as DeliveryPriorityDesc,
      _OutboundDelivery.CompleteDeliveryIsDefined,
      case _OutboundDelivery.CompleteDeliveryIsDefined
        when '' then case DeliveryGroup
          when '000' then case PartialDeliveryIsAllowed
            when '' then 'X'
            when 'D' then 'X'
            else ''
            end
          else ''
          end
        else ''
      end                                                                                                           as PartialDeliveryIsAllowed,
      case _OutboundDelivery.OverallGoodsMovementStatus
        when 'C' then 'X'
        else ''
      end                                                                                                           as DeliveryIsPostedGoodsIssue,
      --    MaxNumberOfPartialDelivery,  //not yet available


      // Dates

      _OutboundDelivery.DeliveryDate                                                                                as RequestedDeliveryDate,
      _OutboundDelivery.LoadingDate                                                                                 as RequestedLoadingDate,
      _OutboundDelivery.PlannedGoodsIssueDate                                                                       as RequestedGoodsIssueDate,
      ProductAvailabilityDate,

      // Quantities and UoM

      @Semantics.unitOfMeasure: true
      BaseUnit,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      ActualDeliveredQtyInBaseUnit                                                                                  as DeliveredQuantityInBaseUnit,
      @Semantics.unitOfMeasure: true
      DeliveryQuantityUnit                                                                                          as SalesUnit,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SalesUnit'
      ActualDeliveryQuantity                                                                                        as DeliveredQuantityInSalesUnit,

      ReferenceSDDocument,
      //QuickviewCategory,


      // Associations

      _BaseUnit,
      _SalesUnit,
      _OutboundDelivery,
      _WBSElement,
      _OutboundDelivery._DeliveryPriority,
      _OutboundDelivery._DeliveryBlockReason,
      _OutboundDelivery._ShipToParty,
      _OutboundDelivery._DeliveryDocumentType,
      _Plant,
      _ReferenceSDDocument,
      _Material,
      _DeliveryQuantityUnit,
      _ReferenceSalesDocumentItem,
      _ReferenceSDDocumentCategory
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_CUSTOMER",
"I_DELIVERYBLOCKREASON",
"I_DELIVERYBLOCKREASONTEXT",
"I_DELIVERYPRIORITY",
"I_DELIVERYPRIORITYTEXT",
"I_ENTPROJECTRESPONSIBLEPERSON",
"I_MATERIAL",
"I_MATERIALTEXT",
"I_OUTBOUNDDELIVERY",
"I_OUTBOUNDDELIVERYITEM",
"I_PLANT",
"I_PROJECTBYINTERNALKEY",
"I_WBSELEMENT",
"I_WBSELEMENTTEXT",
"I_WORKFORCEPERSON"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_DELIVERYBLOCKREASON",
"I_DELIVERYDOCUMENTTYPE",
"I_DELIVERYPRIORITY",
"I_MATERIAL",
"I_OUTBOUNDDELIVERY",
"I_PLANT",
"I_SALESDOCUMENT",
"I_SALESDOCUMENTITEM",
"I_SDDOCUMENTCATEGORY",
"I_UNITOFMEASURE",
"I_WBSELEMENT"
],
"BASE":
[
"I_OUTBOUNDDELIVERY",
"I_OUTBOUNDDELIVERYITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/