I_LineHierarchy

//@AbapCatalog.sqlViewName: 'IPPLINEHIERARCHY'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true 

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUser', '_LastChangedByUser']
@Analytics.dataCategory: #DIMENSION
//@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'LineHierarchyInternalID'
@ObjectModel.semanticKey: ['LineHierarchy', 'Plant']
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER}
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@Search.searchable: true
@EndUserText.label: 'Line Hierarchy'

define view entity I_LineHierarchy
//define view I_LineHierarchy

  as select from ldlh as ldlh
    inner join   crhd as crhd on  crhd.objid = ldlh.lnid
                              and crhd.objty = 'A'

  association [1..1] to I_Plant               as _Plant             on  $projection.Plant = _Plant.Plant
  association [0..*] to I_LineHierarchyText_2 as _Text              on  $projection.LineHierarchyInternalID = _Text.LineHierarchyInternalID
                                                                    and _Text.WorkCenterTypeCode = 'A'
  association [1..1] to I_User                as _CreatedByUser     on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                as _LastChangedByUser on  $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_UnitOfMeasure       as _RateUnit          on  $projection.LineHierarchyRateUnit = _RateUnit.UnitOfMeasure
{
      // Key

      @ObjectModel.text.association: '_Text'
  key ldlh.lnid                                                   as LineHierarchyInternalID,

      // Attributes

      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      cast(crhd.arbpl as ld_line preserving type)                 as LineHierarchy,
      @ObjectModel.foreignKey.association: '_Plant'
      crhd.werks                                                  as Plant,

      // Administartive

      @Semantics.systemDate.createdAt: true
      ldlh.andat                                                  as CreationDate,
      @Semantics.user.createdBy: true
      cast(ldlh.annam as vdm_createdbyuserid preserving type)     as CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      ldlh.aedat                                                  as LastChangeDate,
      @Semantics.user.lastChangedBy: true
      cast(ldlh.aenam as vdm_lastchangedbyuserid preserving type) as LastChangedByUser,
 
      // Measures

//      @Semantics.unitOfMeasure: true

      ldlh.lunit                                                  as LineHierarchyRateUnit,
--    @Semantics.quantity.unitOfMeasure: 'LineHierarchyRateUnit'
--    @DefaultAggregation: #MAX
--    ldlh.lrate                                                  as MaximumRateQuantity,
 
      // Associations

      _Plant,
      _Text,
      _CreatedByUser,
      _LastChangedByUser,
      _RateUnit
}
where ldlh.zaehl = '00000000';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CRHD",
"LDLH"
],
"ASSOCIATED":
[
"I_LINEHIERARCHYTEXT_2",
"I_PLANT",
"I_UNITOFMEASURE",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/