I_MRPLotSizingProcedure

@AbapCatalog.sqlViewName: 'IPPLOTSIZPROC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.buffering: {status: #ACTIVE, type: #FULL, numberOfKeyFields: 000}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.compositionRoot: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY, #EXTRACTION_DATA_SOURCE]
@ObjectModel.representativeKey: 'MaterialLotSizingProcedure'
@ObjectModel.semanticKey: ['MaterialLotSizingProcedure']
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'MRP Lot Sizing Procedure'
// For value help purposes refer to CDS I_MRPLotSizingProcedureVH


/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_MRPLotSizingProcedure
  as select from t439a as proc

  association [0..*] to I_MRPLotSizingProcedureText as _Text                   on $projection.MaterialLotSizingProcedure = _Text.MaterialLotSizingProcedure
  association [1..1] to I_MRPLotSizingProcedureType as _LotSizingProcedureType on $projection.LotSizingProcedureType = _LotSizingProcedureType.LotSizingProcedureType
{
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      @ObjectModel.text.association: '_Text'
  key proc.disls                                    as MaterialLotSizingProcedure,

      @ObjectModel.foreignKey.association: '_LotSizingProcedureType'
      cast(proc.losvf as vdm_losvf preserving type) as LotSizingProcedureType,
      proc.loskz                                    as LotSizeType,
--    proc.peraz                                    as NumberOfLotSizingPeriods,  // DEC fields not allowed

      proc.terbv                                    as LotSizePeriodSchedulingType,
      proc.lastl                                    as LastLotIsPlannedExactly,
      proc.untkz                                    as UnderDeliveryTolIsChecked,

      // Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Text,
      _LotSizingProcedureType
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T439A"
],
"ASSOCIATED":
[
"I_MRPLOTSIZINGPROCEDURETEXT",
"I_MRPLOTSIZINGPROCEDURETYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/