I_LegalTransactionStartedTasks

@AbapCatalog.sqlViewName: 'ILTSTARTT'

@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck:#CHECK
@VDM.viewType : #COMPOSITE

@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel: {
  representativeKey: 'LegalTransactionTask',
  usageType.serviceQuality: #C,
  usageType.sizeCategory: #XL,
  usageType.dataClass: #TRANSACTIONAL
}
@AbapCatalog.compiler.compareFilter:true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@EndUserText.label: 'Basic View for Started Tasks of Legal Transaction'
define view I_LegalTransactionStartedTasks
  as select from I_LegalTransactionWorkflow

    join         I_WorkflowTaskApplObject as WorkflowTaskApplObject on  I_LegalTransactionWorkflow.LglTransWrkFlwModInstce   = WorkflowTaskApplObject.SAPBusinessObjectNodeKey1
                                                                    and WorkflowTaskApplObject.WorkflowObjectRole            = '99'
    //                                                                  SAP node type after 2008

                                                                    and (
                                                                       WorkflowTaskApplObject.SAPObjectNodeRepresentation    = 'LegalTransactionApproval'
                                                                       //                                                                  SAP node type before 2008

                                                                       or WorkflowTaskApplObject.SAPObjectNodeRepresentation = 'LegalTransaction'
                                                                     )
                                                                    and WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'
                                                                    and WorkflowTaskApplObject.WorkflowTaskInternalID        is not null

  association [1..1] to I_LglTransWorkflowTaskTitle as _LglTransWorkflowTaskTitle on $projection.WorkflowTaskInternalID = _LglTransWorkflowTaskTitle.WorkflowTaskInternalID


  association [1..1] to I_LglCntntMWorkflowTask     as _WorkflowTask              on $projection.WorkflowTaskInternalID = _WorkflowTask.WorkflowTaskInternalID
                                                                                  and(
                                                                                    _WorkflowTask.WorkflowTaskType      = 'W'
                                                                                    or _WorkflowTask.WorkflowTaskType   = 'B'
                                                                                  )
  association [0..1] to I_LglCntntMWrkflwStpAgtRole as _LglCntntMWrkflwStpAgtRole on $projection.WorkflowTaskProcessorRole = _LglCntntMWrkflwStpAgtRole.RespyMgmtContextAgentDetnRule
                                                                                  or $projection.WorkflowTaskProcessorRole = _LglCntntMWrkflwStpAgtRole.RespyMgmtOldAgentDetnRule

{
  key  I_LegalTransactionWorkflow.LegalTransactionUUID,
  key  cast(WorkflowTaskApplObject.WorkflowTaskInternalID as lcm_sww_wiid)                                                    as LegalTransactionTask,
       WorkflowTaskApplObject.WorkflowTaskInternalID                                                                          as WorkflowTaskInternalID, //WorkflowTask,

       I_LegalTransactionWorkflow.LglTransWrkFlwModInstce,
       I_LegalTransactionWorkflow.LegalTransactionWrkflwSqnc,
       I_LegalTransactionWorkflow.LglCntntMTaskGroupName,

       _WorkflowTask.WorkflowTaskProcessorRole                                                                                as WorkflowTaskProcessorRole,

       _WorkflowTask.WorkflowTaskStatus                                                                                       as LegalTransactionTaskStatus,

       _WorkflowTask.WorkflowTaskCreatedByUser                                                                                as LegalTransactionTaskCrtedByUsr,

       _WorkflowTask.WorkflowTaskCurrentUser                                                                                  as LegalTransactionTaskCurUsr,

       _WorkflowTask.WorkflowTaskDefinition                                                                                   as LglCntntMTaskDefinition,

       _WorkflowTask.WorkflowTaskStepType                                                                                     as LegalTransactionTaskType,

       @ObjectModel.readOnly: true
       _WorkflowTask.WrkflwTskCreationUTCDateTime                                                                             as LglTransTskCrtnUTCDteTme,

       @ObjectModel.readOnly: true
       _WorkflowTask.WrkflwTskCompletionUTCDateTime                                                                           as LglCntntMTaskCompltnUTCDteTme,

       @Semantics.text: true
       _WorkflowTask._WorkflowStepType._WorkflowTaskStepTypeText[1:Language=$session.system_language].WorkflowStepTypeSubject as LegalTransactionTaskTypeName,

       @Semantics.text: true
       _WorkflowTask._TaskStatus._Text[1:Language=$session.system_language].WorkflowTaskStatusDesc                            as LegalTransactionTaskStatusName,

       //              _WorkflowTask._WorkflowTaskStepResult.WorkflowStepResultNature                                                         as WorkflowStepResultNature,


       //Required for association

       @VDM.lifecycle.status: #DEPRECATED
       @VDM.lifecycle.successor: 'WorkflowTaskInternalID'
       cast( _WorkflowTask.WorkflowTaskInternalID as mlst_task )                                                              as WorkflowTask,

       _WorkflowTask.TopLevelWorkflowTaskDefinition                                                                           as TopLevelWorkflowTaskDefinition,

       _WorkflowTask.WorkflowTaskDefinitionVersion                                                                            as WorkflowTaskDefinitionVersion,
       _WorkflowTask.WorkflowTaskStepType                                                                                     as WorkflowTaskStepType,
       _WorkflowTask.WorkflowTaskStatus                                                                                       as WorkflowTaskStatus,
       _WorkflowTask.WorkflowTaskResult                                                                                       as WorkflowTaskResult,

       _WorkflowTask._WorkflowStepType,
       _WorkflowTask._TaskStatus,
       _LglTransWorkflowTaskTitle,
       I_LegalTransactionWorkflow._LegalTransaction,
       _LglCntntMWrkflwStpAgtRole

}
where
       I_LegalTransactionWorkflow.LglTransWrkFlwModInstce <> ''
  and(
       _WorkflowTask.WorkflowTaskType                     =  'W'
    or _WorkflowTask.WorkflowTaskType                     =  'B'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LEGALTRANSACTIONWORKFLOW",
"I_LGLCNTNTMWORKFLOWTASK",
"I_WORKFLOWSTEPTYPE",
"I_WORKFLOWSTEPTYPETEXT",
"I_WORKFLOWTASKAPPLOBJECT",
"I_WORKFLOWTASKSTATUS",
"I_WORKFLOWTASKSTATUSTEXT"
],
"ASSOCIATED":
[
"I_LEGALTRANSACTION",
"I_LGLCNTNTMWORKFLOWTASK",
"I_LGLCNTNTMWRKFLWSTPAGTROLE",
"I_LGLTRANSWORKFLOWTASKTITLE",
"I_WORKFLOWSTEPTYPE",
"I_WORKFLOWTASKSTATUS"
],
"BASE":
[
"I_LEGALTRANSACTIONWORKFLOW",
"I_LGLCNTNTMWORKFLOWTASK"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/