I_LU_SAFTGenLdgrTaxReportLine

@AbapCatalog.sqlViewName: 'ILUSAFTGLTAXRLI'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'SAFT LU Gnrl Ledger Tax Reporting Line'
define view I_LU_SAFTGenLdgrTaxReportLine
  as select from           I_OperationalAcctgDocItem as GLEntries
    inner join             I_LU_SAFTGenericSettings  as GenSet  on  GenSet.CompanyCode    =  GLEntries.CompanyCode
                                                                and GenSet.FiscalYearFrom <= GLEntries.FiscalYear
    left outer to one join I_LU_SAFTSpecialGLTax     as SpGLTax on  GLEntries.SpecialGLCode        = SpGLTax.SpecialGLCode
                                                                and GLEntries.FinancialAccountType = SpGLTax.FinancialAccountType
{
  key GLEntries.CompanyCode                                                     as CompanyCode,
  key GLEntries.FiscalYear                                                      as FiscalYear,
  key GLEntries.AccountingDocument                                              as AccountingDocument,
  key GLEntries.LedgerGLLineItem                                                as LedgerGLLineItem,
  key GLEntries.AccountingDocumentItem,
      GLEntries.PostingDate,
      GLEntries.TaxCode,

      GLEntries._JournalEntry.AbsoluteExchangeRate                              as ExchangeRate,
      @Semantics.currencyCode: true
      GLEntries.CompanyCodeCurrency,

      case GLEntries.IsNegativePosting  when 'X' then
        case GLEntries.DebitCreditCode  when 'S' then 'H'
                                        when 'H' then 'S'
                     end
            when ' ' then  GLEntries.DebitCreditCode
            else GLEntries.DebitCreditCode
      end                                                                       as DebitCreditCode,

      GLEntries._CompanyCode._Country.TaxCalculationProcedure,
      GLEntries.TransactionTypeDetermination,
      GLEntries.FinancialAccountType,

      @Semantics.currencyCode: true
      GLEntries.TransactionCurrency,

      GLEntries.AmountInCompanyCodeCurrency,
      GLEntries.AmountInTransactionCurrency,
      GLEntries.AccountingDocumentItemType,
      GLEntries.AccountingDocumentType,
      cast(case when (GLEntries.TaxRateValidityStartDate is initial or GLEntries.TaxRateValidityStartDate is null)
      then '  '
      else
      substring (GLEntries.TaxRateValidityStartDate,5,2) end as abap.numc( 2 )) as TaxRateValidityMonth,

      cast(case when (GLEntries.TaxRateValidityStartDate is initial or GLEntries.TaxRateValidityStartDate is null)
      then ''
      else
      substring (GLEntries.TaxRateValidityStartDate,7,2) end as abap.numc( 2 )) as TaxRateValidityDay,

      @Semantics.booleanIndicator: true
      case when SpGLTax.SpecialGLCode is initial or
               SpGLTax.SpecialGLCode is null
       then ' '
      else 'X' end                                                              as CAIsDownPaymentRequest,

      GLEntries.TaxAmount,
      GLEntries.TaxAmountInCoCodeCrcy,

      GLEntries._CompanyCodeCurrency
}
where

  (

        GLEntries.AccountingDocumentItemType <> 'T'
    and GLEntries.TaxCode                    <> ''
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_COUNTRY",
"I_JOURNALENTRY",
"I_LU_SAFTGENERICSETTINGS",
"I_LU_SAFTSPECIALGLTAX",
"I_OPERATIONALACCTGDOCITEM"
],
"ASSOCIATED":
[
"I_CURRENCY"
],
"BASE":
[
"I_OPERATIONALACCTGDOCITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/