I_InsurPlcyContrInsuredObject

@EndUserText.label: 'Contract Insrd Obj in Insurance Policy'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [  '_InsurPlcyContrInsrdObjClause',
                              '_InsurPlcyContrInsrdObjDcbl',
                              '_InsurPlcyContrObjSurchrgDisc',
                              '_InsurPlcyContrInsuredVehicle',
                              '_InsurPlcyContrObjNmdDrvr',
                              '_InsurPlcyContrObjSpclEquip',
                              '_InsurPlcyContrInsuredBldng']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyInsuredObjectID',
   semanticKey: [ 'InsurPlcyInsrdObjUnqID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IPCoInsObj'
}
define view entity I_InsurPlcyContrInsuredObject
  as select from I_InsurPlcyInsuredObjectBasic as Subject

  association        to parent I_InsuranceContract     as _InsuranceContract        on  $projection.InsurPlcyUUID       = _InsuranceContract.InsurPlcyUUID
                                                                                    and $projection.InsurPlcyInsurContr = _InsuranceContract.InsurPlcyInsurContr

  composition [0..*] of I_InsurPlcyContrInsrdObjClause as _InsurPlcyContrInsrdObjClause
  composition [0..*] of I_InsurPlcyContrInsrdObjDcbl   as _InsurPlcyContrInsrdObjDcbl
  composition [0..*] of I_InsurPlcyContrObjSurchrgDisc as _InsurPlcyContrObjSurchrgDisc
  composition [0..1] of I_InsurPlcyContrInsuredVehicle as _InsurPlcyContrInsuredVehicle
  composition [0..*] of I_InsurPlcyContrObjNmdDrvr     as _InsurPlcyContrObjNmdDrvr
  composition [0..*] of I_InsurPlcyContrObjSpclEquip   as _InsurPlcyContrObjSpclEquip
  composition [0..1] of I_InsurPlcyContrInsuredBldng   as _InsurPlcyContrInsuredBldng

  association [1..1] to I_InsurInsrdObjectCategory     as _InsurInsrdObjectCategory on  $projection.InsurPlcyInsuredObjectCategory = _InsurInsrdObjectCategory.InsurPlcyInsuredObjectCategory
  association [1..1] to I_InsurInsrdObjSubCategory     as _InsurInsrdObjSubCategory on  $projection.InsurPlcyInsrdObjSubCategory = _InsurInsrdObjSubCategory.InsurPlcyInsrdObjSubCategory
  association [1..*] to I_InsurPlcyTemplateT           as _InsurPlcyTemplateT       on  $projection.InsurPlcyInsrdObjectTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [1..1] to I_InsurInsurableObject         as _InsurInsurableObject     on  $projection.InsurPlcyInsrdObjUnqID = _InsurInsurableObject.InsurInsrblObj
                                                                                    and $projection.InsurInsrblObjJrnlNmbr = _InsurInsurableObject.InsurInsrblObjJrnlNmbr

{

  key Subject.InsurPlcyUUID,
  key Subject.InsurPlcyInsurContr,
  key Subject.InsurPlcyCoveragePackageID,
  key Subject.InsurPlcyCoverageID,
  key Subject.InsurPlcyInsuredObjectID,
      Subject.InsurPlcyJrnlNmbr,
      Subject.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Subject.InsurPlcyProductPackageID,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Subject.InsurPlcyInsrdObjectTemplate,
      @ObjectModel.foreignKey.association: '_InsurInsrdObjectCategory'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyInsuredObjectCategory'
      Subject.InsurPlcyInsuredObjectCategory,
      @ObjectModel.foreignKey.association: '_InsurInsrdObjSubCategory'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyInsrdObjSubCategory'
      Subject.InsurPlcyInsrdObjSubCategory,
      @ObjectModel.foreignKey.association: '_InsurInsurableObject'
      Subject.InsurPlcyInsrdObjUnqID,
      Subject.InsurInsrblObjJrnlNmbr,
      @Semantics.systemDateTime.lastChangedAt: true
      Subject.LastChangeDateTime,

      /* Associations */
      _InsuranceContract,
      _InsurPlcyContrInsrdObjClause,
      _InsurPlcyContrInsrdObjDcbl,
      _InsurPlcyContrObjSurchrgDisc,
      _InsurPlcyContrInsuredVehicle,
      _InsurPlcyContrObjNmdDrvr,
      _InsurPlcyContrObjSpclEquip,
      _InsurPlcyContrInsuredBldng,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _InsurInsrdObjectCategory,
      @Consumption.hidden: true
      _InsurInsrdObjSubCategory,
      _InsurInsurableObject

}
where
      Subject.InsurPlcyJrnlEndNmbr       = 2147483647
  and Subject.InsurPlcyBusinessObject    = 'P'
  and Subject.InsurPlcyCoveragePackageID = 0
  and Subject.InsurPlcyCoverageID        = 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYINSUREDOBJECTBASIC"
],
"ASSOCIATED":
[
"I_INSURANCECONTRACT",
"I_INSURINSRDOBJECTCATEGORY",
"I_INSURINSRDOBJSUBCATEGORY",
"I_INSURINSURABLEOBJECT",
"I_INSURPLCYCONTRINSRDOBJCLAUSE",
"I_INSURPLCYCONTRINSRDOBJDCBL",
"I_INSURPLCYCONTRINSUREDBLDNG",
"I_INSURPLCYCONTRINSUREDVEHICLE",
"I_INSURPLCYCONTROBJNMDDRVR",
"I_INSURPLCYCONTROBJSPCLEQUIP",
"I_INSURPLCYCONTROBJSURCHRGDISC",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/