I_ListedSubstanceVariant

@AbapCatalog.sqlViewName: 'ILISUVAR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl:
{
  authorizationCheck: #CHECK,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}
@EndUserText.label: 'Listed Substance Variant View'
@ObjectModel.representativeKey: 'ListedSubstanceVariantUUID'
@VDM.viewType: #BASIC

// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE

// Used for BOBF Master Data Object

@ObjectModel.usageType:
{
  serviceQuality: #C,     // < 15 msec

  sizeCategory: #L,       // < 10.000.000

  dataClass: #MASTER
}

// Listed Substance Variants (also called conditions / sub-roots)

// variants are only contained in the delivered listed substance table and can not be created by customers

define view I_ListedSubstanceVariant
  as select from ehfndi_lisu_rt as ListSub
    inner join   ehfndi_lisu_rt as ListSubRef on ListSub.listsub_id_root = ListSubRef.listsub_id

  association [0..*] to I_ListedSubstanceCndnText    as _ConditionText     on  $projection.ListedSubstanceCndn = _ConditionText.ListedSubstanceCndn
  association [0..1] to I_User                       as _CreatedByUser     on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                       as _LastChangedByUser on  $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..*] to I_ListedSubstanceNameText    as _Text              on  $projection.ListedSubstanceVariantUUID = _Text.ListedSubstanceUUID
  association [0..1] to I_ListedSubstanceDefaultName as _DefaultName       on  $projection.ListedSubstanceVariant = _DefaultName.ListedSubstance
{
  key cast( ListSub.db_key as ehfnd_lisu_key_nce preserving type )                 as ListedSubstanceVariantUUID,
      _Text,
      _DefaultName,

      // ID

      ListSub.listsub_id                                                           as ListedSubstanceVariant,
      ListSub.listsub_id_root                                                      as ListedSubstanceReference,
      cast( ListSubRef.db_key as ehfnd_lisu_key_nce preserving type )              as ListedSubstanceUUID,
      @ObjectModel.text.association: '_ConditionText'
      cast( ListSub.condition_code as ehfnd_lisu_cond_code_plain preserving type ) as ListedSubstanceCndn,
      _ConditionText,

      // Identifiers

      cast( ListSub.cas_number as ehfnd_chm_cas_no preserving type )               as CASNumber,
      ListSub.ec_number                                                            as ECNumber,
      ListSub.mol_formula                                                          as MolecularFormula,

      // Admin data

      ListSub.user_id_cr                                                           as CreatedByUser,
      _CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      cast(ListSub.datetime_cr as timestamp preserving type)                       as CreationDateTime,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(ListSub.datetime_ch as timestamp preserving type)                       as LastChangeDateTime,
      ListSub.user_id_ch                                                           as LastChangedByUser,
      _LastChangedByUser
}
where
  ListSub.listsub_id_root <> ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EHFNDI_LISU_RT"
],
"ASSOCIATED":
[
"I_LISTEDSUBSTANCECNDNTEXT",
"I_LISTEDSUBSTANCEDEFAULTNAME",
"I_LISTEDSUBSTANCENAMETEXT",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/