I_InternalOrderCostElementVH

DDL: I_INTERNALORDERCOSTELEMENTVH Type: view_entity COMPOSITE

Cost Element

I_InternalOrderCostElementVH is a Composite CDS View that provides data about "Cost Element" in SAP S/4HANA. It reads from 1 data source (I_CostElementOnControllingArea) and exposes 8 fields with key fields ControllingArea, CostElement, ValidityEndDate. It has 1 association to related views.

1 data source(s) 8 fields

Data Sources (1)

SourceAliasJoin Type
I_CostElementOnControllingArea I_CostElementOnControllingArea from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_CostElementText _CostElementText $projection.ChartOfAccounts = _CostElementText.ChartOfAccounts and $projection.CostElement = _CostElementText.CostElement

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
EndUserText.label Cost Element view
Search.searchable true view
VDM.viewType #COMPOSITE view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #MIXED view
UI.textArrangement #TEXT_LAST view
Consumption.ranked true view

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY ControllingArea ControllingArea
KEY CostElement CostElement
KEY ValidityEndDate ValidityEndDate
ValidityStartDate ValidityStartDate
CostElementDescription
CostElementCategory CostElementCategory
ChartOfAccounts ChartOfAccounts
_CostElementCategory _CostElementCategory 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Cost Element'
@Search.searchable: true
@VDM: {
  viewType: #COMPOSITE
}
@ObjectModel: {
  dataCategory: #VALUE_HELP,
  semanticKey: [ 'CostElement' ],
  usageType: {
    serviceQuality: #C,
    sizeCategory: #M,
    dataClass: #MIXED
  }
}
@UI.textArrangement: #TEXT_LAST
@Consumption.ranked: true
define view entity I_InternalOrderCostElementVH
  as select from I_CostElementOnControllingArea

  association [0..*] to I_CostElementText as _CostElementText on  $projection.ChartOfAccounts = _CostElementText.ChartOfAccounts
                                                              and $projection.CostElement     = _CostElementText.CostElement

{

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ControllingAreaStdVH',
                     element: 'ControllingArea' }
      }]
  key ControllingArea,
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      @ObjectModel.text.element: ['CostElementDescription']
      @UI.textArrangement: #TEXT_LAST
  key CostElement,
      @Semantics.businessDate.to: true
  key ValidityEndDate,
      @Semantics.businessDate.from: true
      ValidityStartDate,
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      _CostElementText[1: Language = $session.system_language].CostElementDescription,
      CostElementCategory,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ChartOfAccountsStdVH',
                     element: 'ChartOfAccounts' }
      }]
      ChartOfAccounts,
      
      _CostElementCategory
}
where CostElementCategory = '21'
   or CostElementCategory = '22' 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COSTELEMENTONCONTROLLINGAREA",
"I_COSTELEMENTTEXT"
],
"ASSOCIATED":
[
"I_COSTELEMENTCATEGORY"
],
"BASE":
[
"I_COSTELEMENTONCONTROLLINGAREA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More