I_InsurancePolicyContrCoverage

@EndUserText.label: 'Contract Coverage in Insurance Policy'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
                    privilegedAssociations:  [  '_InsurPlcyContrCvrgSurcharge',
                                                '_InsurPlcyContrCvrgLimit',
                                                '_InsurPlcyContrCvrgClause',
                                                '_InsurPlcyContrCvrgDeductible',
                                                '_InsurPlcyContrCvrgInsrdObj',
                                                '_InsurPlcyContrCvrgSubCvrg',
                                                '_InsurPlcyContrCvrgPlndProcg',
                                                '_InsurPlcyContrCvrgTypeRgnlCl',
                                                '_InsurPlcyContrCvrgPremComprn',
                                                '_InsurPlcyContrCvrgBonusMalus']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyCoverageID',
   semanticKey: [ 'InsurPlcyInsuranceCoverage' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IPPlcyContrCvrg'
}

define view entity I_InsurancePolicyContrCoverage
  as select from I_InsurPlcyCoverageBasic as Coverage

  // Join to Regular Premium on Coveragelevel

    inner join   R_InsurancePolicyPremium as RegularPremium        on  RegularPremium.InsurPlcyUUID              = Coverage.InsurPlcyUUID
                                                                   and RegularPremium.InsurPlcyInsurContr        = Coverage.InsurPlcyInsurContr
                                                                   and RegularPremium.InsurPlcyCoveragePackageID = Coverage.InsurPlcyCoveragePackageID
                                                                   and RegularPremium.InsurPlcyCoverageID        = Coverage.InsurPlcyCoverageID

  // Get Template of Contract

    inner join   I_InsuranceContract      as InsuranceContractTmpl on  Coverage.InsurPlcyUUID       = InsuranceContractTmpl.InsurPlcyUUID
                                                                   and Coverage.InsurPlcyInsurContr = InsuranceContractTmpl.InsurPlcyInsurContr

  // Filter Premium Objects

    inner join   I_InsurPlcyRegPremConfig as PremiumConfig         on  PremiumConfig.InsurPlcyProductTemplate = InsuranceContractTmpl.InsurPlcyProductTemplate
                                                                   and PremiumConfig.InsurPremType            = RegularPremium.InsurPremType

  association        to parent I_InsuranceContract     as _InsuranceContract         on  $projection.InsurPlcyUUID       = _InsuranceContract.InsurPlcyUUID
                                                                                     and $projection.InsurPlcyInsurContr = _InsuranceContract.InsurPlcyInsurContr

  composition [0..*] of I_InsurPlcyContrCvrgLimit      as _InsurPlcyContrCvrgLimit
  composition [0..*] of I_InsurPlcyContrCvrgClause     as _InsurPlcyContrCvrgClause
  composition [0..*] of I_InsurPlcyContrCvrgDeductible as _InsurPlcyContrCvrgDeductible
  composition [0..*] of I_InsurPlcyContrCvrgInsrdObj   as _InsurPlcyContrCvrgInsrdObj
  composition [0..*] of I_InsurPlcyContrCvrgSurcharge  as _InsurPlcyContrCvrgSurcharge
  composition [0..*] of I_InsurPlcyContrCvrgSubCvrg    as _InsurPlcyContrCvrgSubCvrg
  composition [0..1] of I_InsurPlcyContrCvrgTypeRgnlCl as _InsurPlcyContrCvrgTypeRgnlCl
  composition [0..1] of I_InsurPlcyContrCvrgPremComprn as _InsurPlcyContrCvrgPremComprn
  composition [0..*] of I_InsurPlcyContrCvrgPlndProcg  as _InsurPlcyContrCvrgPlndProcg
  composition [0..*] of I_InsurPlcyContrCvrgBonusMalus as _InsurPlcyContrCvrgBonusMalus
  composition [0..*] of I_InsurPlcyContrCvrgBnfcy      as _InsurPlcyContrCvrgBeneficiary

  association [1..1] to I_Currency                     as _PremiumCurrency           on  $projection.InsurPlcyPremiumCurrency = _PremiumCurrency.Currency
  association [1..1] to I_Currency                     as _CoverageCurrency          on  $projection.InsurPlcyCoverageCurrency = _CoverageCurrency.Currency
  association [1..1] to I_InsurContrCanclnReason       as _InsurContrCanclnReason    on  $projection.InsurContrCanclnRsn = _InsurContrCanclnReason.InsurContrCanclnRsn
  association [1..1] to I_InsurPlcyCvrgLifeCycSts      as _InsurPlcyCvrgLifeCycSts   on  $projection.InsurPlcyCvrgLifeCycleStatus = _InsurPlcyCvrgLifeCycSts.InsurPlcyCvrgLifeCycleStatus
  association [1..1] to I_InsurPlcyCvrgInsrdSumCalc    as _InsurPlcyCvrgInsrdSumCalc on  $projection.InsurPlcyCvrgInsrdSumCalcMeth = _InsurPlcyCvrgInsrdSumCalc.InsurPlcyCvrgInsrdSumCalcMeth
  association [1..1] to I_InsurPlcyCvrgSuspension      as _InsurPlcyCvrgSuspension   on  $projection.InsurPlcyCoverageSuspension = _InsurPlcyCvrgSuspension.InsurPlcyCoverageSuspension
  association [1..*] to I_InsurPlcyTemplateT           as _InsurPlcyTemplateT        on  $projection.InsurPlcyElementaryProdTmpl = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [1..1] to I_InsurPlcyCvrgPremExmpRsnLink as _InsurPlcyCvrgPremExmpRsn  on  $projection.InsurPlcyCvrgPremExmpReason = _InsurPlcyCvrgPremExmpRsn.InsurPlcyCvrgPremExmpReason
                                                                                     and $projection.InsurPlcyElementaryProdTmpl = _InsurPlcyCvrgPremExmpRsn.InsurancePolicyCoverageControl

