I_InvgCsMAddress

@AbapCatalog.sqlViewName: 'IINVGCSADD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@VDM.viewType: #BASIC
@EndUserText.label: 'ICM Address'
define view I_InvgCsMAddress
  as select from adrc
  association[1..*] to I_InvgCsMAddressText as _AddressText on $projection.AddressID = _AddressText.AddressID
  association [0..1] to I_Region              as _Region                   on  $projection.Region  = _Region.Region
                                                                           and $projection.Country = _Region.Country
  association [0..1] to I_Country             as _Country                  on  $projection.Country = _Country.Country
  association [0..1] to I_CityCode           as _CityCode    on  $projection.Country = _CityCode.Country
                                                             and $projection.Region  = _CityCode.Region
                                                             //and $projection.CityNumber = _CityCode.CityCode

                                                             and $projection.CityCode = _CityCode.CityCode
                                                             
  association [0..*] to I_SecondaryRegion    as _CountyCode  on  $projection.Country = _CountyCode.Country
                                                             and $projection.Region  = _CountyCode.Region
{
  key addrnumber as AddressID,
  key cast( date_from as crms4_icm_ad_date_fr ) as InvgCsMAddrValidFromDate,
  key nation as Nation,
      po_box as POBox,
      po_box_num as POBoxIsWithoutNumber,
      post_code2 as POBoxPostalCode,
      po_box_lobby as POBoxLobbyName,
      po_box_loc as POBoxDeviatingCityName,
      po_box_reg as POBoxDeviatingRegion,
      po_box_cty as POBoxDeviatingCountry,
      deli_serv_type as DeliveryServiceTypeCode,
      deli_serv_number as DeliveryServiceNumber,
      time_zone as AddressTimeZone,
      langu as CorrespondenceLanguage,
      deflt_comm as PrfrdCommMediumType,
      post_code1 as PostalCode,
      post_code3 as CompanyPostalCode,
      street as StreetName,
      house_num1 as HouseNumber,
      house_num2 as HouseNumberSupplementText,
      building as Building,
      floor as Floor,
      roomnumber as RoomNumber,
      title as FormOfAddress,
      country as Country,
      region as Region,
      taxjurcode as TaxJurisdiction,
      transpzone as TransportZone,
      cast(substring(replace(concat(name1, concat(' &@', name2)), '&@', ''),1,80) as adfullname ) as FullName,
      city1 as CityName,
      location as AdditionalStreetSuffixName ,
      chckstatus as CityFileTestStatus,
      dont_use_s as AddressStreetUnusable,
      dont_use_p as AddressPostBoxUnusable,
      city2 as DistrictName,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'DistrictName'
      city2 as District,
      //cast( city2 as ort02_gp ) as District,

      city_code as CityNumber,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'CityNumber'
      city_code as CityCode,
      home_city as HomeCityName,
      str_suppl1 as StreetPrefixName,
      str_suppl2 as AdditionalStreetPrefixName,
      str_suppl3 as StreetSuffixName,
      county as SecondaryRegionName,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'SecondaryRegionName'
      county as County,
      //cast( county as counc ) as County,

      county_code as CountyCode,
      township_code as TownshipCode,
      township as TownshipName,
      name1 as BusinessPartnerName1,
      name2 as BusinessPartnerName2,
      sort1 as SearchTerm1,
      sort2 as SearchTerm2,
      mc_street as StreetSearch,
      mc_city1  as CitySearch,
      name3 as BusinessPartnerName3,
      name4 as BusinessPartnerName4,
      city_code2 as AddressCityPostBoxCode,
      house_num3 as InvgCsMAddrHouseNumberRange,
      cityp_code as InvgCsMAddrDistrictCode,
      cityh_code as InvgCsMAddrDiffntCityName,
      date_to as InvgCsMAddrValidToDate,
      name_text as InvgCsMAddrNameText,
      cast(name_co as crms4_icm_ad_name_co ) as InvgCsMAddrNameCareOfText,
      regiogroup as InvgCsMAddrRegionGroup,
      pcode1_ext as InvgCsMAddrPostlCodeExtn,
      pcode2_ext as InvgCsMAddrPOBoxCodeExtn,
      pcode3_ext as InvgCsMAddrCustPostCodeExtn,
      postalarea as InvgCsMAddrPostDelivDstrctCode,
      streetcode as InvgCsMAddrStCode,
      streetabbr as InvgCsMAddrStAbbrCode,
      sort_phn as InvgCsMAddrSortPhone,
      addrorigin as InvgCsMAddrOrigin,
      extension1 as InvgCsMAddrExtn1Text,
      extension2 as InvgCsMAddrExtn2Text,
      address_id as InvgCsMAddressID,
      langu_crea as InvgCsMAddrRecdLangCrtnCode,
      @Semantics.booleanIndicator: true
      xpcpt as InvgCsMAddrBizPrpsIsCmpltd,
      _AddressText.InvgCsMAddrRemarkText,
      _AddressText,
      _Region,
      _Country,
      _CityCode,
      _CountyCode

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INVGCSMADDRESSTEXT",
"ADRC"
],
"ASSOCIATED":
[
"I_CITYCODE",
"I_COUNTRY",
"I_INVGCSMADDRESSTEXT",
"I_REGION",
"I_SECONDARYREGION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/