I_InsurancePolicy

@EndUserText.label: 'Insurance Policy'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
                    privilegedAssociations:  [  '_InsuranceContract',
                                                '_InsurancePolicyholder',
                                                '_InsurPlcyContrJrnl']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyUUID',
   semanticKey: [ 'InsurancePolicy' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IPPlcy'
}

define root view entity I_InsurancePolicy
  as select from I_InsurPlcyBasic as Policy

  composition [1..*] of I_InsurancePolicyPolicyHolder  as _InsurancePolicyholder
  composition [1..*] of I_InsuranceContract            as _InsuranceContract
  composition [1..*] of I_InsurPlcyContrJrnl           as _InsurPlcyContrJrnl
  composition [0..*] of I_InsurPolicyPlannedProcessing as _InsurPlcyPlndProcg

  association [1..1] to I_InsurPlcyDistrChnl           as _InsurPlcyDistrChnl       on  $projection.InsurPlcyDistrChnl = _InsurPlcyDistrChnl.InsurPlcyDistrChnl
  association [1..1] to I_InsurPlcyAcquisitionType     as _InsurPlcyAcqnType        on  $projection.InsurPlcyAcqnType = _InsurPlcyAcqnType.InsurPlcyAcqnType
  association [1..1] to I_InsurPlcyInsurer             as _InsurPlcyInsurer         on  $projection.InsrrIDByInsrr = _InsurPlcyInsurer.InsrrIDByInsrr
  association [1..*] to I_InsurPlcyTemplateT           as _InsurPlcyTemplateT       on  $projection.InsurPlcySalesProductTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [1..1] to I_InsurApplLifeCycleStatus     as _InsurApplLifeCycleStatus on  $projection.InsurApplLifeCycSts = _InsurApplLifeCycleStatus.InsurApplLifeCycSts
  association [1..*] to I_InsurPlcyCashFlowHeader      as _InsurPlcyCashFlowHeader  on  $projection.InsurancePolicy = _InsurPlcyCashFlowHeader.InsurancePolicy

  association [1..1] to E_InsurancePolicy              as _Extension                on  $projection.InsurPlcyUUID        = _Extension.InsurPlcyUUID
                                                                                    and $projection.InsurPlcyJrnlNmbr    = _Extension.InsurPlcyJrnlNmbr
                                                                                    and $projection.InsurPlcyJrnlEndNmbr = _Extension.InsurPlcyJrnlEndNmbr

{
  key Policy.InsurPlcyUUID,
      Policy.InsurPlcyJrnlNmbr,
      Policy.InsurPlcyJrnlEndNmbr,
      Policy.InsurancePolicy,
      @Consumption.hidden: true
      Policy.InsurPlcyAuthznSlsProductGroup,
      @Semantics.dateTime:true
      Policy.InsurPlcyStartDateTime,
      @ObjectModel.foreignKey.association: '_InsurApplLifeCycleStatus'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurApplLifeCycleStatus'
      Policy.InsurApplLifeCycSts,
      @ObjectModel.foreignKey.association: '_InsurPlcyDistrChnl'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPolicyDistributionChannel'
      Policy.InsurPlcyDistrChnl,
      @ObjectModel.foreignKey.association: '_InsurPlcyInsurer'
      @ObjectModel.sapObjectNodeTypeReference: 'Insurer'
      Policy.InsrrIDByInsrr,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Policy.InsurPlcySalesProductTemplate,
      @ObjectModel.foreignKey.association: '_InsurPlcyAcqnType'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPolicyAcquisitionType'
      Policy.InsurPlcyAcqnType,
      Policy.PrdcssrInsurancePolicy,
      @Semantics.systemDateTime.lastChangedAt: true
      Policy.LastChangeDateTime,
      Policy.InsurPolicyCancellationStatus,

      _InsuranceContract,
      _InsurancePolicyholder,
      _InsurPlcyCashFlowHeader,
      _InsurPlcyContrJrnl,
      _InsurPlcyPlndProcg,

      @Consumption.hidden: true
      _InsurPlcyDistrChnl,
      @Consumption.hidden: true
      _InsurPlcyAcqnType,
      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _InsurPlcyInsurer,
      @Consumption.hidden: true
      _InsurApplLifeCycleStatus

}
where
      Policy.InsurPlcyJrnlEndNmbr    = 2147483647
  and Policy.InsurPlcyBusinessObject = 'P'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYBASIC"
],
"ASSOCIATED":
[
"I_INSURANCECONTRACT",
"I_INSURANCEPOLICYPOLICYHOLDER",
"I_INSURAPPLLIFECYCLESTATUS",
"I_INSURPLCYACQUISITIONTYPE",
"I_INSURPLCYCASHFLOWHEADER",
"I_INSURPLCYCONTRJRNL",
"I_INSURPLCYDISTRCHNL",
"I_INSURPLCYINSURER",
"I_INSURPLCYTEMPLATET",
"I_INSURPOLICYPLANNEDPROCESSING"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/