{

  key Coverage.InsurPlcyUUID,
  key Coverage.InsurPlcyInsurContr,
  key Coverage.InsurPlcyCoveragePackageID,
  key Coverage.InsurPlcyCoverageID,
      Coverage.InsurPlcyJrnlNmbr,
      Coverage.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Coverage.InsurPlcyProductPackageID,
      Coverage.InsurPlcyInsuranceCoverage,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Coverage.InsurPlcyElementaryProdTmpl,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCoverageStartDateTime,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCoverageEndDateTime,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgPremExmpRsn'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyCvrgPremExmpReason'      
      Coverage.InsurPlcyCvrgPremExmpReason,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgLifeCycSts'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyCvrgLifeCycleStatus'
      Coverage.InsurPlcyCvrgLifeCycleStatus,
      @ObjectModel.foreignKey.association: '_InsurContrCanclnReason'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurContrCancellationReason'
      Coverage.InsurContrCanclnRsn,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCvrgCanclnDateTime,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgSuspension'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPolicyCoverageSuspension'
      Coverage.InsurPlcyCoverageSuspension,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCvrgSuspnStrtDateTime,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCvrgSuspnEndDateTime,
      @Semantics.amount.currencyCode: 'InsurPlcyCoverageCurrency'
      Coverage.InsurPlcyCvrgInsuredSumAmount,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgInsrdSumCalc'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyCvrgInsrdSumCalcMeth'
      Coverage.InsurPlcyCvrgInsrdSumCalcMeth,
      Coverage.InsurPlcyCvrgInsuredSumPercent,
      @ObjectModel.foreignKey.association: '_CoverageCurrency'
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      Coverage.InsurPlcyCoverageCurrency,
      //FS-PM Auto sibling specific fields

      Coverage.InsurPlcyBonusRestorerType,
      Coverage.InsurPlcyVehDeregistrationDate,
      Coverage.InsurPlcyBonusMalusIsNotCeded,
      Coverage.InsurPlcyInsurEndMsgSendDate,
      Coverage.InsurPlcySubcoverageVariant,
      Coverage.InsurPlcyVehInsurCoverEndDate,
      Coverage.InsurPlcyNrOfVehClaimsRestored,
      Coverage.InsurPlcyCrteInsurEndMessage,
      @Semantics.booleanIndicator:true
      Coverage.InsurPlcyDiscProtIsActive,
      @Semantics.systemDateTime.lastChangedAt: true
      Coverage.LastChangeDateTime,

      RegularPremium.InsurancePolicyPremium,
      RegularPremium.InsurPlcyJrnlNmbr    as InsurPlcyPremiumJournalNumber,
      RegularPremium.InsurPlcyJrnlEndNmbr as InsurPlcyPremJournalEndNumber,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPerdPremBfrTaxPaytAmt,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPerdPremAftTaxPaytAmt,
      RegularPremium.InsurPremType,
      @Semantics.booleanIndicator:true
      RegularPremium.InsurPlcyCvrgIsPremiumExempt,
      RegularPremium.InsurPlcyCvrgPremExmpEndDate,
      @ObjectModel.foreignKey.association: '_PremiumCurrency'
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      RegularPremium.InsurPlcyPremiumCurrency,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPlcyTotAnnPremAmt,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPlcyPerdPremBfrTxPaytAmt,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      RegularPremium.InsurPlcyPremiumTemplate,

      /* Associations */
      _InsuranceContract,
      _InsurPlcyContrCvrgSurcharge,
      _InsurPlcyContrCvrgLimit,
      _InsurPlcyContrCvrgClause,
      _InsurPlcyContrCvrgDeductible,
      _InsurPlcyContrCvrgInsrdObj,
      _InsurPlcyContrCvrgSubCvrg,
      _InsurPlcyContrCvrgTypeRgnlCl,
      _InsurPlcyContrCvrgPremComprn,
      _InsurPlcyContrCvrgPlndProcg,
      _InsurPlcyContrCvrgBonusMalus,
      _InsurPlcyContrCvrgBeneficiary,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _InsurContrCanclnReason,
      @Consumption.hidden: true
      _InsurPlcyCvrgLifeCycSts,
      @Consumption.hidden: true
      _InsurPlcyCvrgSuspension,
      @Consumption.hidden: true
      _InsurPlcyCvrgInsrdSumCalc,
      @Consumption.hidden: true
      _CoverageCurrency,
      @Consumption.hidden: true
      _PremiumCurrency,
      @Consumption.hidden: true
      _InsurPlcyCvrgPremExmpRsn

}
where
      Coverage.InsurPlcyJrnlEndNmbr       = 2147483647
  and Coverage.InsurPlcyBusinessObject    = 'P'
  and Coverage.InsurPlcyCoveragePackageID = 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURANCECONTRACT",
"I_INSURPLCYCOVERAGEBASIC",
"I_INSURPLCYREGPREMCONFIG",
"R_INSURANCEPOLICYPREMIUM"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_INSURANCECONTRACT",
"I_INSURCONTRCANCLNREASON",
"I_INSURPLCYCONTRCVRGBNFCY",
"I_INSURPLCYCONTRCVRGBONUSMALUS",
"I_INSURPLCYCONTRCVRGCLAUSE",
"I_INSURPLCYCONTRCVRGDEDUCTIBLE",
"I_INSURPLCYCONTRCVRGINSRDOBJ",
"I_INSURPLCYCONTRCVRGLIMIT",
"I_INSURPLCYCONTRCVRGPLNDPROCG",
"I_INSURPLCYCONTRCVRGPREMCOMPRN",
"I_INSURPLCYCONTRCVRGSUBCVRG",
"I_INSURPLCYCONTRCVRGSURCHARGE",
"I_INSURPLCYCONTRCVRGTYPERGNLCL",
"I_INSURPLCYCVRGINSRDSUMCALC",
"I_INSURPLCYCVRGLIFECYCSTS",
"I_INSURPLCYCVRGPREMEXMPRSNLINK",
"I_INSURPLCYCVRGSUSPENSION",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/