I_JointVentureOrderData

@AbapCatalog.sqlViewName: 'IJVORDDATA'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #L,
  dataClass: #MIXED
  }
@EndUserText.label: 'Joint Venture Order Data'

define view I_JointVentureOrderData
  as select from aufk
    inner join   I_JointVentureCompanyCodeVH as _JVCompanyCode on aufk.bukrs = _JVCompanyCode.CompanyCode
  association [0..1] to I_ControllingArea             as _ControllingArea             on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_CompanyCode                 as _CompanyCode                 on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_JointVentureMasterFld       as _JointVentureMasterFld       on  $projection.CompanyCode  = _JointVentureMasterFld.CompanyCode
                                                                                      and $projection.JointVenture = _JointVentureMasterFld.JointVenture
  association [0..1] to I_JointVentureOrderInSuspense as _JointVentureOrderInSuspense on  $projection.CompanyCode   = _JointVentureOrderInSuspense.CompanyCode
                                                                                      and $projection.InternalOrder = _JointVentureOrderInSuspense.InternalOrder
  association [0..1] to I_JntVntrRecoveryInd          as _JntVntrRecoveryInd          on  $projection.CompanyCode              = _JntVntrRecoveryInd.CompanyCode
                                                                                      and $projection.JointVentureRecoveryCode = _JntVntrRecoveryInd.JointVentureRecoveryCode
  association [1..1] to I_JntVntrEquityTypeMaster     as _JntVntrEquityType           on  $projection.CompanyCode            = _JntVntrEquityType.CompanyCode
                                                                                      and $projection.JointVentureEquityType = _JntVntrEquityType.JointVentureEquityType
  association [0..1] to I_JntIntrstBillgClass         as _JntIntrstBillgClass         on  $projection.CompanyCode         = _JntIntrstBillgClass.CompanyCode
                                                                                      and $projection.JntIntrstBillgClass = _JntIntrstBillgClass.JntIntrstBillgClass
  association [0..1] to I_JntIntrstBillgSubclass      as _JntIntrstBillgSubclass      on  $projection.CompanyCode            = _JntIntrstBillgSubclass.CompanyCode
                                                                                      and $projection.JntIntrstBillgClass    = _JntIntrstBillgSubclass.JntIntrstBillgClass
                                                                                      and $projection.JntIntrstBillgSubClass = _JntIntrstBillgSubclass.JntIntrstBillgSubClass
  association [0..1] to I_JointVentureSuspenseText    as _JointVentureSuspenseText    on  $projection.JointVentureOrdIsSuspended = _JointVentureSuspenseText.JntVntrSuspenseStatus
                                                                                      and _JointVentureSuspenseText.Language = $session.system_language
  association [0..1] to I_OrderCategory               as _OrderCategory               on  $projection.OrderCategory = _OrderCategory.OrderCategory
  association [0..1] to I_OrderType                   as _OrderType                   on  $projection.OrderType = _OrderType.OrderType
  association [0..1] to I_Order                       as _ReferenceOrder              on  $projection.ReferenceOrder= _ReferenceOrder.OrderID
{
      @ObjectModel.text.element: ['InternalOrderDescription']
  key aufk.aufnr                                                                                                as InternalOrder,
      @Semantics.text: true
      cast(aufk.ktext as fis_internalorder_text preserving type )                                               as InternalOrderDescription,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      cast(aufk.kokrs as fis_kokrs preserving type )                                                            as ControllingArea,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      aufk.bukrs                                                                                                as CompanyCode,
      @ObjectModel.foreignKey.association: '_JointVentureMasterFld'
      cast( aufk.vname as jv_name_cds preserving type )                                                         as JointVenture,
      @ObjectModel.foreignKey.association: '_JntVntrRecoveryInd'
      aufk.recid                                                                                                as JointVentureRecoveryCode,
      @ObjectModel.foreignKey.association: '_JntVntrEquityType'
      aufk.etype                                                                                                as JointVentureEquityType,
      @ObjectModel.foreignKey.association: '_JntIntrstBillgClass'
      aufk.jv_jibcl                                                                                             as JntIntrstBillgClass,
      @ObjectModel.foreignKey.association: '_JntIntrstBillgSubclass'
      aufk.jv_jibsa                                                                                             as JntIntrstBillgSubClass,
      aufk.jv_oco                                                                                               as JointVentureOriginalCostObject,
      aufk.otype                                                                                                as JointVentureObjectType,
      // Category and Type

      @ObjectModel.foreignKey.association: '_OrderCategory'
      cast(aufk.autyp as pph_autyp preserving type)                                                             as OrderCategory,
      @ObjectModel.foreignKey.association: '_OrderType'
      cast(aufk.auart as aufart    preserving type)                                                             as OrderType,
      @ObjectModel.foreignKey.association: '_ReferenceOrder'
      cast(aufk.refnr as fis_aufrefnr preserving type)                                                          as ReferenceOrder,

      // Order Suspense Info //

      @ObjectModel.text.association: '_JointVentureSuspenseText'
      cast( _JointVentureOrderInSuspense.JointVentureOrdIsSuspended as jv_suspense_status_cds preserving type ) as JointVentureOrdIsSuspended,
      _JointVentureOrderInSuspense.JointVentureOrdSuspensePerd,
      _JointVentureOrderInSuspense.JointVentureOrdSuspenseYear,
      _JointVentureOrderInSuspense.JointVentureOrdIsNotSuspended,
      _JointVentureOrderInSuspense.JointVentureOrdNotSuspensePerd,
      _JointVentureOrderInSuspense.JointVentureOrdNotSuspenseYear,

      _ControllingArea,
      _CompanyCode,
      _JointVentureMasterFld,
      _JointVentureOrderInSuspense,
      _JntVntrRecoveryInd,
      _JntVntrEquityType,
      _JntIntrstBillgClass,
      _JntIntrstBillgSubclass,
      _JointVentureSuspenseText,
      _OrderCategory,
      _OrderType,
      _ReferenceOrder 
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOINTVENTURECOMPANYCODEVH",
"I_JOINTVENTUREORDERINSUSPENSE",
"AUFK"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_JNTINTRSTBILLGCLASS",
"I_JNTINTRSTBILLGSUBCLASS",
"I_JNTVNTREQUITYTYPEMASTER",
"I_JNTVNTRRECOVERYIND",
"I_JOINTVENTUREMASTERFLD",
"I_JOINTVENTUREORDERINSUSPENSE",
"I_JOINTVENTURESUSPENSETEXT",
"I_ORDER",
"I_ORDERCATEGORY",
"I_ORDERTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/