I_JITOutbCallHeader

@AbapCatalog.sqlViewName: 'IJITOUTBHDR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@ClientHandling:{
     type: #INHERITED,
     algorithm: #SESSION_VARIABLE
   }
@Analytics.internalName:#LOCAL
@AccessControl:{
   authorizationCheck: #NOT_REQUIRED,
   personalData.blocking: #NOT_REQUIRED
   }
@ObjectModel.representativeKey: 'InternalJITCallNumber'
@Metadata.allowExtensions:true
@ObjectModel: {
    usageType.dataClass: #TRANSACTIONAL,
    usageType.serviceQuality: #B,
    usageType.sizeCategory: #L
}

@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@EndUserText.label: 'JustIn Time header basic view'
@Analytics.dataCategory: #DIMENSION

define view I_JITOutbCallHeader
  as select from njit_call_d_hdr
  association [1..*] to I_JITOutbCallCompGrp        as _JITOutbCallCompGroup      on  $projection.JITHeaderUUID         = _JITOutbCallCompGroup.ParentDraftKey
                                                                                  and $projection.InternalJITCallNumber = _JITOutbCallCompGroup.InternalJITCallNumber

  association [0..1] to I_JITLifecycleStatus        as _JITLifecycleStatus        on  $projection.JITLifecycleStatus = _JITLifecycleStatus.JITLifecycleStatus

  association [0..1] to I_JITCallType               as _JITCallType               on  $projection.JITCallType = _JITCallType.JITCallType

  association [0..1] to I_UserContactCard           as _CreatedByUser             on  $projection.CreatedByUser = _CreatedByUser.ContactCardID

  association [0..1] to I_UserContactCard           as _LastChangedByUser         on  $projection.LastChangedByUser = _LastChangedByUser.ContactCardID

  association [0..1] to I_JITCallCreationMode       as _JITCallCreationMode       on  $projection.JITCallCreationMode = _JITCallCreationMode.JITCallCreationMode
  association [0..1] to I_DeliveryPriority          as _DeliveryPriority          on  $projection.JITCallPriorityID = _DeliveryPriority.DeliveryPriority
  association [0..1] to I_JITOutbMissingFlag        as _JITOutbMissingPartFlag    on $projection.JITMissingPartFlag    = _JITOutbMissingPartFlag.JITMaterialStockIsMissing


{
  key db_key                           as JITHeaderUUID,
  key int_call_num                     as InternalJITCallNumber,
      ext_call_num                     as ExternalJITCallNumber,
      kunnr                            as ShipToParty,
      cast( kunag as abap.char(10) )   as SoldToParty,
      @ObjectModel.foreignKey.association: '_JITLifecycleStatus'
      lifecycle_stat                   as JITLifecycleStatus,
      @ObjectModel.foreignKey.association: '_JITCallType'
      call_type                        as JITCallType,
      vhvin                            as VehicleIdentificationNumber,
      vhcle_model                      as VehicleModel,
      vkorg                            as SalesOrganization,
      vtweg                            as DistributionChannel,
      spart                            as Division,
      ablad                            as UnloadingPointName,
      knref                            as CustomerPartnerDescription,
      abrvw                            as MatlUsageIndicator,
      cast( lifnr as abap.char( 10 ) ) as ActiveSupplier,
      log_severity                     as ApplLogHighestMessageSeverity,
      immediate_request                as JITCallImmediateRequest,
      @ObjectModel.foreignKey.association: '_JITOutbMissingPartFlag'
      missing_parts                    as JITMissingPartFlag,
      priority_type                    as JITCallPriorityType,
      priority_id                      as JITCallPriorityID,
      concat('JIT-TOLR',int_call_num)  as JITCallProcessingLogID,
      int_sequence_num                 as JITIntSequenceNumber,
      ext_sequence_num                 as JITExtSequenceNumber,
      call_creation_mode               as JITCallCreationMode,
      planned_order                    as JITPlannedOrderNumber,
      sequence_date                    as JITVehicleSeqDateTime,
      // Administrative Data

      @Semantics.systemDateTime.createdAt: true
      crea_date_time                   as CreationDateTime,
      @Semantics.user.createdBy: true
      crea_uname                       as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      lchg_date_time                   as LastChangeDateTime,
      @Semantics.user.lastChangedBy:true
      lchg_uname                       as LastChangedByUser,
      njit_scenario                    as JITScenario,
      jitcallisforwarded               as JITCallIsForwarded,
      //Associations

      _JITOutbMissingPartFlag,
      _JITLifecycleStatus,
      _JITCallType,
      _CreatedByUser,
      _LastChangedByUser,
      _JITOutbCallCompGroup,
      _JITCallCreationMode,
      _DeliveryPriority

}
where
  njit_scenario = '2' and
  jitcallisforwarded = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"NJIT_CALL_D_HDR"
],
"ASSOCIATED":
[
"I_DELIVERYPRIORITY",
"I_JITCALLCREATIONMODE",
"I_JITCALLTYPE",
"I_JITLIFECYCLESTATUS",
"I_JITOUTBCALLCOMPGRP",
"I_JITOUTBMISSINGFLAG",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/