I_LglCntntMContextBasic

@AbapCatalog.sqlViewName: 'ILCMCONTEXTBASIC'
@AbapCatalog.compiler.compareFilter:true
@AbapCatalog.preserveKey:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType : #BASIC

@ObjectModel: {
  representativeKey: 'LglCntntMContextUUID',
  usageType.serviceQuality: #A,
  usageType.sizeCategory: #L,
  usageType.dataClass: #TRANSACTIONAL
}

@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: [ '_Owner', '_CreatedBy', '_ChangedBy', '_OwnerUserDetails' ]

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@EndUserText.label: 'LCM Context Basic'
define view I_LglCntntMContextBasic
  as select from lcm_context

  association [0..1] to I_LglCntntMGovLaw          as _LglCntntMGovLaw          on  $projection.LglCntntMGovLaw = _LglCntntMGovLaw.LglCntntMGovLaw

  association [0..1] to I_LglCntntMAccessLvlText   as _LglCntntMAccessLvlText   on  $projection.LglCntntMCntxtAccessLvl = _LglCntntMAccessLvlText.LglCntntMAccessLvl
                                                                                and _LglCntntMAccessLvlText.Language    = $session.system_language

  association [0..*] to I_LglCntntMMainOrgTypeText as _LglCntntMMainOrgTypeText on  $projection.LglCntntMMainOrgType = _LglCntntMMainOrgTypeText.LglCntntMMainOrgType
  //                                                                                and Language                         = $session.system_language


  association [0..1] to I_PurchasingOrganization   as _PurchasingOrganization   on  $projection.LglCntntMMainOrgPurOrg = _PurchasingOrganization.PurchasingOrganization

  association [0..*] to I_SalesOrganizationText    as _SalesOrganizationText    on  $projection.LglCntntMMainOrgSalesOrg = _SalesOrganizationText.SalesOrganization

  association [0..1] to I_LglCntntMProfileText     as _LglCntntMProfileText     on  $projection.LglCntntMProfile   = _LglCntntMProfileText.LglCntntMProfile
                                                                                and _LglCntntMProfileText.Language = $session.system_language
  association [0..*] to I_LglCntntMIntegTypeText   as _LglCntntMIntegTypeText   on  $projection.LglCntntMIntegrationType = _LglCntntMIntegTypeText.LglCntntMIntegrationType
  //                                                                                and _LglCntntMIntegTypeText.Language     = $session.system_language


  // ESH associations

  association [1..*] to I_LCMContextParentCategory as _ContextParentCategory    on  $projection.LglCntntMContextUUID = _ContextParentCategory.LglCntntMContextUUID

  association [1..*] to I_LCMContextCategory       as _ContextCategory          on  $projection.LglCntntMContextUUID = _ContextCategory.LglCntntMContextUUID

  association [1..*] to I_LCMContextEntity         as _ContextEntity            on  $projection.LglCntntMContextUUID = _ContextEntity.LglCntntMContextUUID

  association [1..1] to I_LCMContextEntity         as _MainContextEntity        on  $projection.LglCntntMContextUUID         = _MainContextEntity.LglCntntMContextUUID
                                                                                and _MainContextEntity.LglCntntMIsMainEntity = 'X'

  association [0..1] to I_LCMStatusText            as _ContextStatusText        on  $projection.LglCntntMContextStatus = _ContextStatusText.LglCntntMStatus
                                                                                and _ContextStatusText.Language        = $session.system_language

  association [0..1] to I_LanguageText             as _LanguageText             on  $projection.LglCntntMCntxtLanguage = _LanguageText.LanguageCode
                                                                                and _LanguageText.Language             = $session.system_language

  association [0..1] to I_LCMUserAddressAssignment as _Owner                    on  $projection.LglCntntMContextOwner = _Owner.ContactCardID

  association [0..1] to I_LCMUserAddressAssignment as _CreatedBy                on  $projection.LglCntntMCreatedByUser = _CreatedBy.ContactCardID

  association [0..1] to I_LCMUserAddressAssignment as _ChangedBy                on  $projection.LglCntntMChangedByUser = _ChangedBy.ContactCardID

  association [0..1] to I_LglCntntMUserDetails     as _OwnerUserDetails         on  _OwnerUserDetails.ContactCardID = $projection.LglCntntMContextOwner

  association [1..1] to E_LglCntntMContext         as _Extension                on  $projection.LglCntntMContextUUID = _Extension.LglCntntMContextUUID

