I_JITOutbCallDelivDocRef

@AbapCatalog.sqlViewName: 'IJITODELVDOC'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling:{
     type: #INHERITED,
     algorithm: #SESSION_VARIABLE
   }
@ObjectModel: {
    usageType.dataClass: #TRANSACTIONAL,
    usageType.serviceQuality: #C,
    usageType.sizeCategory: #XL
}
@VDM: {
    viewType: #COMPOSITE
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Material Document Reference for Delivery'

define view I_JITOutbCallDelivDocRef
  as select from    I_SDDocumentMultiLevelProcFlow as _SDDocumentMultiLevelProcFlow
    inner join      I_JITOutbCallCompDocRef        as _NjitDoCumentReference on(
      _SDDocumentMultiLevelProcFlow.PrecedingDocument         = _NjitDoCumentReference.BusinessTransactionDocument
      and _SDDocumentMultiLevelProcFlow.PrecedingDocumentItem = _NjitDoCumentReference.BusinessTransactionDocItem
      and _NjitDoCumentReference.BusinessTransactionDocStatus = '1'
      and _NjitDoCumentReference.BusinessTransactionDocType   = 'I'
    )
    inner join      I_DeliveryDocumentItem         as _DeliveryDocumentItem  on(
       _SDDocumentMultiLevelProcFlow.PrecedingDocument         = _DeliveryDocumentItem.DeliveryDocument
       and _SDDocumentMultiLevelProcFlow.PrecedingDocumentItem = _DeliveryDocumentItem.DeliveryDocumentItem
       and ( _DeliveryDocumentItem.GoodsMovementStatus           = 'C' or
             _DeliveryDocumentItem.GoodsMovementStatus           = 'B' )
     )
{
  key _SDDocumentMultiLevelProcFlow.PrecedingDocument       as DeliveryDocument,
  key _SDDocumentMultiLevelProcFlow.PrecedingDocumentItem   as DeliveryDocumentItem,
      max(_SDDocumentMultiLevelProcFlow.SubsequentDocument) as MaterialDocument,
      _SDDocumentMultiLevelProcFlow.MaterialDocumentYear    as MaterialDocumentYear
}
where
      _SDDocumentMultiLevelProcFlow.PrecedingDocumentCategory = '7'
  and _SDDocumentMultiLevelProcFlow.MaterialDocumentYear      is not initial
group by
  _SDDocumentMultiLevelProcFlow.PrecedingDocument,
  _SDDocumentMultiLevelProcFlow.PrecedingDocumentItem,
  _SDDocumentMultiLevelProcFlow.MaterialDocumentYear
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DELIVERYDOCUMENTITEM",
"I_JITOUTBCALLCOMPDOCREF",
"I_SDDOCUMENTMULTILEVELPROCFLOW"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/