I_JntVntrCoCodeParam

@AbapCatalog.sqlViewName: 'IJVCOPARAM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'JV Company Code Global Parameters'
@VDM.viewType: #BASIC
@ObjectModel:{
 representativeKey: 'CompanyCode',
 usageType:{ dataClass: #CUSTOMIZING,
             sizeCategory: #M,
             serviceQuality: #B
           }   }
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

define view I_JntVntrCoCodeParam
  as select from t8jz
  association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode  
  association [1..1] to t8js          as _t8js        on t8jz.bstruct = _t8js.bstruct
  association [0..1] to I_Ledger      as _Ledger      on $projection.Ledger = _Ledger.Ledger
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key bukrs      as CompanyCode,
      itd        as JntVntrInceptionToDateBillg,
      int_us     as JointVentureRegion,
      opaccnumb  as Operator,
      corpvent   as JointVentureCorporate,
      corpeqgp   as JointVentureCorporateEquityGrp,
      corprecind as JVACorpFundedRcvryCode,
      corpvbacri as JVAVentureFundedCorpRcvryCode,
      taxin      as TaxCode,
      taxout     as JntVntrOutTaxCode,
      txjcd      as JntVntrTaxJurisdiction,
      xsetcon    as JntVntrConstructionExclsnSet,
      xsetcat    as JntVntrCatastropheExclsnSet,
      xper1      as JVAExclsnAcctSetPercentProdg,
      xper2      as JVAExclsnAcctSetPercentDev,
      xsetcap    as JntVntrCapitalExclsnSet,
      noncomp    as JntVntrNonCompulsoryRate,
      
      @ObjectModel.foreignKey.association: '_Ledger'
      rldnr      as Ledger,
     
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_Currency'
      _CompanyCode.Currency,

      @Semantics: { amount : { currencyCode: 'Currency'} }
      billthres  as JntVntrBillgThldDebit,
      @Semantics: { amount : { currencyCode: 'Currency'} }
      billthresc as JntVntrBillgThldCredit,
      _t8js.invlevel as InvoicingLevel,
      _CompanyCode,
      _CompanyCode._Currency,
      _Ledger
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"T8JS",
"T8JZ"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_LEDGER",
"T8JS"
],
"BASE":
[
"I_COMPANYCODE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/