{

  key lglcntntmcontextuuid          as LglCntntMContextUUID,

      lglcntntmcontext              as LglCntntMContext,

      lglcntntmcontextversion       as LglCntntMContextVersion,

      @Semantics.text: true
      lglcntntmcontexttitle         as LglCntntMContextTitle,

      lglcntntmcontextstatus        as LglCntntMContextStatus,

      lglcntntmstsprfl              as LglCntntMStsPrfl,

      lglcntntmcontextowner         as LglCntntMContextOwner,

      lglcntntmcreatedbyuser        as LglCntntMCreatedByUser,

      lglcntntmcreatedutcdatetime   as LglCntntMCreatedUTCDateTime,

      lglcntntmchangedutcdatetime   as LglCntntMChangedUTCDateTime,

      lglcntntmchangedbyuser        as LglCntntMChangedByUser,

      @Semantics.businessDate.from: true
      lglcntntmcontextvalidfromdate as LglCntntMContextValidFromDate,

      @Semantics.businessDate.to: true
      lglcntntmcontextvalidtodate   as LglCntntMContextValidToDate,

      lglcntntmcntxtlanguage        as LglCntntMCntxtLanguage,

      lglcntntmprevcntxtvers        as LglCntntMPrevCntxtVers,

      lglcntntmcntxtisreadonly      as LglCntntMCntxtIsReadOnly,

      @ObjectModel.text.association: '_LglCntntMProfileText'
      lglcntntmprofile              as LglCntntMProfile,

      @Semantics.booleanIndicator: true
      isendofpurposeblocked         as IsEndOfPurposeBlocked,

      lglcntntmgovlaw               as LglCntntMGovLaw,

      @ObjectModel.text.association: '_LglCntntMAccessLvlText'
      lglcntntmcntxtaccesslvl       as LglCntntMCntxtAccessLvl,

      @ObjectModel.text.association: '_LglCntntMMainOrgTypeText'
      lglcntntmmainorgtype          as LglCntntMMainOrgType,

      lglcntntmmainorgcocode        as LglCntntMMainOrgCoCode,

      lglcntntmmainorgsalesorg      as LglCntntMMainOrgSalesOrg,

      lglcntntmmainorgpurorg        as LglCntntMMainOrgPurOrg,

      lglcntntmlongtextuuid         as LglCntntMLongTextUUID,

      @ObjectModel.text.association: '_LglCntntMIntegTypeText'
      lglcntntmintegrationtype      as LglCntntMIntegrationType,

      _LglCntntMGovLaw,

      _LglCntntMAccessLvlText,

      _LglCntntMMainOrgTypeText,

      _PurchasingOrganization,

      _SalesOrganizationText,

      _LglCntntMProfileText,

      _LglCntntMIntegTypeText,

      _ContextParentCategory,

      _ContextCategory,

      _ContextEntity,

      _MainContextEntity,

      _ContextStatusText,

      _LanguageText,

      _Owner,

      _CreatedBy,

      _ChangedBy,

      _OwnerUserDetails

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"LCM_CONTEXT"
],
"ASSOCIATED":
[
"E_LGLCNTNTMCONTEXT",
"I_LANGUAGETEXT",
"I_LCMCONTEXTCATEGORY",
"I_LCMCONTEXTENTITY",
"I_LCMCONTEXTPARENTCATEGORY",
"I_LCMSTATUSTEXT",
"I_LCMUSERADDRESSASSIGNMENT",
"I_LGLCNTNTMACCESSLVLTEXT",
"I_LGLCNTNTMGOVLAW",
"I_LGLCNTNTMINTEGTYPETEXT",
"I_LGLCNTNTMMAINORGTYPETEXT",
"I_LGLCNTNTMPROFILETEXT",
"I_LGLCNTNTMUSERDETAILS",
"I_PURCHASINGORGANIZATION",
"I_SALESORGANIZATIONTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/