I_JobText

@AbapCatalog.sqlViewName: 'IJOBTEXT'
@VDM.viewType:  #BASIC
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Job text'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'Job'

define view I_JobText
  as select distinct from t513s          as old
    left outer join       wfd_d_new_pers as switch on old.mandt = switch.mandt
  association [0..1] to I_Language as _Language on old.sprsl = _Language.Language
{
  key stell as Job,
  key begda as StartDate,
  key endda as EndDate,
      @Semantics.language
  key sprsl as Language,
      @Semantics.text: true
      stltx as JobName,
      _Language
}
where
     switch.switch is null
  or switch.switch <> 'NEW'

union all select from wfd_d_jobcodet as new
  inner join          wfd_d_new_pers as switch on new.client = switch.mandt
association [0..1] to I_Language as _Language on $projection.Language = _Language.Language

{
  key job_code                                                         as Job,
      start_date                                                       as StartDate,
      end_date                                                         as EndDate,
      @Semantics.language
  key coalesce(  cast ($session.system_language as langu ), language ) as Language,
      @Semantics.text: true
      job_title                                                        as JobName,
      _Language
}
where
  switch.switch = 'NEW'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T513S",
"WFD_D_JOBCODET",
"WFD_D_NEW_PERS"
],
"ASSOCIATED":
[
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0
}
}*/