I_MLPricePersistedPeriod

@AbapCatalog.sqlViewName: 'IMLPRICEPERSPER'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Periods for ML Prices per Currency'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #MIXED

define view I_MLPricePersistedPeriod
  as select from P_MLPricePersistedPeriod as cr
{
  key  CostEstimate,
  key  ValuationArea,
  key  Material,
  key  CurrencyRole,
  key  FiscalYearPeriod,
       CompanyCode,
       MatlPrcMigratedUntilFsclYrPerd
}
 
 union all 
 
  select from I_MaterialLedgerPrice as fmltp
    inner join R_MatlPriceDataMigrationStatus as tf on ( tf.MatlPriceDataMigrationStatus = 'F' ) 
                                                    or ( tf.MatlPriceDataMigrationStatus = 'R' )
    inner join   ckmlhd as hd on hd.kalnr = fmltp.CostEstimate
    inner join   t001k  as tk on tk.bwkey = hd.bwkey
{
  key  fmltp.CostEstimate                                     as CostEstimate,
  key  tk.bwkey                                        as ValuationArea,
  key  hd.matnr                                        as Material,
  key  fmltp.CurrencyRole                              as CurrencyRole,
  key  MatlPrcValdtyStrtFsclYearPerd                   as FiscalYearPeriod,
       tk.bukrs                                        as CompanyCode,
       cast(hd.price_sdm_yearper as fml_yearper_nconv) as MatlPrcMigratedUntilFsclYrPerd
}
where ( ( hd.price_sdm_yearper <> '0000000' and hd.price_sdm_yearper <= fmltp.MatlPrcValdtyStrtFsclYearPerd ) )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALLEDGERPRICE",
"P_MLPRICEPERSISTEDPERIOD",
"R_MATLPRICEDATAMIGRATIONSTATUS",
"CKMLHD",
"T001K"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/