I_JrnlPeriodEndClosingRunLog

@AbapCatalog.sqlViewName: 'IFICLSRUNLOG'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Log entries for period end closing runs'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
                usageType.serviceQuality: #B,
                usageType.sizeCategory: #XXL,
                usageType.dataClass: #TRANSACTIONAL }
@VDM.viewType: #BASIC


define view I_JrnlPeriodEndClosingRunLog
  as select from fins_cls_run
  association [1..1] to I_BusinessTransactionCategory    as _BusinessTransactionCategory on  $projection.BusinessTransactionCategory = _BusinessTransactionCategory.BusinessTransactionCategory
  association [0..1] to I_BusinessTransactionType        as _BusinessTransactionType     on  $projection.BusinessTransactionType = _BusinessTransactionType.BusinessTransactionType
  association [0..*] to I_FinClsgRunExecStatusText       as _FinClsgRunExecStatusText    on  $projection.FinClosingRunExecutionStatus = _FinClsgRunExecStatusText.FinClosingRunExecutionStatus
  association [0..*] to I_FinClsgProcessingOptionText    as _FinClsgProcessingOptionText on  $projection.FinClosingRunIsTestExecution = _FinClsgProcessingOptionText.FinClosingRunIsTestExecution
  association [0..*] to I_BusTransactionCategoryText     as _BusTransactionCategoryText  on  $projection.BusinessTransactionCategory = _BusTransactionCategoryText.BusinessTransactionCategory
  association [0..1] to I_CompanyCode                    as _CompanyCode                 on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..*] to I_LedgerText                     as _LedgerText                  on  $projection.Ledger      = _LedgerText.Ledger
  association [1..1] to I_Ledger                         as _Ledger                      on  $projection.Ledger = _Ledger.Ledger
//  association [1..*] to ZC_AnalyzeClsgRunGLAcctInfo      as _GLAccountInfo               on  $projection.JrnlPeriodEndClosingRunLogUUID = _GLAccountInfo.JrnlPeriodEndClosingRunLogUUID

//                                                                                         and $projection.Ledger = _GLAccountInfo.Ledger                                                                     

                                                                                                                                                                               
{
  key jrnlperiodendclosingrunloguuid as JrnlPeriodEndClosingRunLogUUID,
//      bintohex(jrnlperiodendclosingrunloguuid) as JrnlPeriodEndClosin,

      jrnlperiodendclosingrunlogid   as JrnlPeriodEndClosingRunLogID,
      @ObjectModel.foreignKey.association: '_BusinessTransactionCategory'
      businesstransactioncategory    as BusinessTransactionCategory,
      @ObjectModel.foreignKey.association: '_BusinessTransactionType'
      businesstransactiontype        as BusinessTransactionType,
      financialclosingruntype        as FinancialClosingRunType,
      financialclosingstep           as FinancialClosingStep,
      @Semantics.dateTime: true
      jrnlperdendclsgruncrtndtetime  as JrnlPerdEndClsgRunCrtnDteTime,
      @Semantics.dateTime: true
      run_time_end                   as JrnlPerdEndClsgRunEndDateTime,
      @Semantics.dateTime: true
      jrnlperdendclsgrunchgddatetime as JrnlPerdEndClsgRunChgdDateTime,
      jrnlperdendclsgruncrtedbyuser  as JrnlPerdEndClsgRunCrtedByUser,
      jrnlperdendclsgrunchgdbyuser   as JrnlPerdEndClsgRunChgdByUser,
      finclsgrunconfignjsonstring    as FinClsgRunConfignJSONString,
      finclsgruninputparamjsonstr    as FinClsgRunInputParamJSONStr,
      finclosingrunexecutionstatus   as FinClosingRunExecutionStatus,
      finclosingrunbatchjobname      as FinClosingRunBatchJobName,
      financialclosingrunbatchjob    as FinancialClosingRunBatchJob,
      finclosingrunistestexecution   as FinClosingRunIsTestExecution,
      companycode                    as CompanyCode,
      ledger                         as Ledger,
      fiscalyear                     as FiscalYear,
      fiscalperiod                   as FiscalPeriod,
      
      cast( concat( fiscalyear, fiscalperiod ) as fins_fyearperiod ) as FiscalYearPeriod,
      
      keydate                        as KeyDate,
      duration                       as FinancialClosingRunDuration,
      number_obj_ok                  as NmbrOfSuccssflObjectsInClsgRun,
      number_obj_fail                as NmbrOfFailedObjectsInClsgRun,
      msg_cnt_e                      as NumberOfErrorMessages,
      msg_cnt_w                      as NumberOfWarningMessages,

      _BusinessTransactionType,
      _BusinessTransactionCategory,
      _FinClsgRunExecStatusText,
      _FinClsgProcessingOptionText,
      _BusTransactionCategoryText,
      _CompanyCode,
      _LedgerText,
      _Ledger
//     @ObjectModel.association.type: #TO_COMPOSITION_CHILD

//      _GLAccountInfo

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FINS_CLS_RUN"
],
"ASSOCIATED":
[
"I_BUSINESSTRANSACTIONCATEGORY",
"I_BUSINESSTRANSACTIONTYPE",
"I_BUSTRANSACTIONCATEGORYTEXT",
"I_COMPANYCODE",
"I_FINCLSGPROCESSINGOPTIONTEXT",
"I_FINCLSGRUNEXECSTATUSTEXT",
"I_LEDGER",
"I_LEDGERTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/