I_MDChgProcessTypeText

@AbapCatalog.sqlViewName: 'IMDCHGPROCTYPT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'MDChgProcessTypeID'
@ObjectModel.usageType: { sizeCategory: #S, dataClass: #CUSTOMIZING, serviceQuality: #C }
@VDM.viewType: #COMPOSITE
@Search.searchable: true
@EndUserText.label: 'MD Change Process Type - Text'
define view I_MDChgProcessTypeText
  as select from I_MDChgProcTypeDescRAPCustom
  association [0..1] to I_Language                 as _Language         on $projection.Language = _Language.Language
  association [1..1] to I_MDChangeProcessTypeUnion as _MDChgProcessType on $projection.MDChgProcessTypeID = _MDChgProcessType.MDChgProcessTypeID
{
  key MDChgProcessTypeID,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language
  key Language,
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #LOW }
      @Semantics.text
      @EndUserText: { label: 'Template Description', quickInfo: 'Template Description' }
      MDChgProcessTypeDesc,

      /* Associations */
      _Language,
      @Consumption.hidden: true
      _MDChgProcessType
}
union select from         I_MDChgProcTypeDescRapBased  as RAPBasedDescription
  left outer to many join I_MDChgProcTypeDescRAPCustom as RapCustomDescription on RAPBasedDescription.MDChgProcessTypeID like '%'
association [0..1] to I_Language                 as _Language         on $projection.Language = _Language.Language
association [1..1] to I_MDChangeProcessTypeUnion as _MDChgProcessType on $projection.MDChgProcessTypeID = _MDChgProcessType.MDChgProcessTypeID
{
  key RAPBasedDescription.MDChgProcessTypeID,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language
  key RAPBasedDescription.Language,
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #LOW }
      @Semantics.text
      @EndUserText: { label: 'Template Description', quickInfo: 'Template Description' }
      RAPBasedDescription.MDChgProcessTypeDesc,

      /* Associations */
      _Language,
      @Consumption.hidden: true
      _MDChgProcessType
}
where
  RAPBasedDescription.MDChgProcessTypeID is null

union select from        I_MDChgProcessTypeDescription as ClassicDescription
  left outer to one join I_MDChgProcTypeDescRapBased   as RAPBasedDescription  on  ClassicDescription.MDChgProcessTypeID = RAPBasedDescription.MDChgProcessTypeID
                                                                               and ClassicDescription.Language           = RAPBasedDescription.Language
  left outer to one join I_MDChgProcTypeDescRAPCustom  as RapCustomDescription on  ClassicDescription.MDChgProcessTypeID = RapCustomDescription.MDChgProcessTypeID
                                                                               and ClassicDescription.Language           = RapCustomDescription.Language
association [0..1] to I_Language                 as _Language         on $projection.Language = _Language.Language
association [1..1] to I_MDChangeProcessTypeUnion as _MDChgProcessType on $projection.MDChgProcessTypeID = _MDChgProcessType.MDChgProcessTypeID
{
  key ClassicDescription.MDChgProcessTypeID,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language
  key ClassicDescription.Language,
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #LOW }
      @Semantics.text
      @EndUserText: { label: 'Template Description', quickInfo: 'Template Description' }
      ClassicDescription.MDChgProcessTypeDesc,

      /* Associations */
      _Language,
      @Consumption.hidden: true
      _MDChgProcessType
}
where
      RAPBasedDescription.MDChgProcessTypeID  is null
  and RapCustomDescription.MDChgProcessTypeID is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MDCHGPROCESSTYPEDESCRIPTION",
"I_MDCHGPROCTYPEDESCRAPBASED",
"I_MDCHGPROCTYPEDESCRAPCUSTOM"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_MDCHANGEPROCESSTYPEUNION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/