I_LogAccMContext

@AbapCatalog.sqlViewName: 'ILOGACCMCONTEXT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.representativeKey: 'LogAccMContextInternalId'
@ObjectModel.semanticKey: [ 'LogAccMContext' ]

@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #MASTER

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC

@EndUserText.label: 'Access Control Context'
define view I_LogAccMContext
  as select from hrp7600

  association [0..*] to I_LogAccMContextText        as _LogAccMContextText        on  $projection.LogAccMContextInternalId = _LogAccMContextText.LogAccMContextInternalId
  association [0..1] to I_User                      as _CreatedByUser             on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                      as _LastChangedByUser         on  $projection.LastChangedByUser = _LastChangedByUser.UserID

  association [0..*] to I_LogAccMSecureIDRepository as _LogAccMSecureIDRepository on  $projection.LogAccMContextInternalId = _LogAccMSecureIDRepository.LogAccMSecureIDOwnerID
  association [0..1] to I_LogAccMObjectTypeActive   as _LogAccMObjectTypeActive   on  _LogAccMObjectTypeActive.LogAccMObjectType = 'PLM_ACC'

  association [0..*] to I_LogAccMObjSecureIDAssgmt  as _LogAccMObjSecureIDAssgmt  on  $projection.LogAccMContextInternalId        = _LogAccMObjSecureIDAssgmt.LogAccMObjectID
                                                                                  and _LogAccMObjSecureIDAssgmt.LogAccMObjectType = 'PLM_ACC'

  association [0..*] to I_LogAccMObjectUserAuthzn   as _LogAccMObjectUserAuthzn   on  $projection.LogAccMContextInternalId             = _LogAccMObjectUserAuthzn.LogAccMObjectID
                                                                                  and _LogAccMObjectUserAuthzn.LogAccMObjectType       = 'PLM_ACC'
                                                                                  and _LogAccMObjectUserAuthzn.LogAccMUserAuthznObject = 'PLM_ACC'
                                                                                  and (
                                                                                     _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom    = '03'
                                                                                     or _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom = '*'
                                                                                   )
                                                                                  and _LogAccMObjectUserAuthzn.LogAccMUserAuthznField  = 'ACTVT'
                                                                                  and (
                                                                                     _LogAccMObjectUserAuthzn.LogAccMUserEntityID      = $session.user
                                                                                     or _LogAccMObjectUserAuthzn.UserID                = $session.user
                                                                                   )
{
  key objid           as LogAccMContextInternalId,
      context_id_ext  as LogAccMContext,
      context_type    as LogAccMContextType,
      is_active       as LogAccMContextIsActivated,
      is_deleted      as LogAccMContextIsDeleted,

      @Semantics.systemDateTime.createdAt: true
      create_datetime as CreationDateTime,

      @Semantics.user.createdBy: true
      create_user_id  as CreatedByUser,

      @Semantics.systemDateTime.lastChangedAt: true
      change_datetime as LastChangeDateTime,

      @Semantics.user.lastChangedBy: true
      change_user_id  as LastChangedByUser,

      /* Associations */

      _LogAccMContextText,
      _LogAccMSecureIDRepository,
      _CreatedByUser,
      _LastChangedByUser,
      _LogAccMObjectTypeActive,
      _LogAccMObjectUserAuthzn,
      _LogAccMObjSecureIDAssgmt

}
where
      plvar = '01'
  and otype = 'CC'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRP7600"
],
"ASSOCIATED":
[
"I_LOGACCMCONTEXTTEXT",
"I_LOGACCMOBJECTTYPEACTIVE",
"I_LOGACCMOBJECTUSERAUTHZN",
"I_LOGACCMOBJSECUREIDASSGMT",
"I_LOGACCMSECUREIDREPOSITORY",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/