I_MRPChangeRequest

@AbapCatalog.sqlViewName: 'IMRPCHANGEREQ'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'MRP Change Request'

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED },
    semanticKey:  [ 'ChangeRequestUUID' ],
    representativeKey: 'ChangeRequestUUID'
}

@VDM.viewType: #COMPOSITE
@AccessControl.personalData.blocking: #REQUIRED
define view I_MRPChangeRequest
  as select from I_MRPRequestNote
  association [0..1] to I_MRPChangeRequestLine as _ChangeRequestLineOriginal  on  $projection.ChangeRequestUUID                    = _ChangeRequestLineOriginal.ChangeRequestUUID
                                                                              and _ChangeRequestLineOriginal.ChangeRequestLineType = '01'
  association [0..1] to I_MRPChangeRequestLine as _ChangeRequestLineRequested on  $projection.ChangeRequestUUID                     = _ChangeRequestLineRequested.ChangeRequestUUID
                                                                              and _ChangeRequestLineRequested.ChangeRequestLineType = '02'

  association [0..1] to I_Plant                as _SupplierPlant              on  $projection.SupplierPlant = _SupplierPlant.Plant
  association [0..1] to I_PurchaseOrder        as _PurchaseOrder              on  $projection.MRPElement = _PurchaseOrder.PurchaseOrder
  association [0..1] to I_Supplier             as _Supplier                   on  $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_Material             as _Material                   on  $projection.Material = _Material.Material
  association [0..*] to I_MRPRequestStatusText as _MRPRequestStatusText       on  $projection.SolutionRequestStatus = _MRPRequestStatusText.DomainValue
  association [0..*] to I_MRPRequestSupplierText as _MRPRequestSupplierText   on  $projection.MRPRequestSupplierResponse = _MRPRequestSupplierText.DomainValue
{
  key ChangeRequestUUID,
      MRPPlant,
      @ObjectModel.foreignKey.association: '_Material'
      Material,
      MRPArea,
      CreationDateTime,
      CreatedByUser,
      GoodsReceiptDuration,
      MRPElement,
      MRPElementItem,
      MRPElementScheduleLine,
      MRPPlanningSegment,
      MRPPlanningSegmentType,
      ChangeRequestNote,
      @ObjectModel.text.association: '_MRPRequestStatusText'
      SolutionRequestStatus,
      _MRPRequestStatusText[1: Language = $session.system_language ].DomainText as SolutionRequestStatusName,
      ChangeRequestType,
      ChangedDateTime,
      LastChangedByUser,
      Supplier,
      SupplierPlant,
      MRPRequestSupplierResponse,
      _MRPRequestSupplierText[1: Language = $session.system_language ].DomainText as MRPRequestSupplierResponseText,
      @Semantics.unitOfMeasure: true
      _Material.MaterialBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      _ChangeRequestLineOriginal.OpenQuantity,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      _ChangeRequestLineOriginal.TotalQuantity                                  as OriginalTotalQuantity,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      _ChangeRequestLineRequested.OpenQuantity                                  as MRPElementChangedOpenQuantity,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      _ChangeRequestLineRequested.TotalQuantity,

      @Semantics.businessDate.at: true
      _ChangeRequestLineOriginal.DeliveryDate                                   as MRPElementAvailyOrRqmtDate,
      @Semantics.businessDate.at: true
      _ChangeRequestLineRequested.DeliveryDate                                  as MRPElementChgAvailyOrRqmtDate,

      @Semantics.name.fullName: true
      case
        when _PurchaseOrder._PurchasingGroup.PurchasingGroupName is not null then _PurchaseOrder._PurchasingGroup.PurchasingGroupName
        else case
            when SupplierPlant is not null then _SupplierPlant._Supplier.SupplierName
            else _Supplier.SupplierName
        end
      end                                                                       as ContactPerson,

      @Semantics.telephone.type:  [ #PREF ]
      case
        when _PurchaseOrder._PurchasingGroup.PurchasingGroupName is not null then _PurchaseOrder._PurchasingGroup.PurchasingGroupPhoneNumber
        else case
            when SupplierPlant is not null then _SupplierPlant._Supplier._StandardAddress.PhoneNumber
            else _Supplier._StandardAddress.PhoneNumber
        end
      end                                                                       as ContactPersonPhoneNumber,

      @Semantics.eMail.address: true
      case
        when _PurchaseOrder._PurchasingGroup.PurchasingGroupName is not null then _PurchaseOrder._PurchasingGroup.EmailAddress
        else case
            when SupplierPlant is not null then _SupplierPlant._Supplier._StandardAddress._DefaultEmailAddress.EmailAddress
            else _Supplier._StandardAddress._DefaultEmailAddress.EmailAddress
        end
      end                                                                       as ContactPersonEmailAddress,

      case
        when SupplierPlant is not null then _SupplierPlant._Supplier.AuthorizationGroup
              else _Supplier.AuthorizationGroup
      end                                                                       as AuthorizationGroup,
      _ChangeRequestLineRequested,
      _ChangeRequestLineOriginal,
      _Material,
      _Material._BaseUnit,
      _MRPRequestStatusText,
      _PurchaseOrder.CompanyCode,
      MRPRequestPriority,
      MRPRequestReason,
      MRPRequestRejection,
      MRPRequestDistributionStatus,
      MRPRequestDistributedDateTime,
      MRPRequestCostOfChangeAmount,
      Currency,
      HasAttachment,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      _Supplier

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_ADDRESSEMAILADDRESS",
"I_MATERIAL",
"I_MRPCHANGEREQUESTLINE",
"I_MRPREQUESTNOTE",
"I_MRPREQUESTSTATUSTEXT",
"I_MRPREQUESTSUPPLIERTEXT",
"I_PLANT",
"I_PURCHASEORDER",
"I_PURCHASINGGROUP",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_MRPCHANGEREQUESTLINE",
"I_MRPREQUESTSTATUSTEXT",
"I_MRPREQUESTSUPPLIERTEXT",
"I_PLANT",
"I_PURCHASEORDER",
"I_SUPPLIER",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_MATERIAL"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/