I_LU_SAFTAdditionalZeroLine

@AbapCatalog.sqlViewName: 'ILUSAFTADDZEROL'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'SAFT LU Additional VAT Zero Line'
define view I_LU_SAFTAdditionalZeroLine
  as select from P_LU_SAFTZeroTaxLine        as Journal

    inner join   P_LU_SAFTIsAlternateAccount as AlternateAccount on AlternateAccount.CompanyCode = Journal.CompanyCode

    inner join   I_GLAccountInCompanyCode    as TaxGLAccount     on  TaxGLAccount.GLAccount   = Journal.ActiveGLAccount
                                                                 and TaxGLAccount.CompanyCode = Journal.CompanyCode
{

  key Journal.CompanyCode                                                                              as CompanyCode,
  key Journal.FiscalYear                                                                               as FiscalYear,
  key Journal.AccountingDocument                                                                       as AccountingDocument,

  key concat( substring(Journal.LedgerGLLineItem, 4,3) , Journal.TaxItem )                             as LedgerGLLineItem,
      Journal.PostingDate,
      Journal.AmountInCompanyCodeCurrency,

      Journal.AccountingDocumentType                                                                   as JournalEntryType,
      Journal.Ledger,
      Journal.TaxCalculationProcedure,
      Journal.FinancialAccountType,
      Journal.TransactionCurrency,
      cast( 0 as abap.curr(8,2))                                                                       as DebitAmountInCoCodeCrcy,
      cast( 0 as abap.curr(8,2))                                                                       as CreditAmountInCoCodeCrcy,

      cast(case when AlternateAccount.IsAltAcct is not initial
      then concat(TaxGLAccount.CompanyCode, concat('_', Journal.ActiveGLAccount))
      else concat(TaxGLAccount.CompanyCode, concat('_', TaxGLAccount.GLAccount)) end as abap.char(70)) as SAFTGeneralLedgerAccountID,

      case
        when AlternateAccount.IsAltAcct is initial
          then Journal.ActiveGLAccount
          else TaxGLAccount.AlternativeGLAccount
      end                                                                                              as GLAccount,

      Journal.AccountingDocumentItemType,
      Journal.CompanyCodeCurrency,
      Journal.TaxCode,
      Journal.DebitCreditCode,
      Journal.DocumentItemText                                                                         as DocumentItemText,

      Journal._CompanyCodeCurrency

}

where
  Journal.TaxAmount = 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_GLACCOUNTINCOMPANYCODE",
"P_LU_SAFTISALTERNATEACCOUNT",
"P_LU_SAFTZEROTAXLINE"
],
"ASSOCIATED":
[
"I_CURRENCY"
],
"BASE":
[
"P_LU_SAFTZEROTAXLINE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/