I_InsurOpenApplSubCvrgClause

@EndUserText.label: 'SubCoverage Clause of CvPcg in InsOpAppl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'InsurPlcyClauseID',
   semanticKey: [ 'InsurPlcyClauseID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IOASubcvrgCls'
}
define view entity I_InsurOpenApplSubCvrgClause
  as select from           I_InsurPlcyClauseBasic        as Clause

    left outer to one join P_InsurOpenApplClauseLatest   as OpenApplJrnl on  (
        OpenApplJrnl.InsurPlcyUUID                                                                                       = Clause.InsurPlcyUUID
        or OpenApplJrnl.InsurPlcyApplUUID                                                                                = Clause.InsurPlcyUUID
      )
                                                                         and OpenApplJrnl.InsurPlcyInsurContr            = Clause.InsurPlcyInsurContr
                                                                         and OpenApplJrnl.InsurPlcyCoveragePackageID     = Clause.InsurPlcyCoveragePackageID
                                                                         and OpenApplJrnl.InsurPlcyCoverageID            = Clause.InsurPlcyCoverageID
                                                                         and OpenApplJrnl.InsurPlcySubCvrgID             = Clause.InsurPlcySubCvrgID
                                                                         and OpenApplJrnl.InsurPlcyInsuredObjectID       = Clause.InsurPlcyInsuredObjectID
                                                                         and Clause.InsurPlcyClauseID                    = Clause.InsurPlcyClauseID
                                                                         and OpenApplJrnl.InsurPlcyClauseID              = Clause.InsurPlcyClauseID
                                                                         and OpenApplJrnl.InsurPlcyJrnlNmbr              = Clause.InsurPlcyJrnlNmbr
                                                                         and OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr < Clause.InsurPlcyJrnlEndNmbr

    left outer to one join I_InsurPlcyClauseLongTxtBasic as LongText     on Clause.InsurPlcyClauseDetailTextUUID = LongText.InsurPlcyClauseDetailTextUUID

  association        to parent I_InsurOpenApplSubCoverage as _InsurOpenApplSubCoverage  on  $projection.InsurPlcyApplUUID              = _InsurOpenApplSubCoverage.InsurPlcyApplUUID
                                                                                        and $projection.InsuranceApplication           = _InsurOpenApplSubCoverage.InsuranceApplication
                                                                                        and $projection.InsurPlcyInsurContr            = _InsurOpenApplSubCoverage.InsurPlcyInsurContr
                                                                                        and $projection.InsurPlcyCoveragePackageID     = _InsurOpenApplSubCoverage.InsurPlcyCoveragePackageID
                                                                                        and $projection.InsurPlcyCoverageID            = _InsurOpenApplSubCoverage.InsurPlcyCoverageID
                                                                                        and $projection.InsurPlcySubCvrgID             = _InsurOpenApplSubCoverage.InsurPlcySubCvrgID
                                                                                        and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurOpenApplSubCoverage.InsurPlcyContrDataDetnJrnlNmbr
  association [1..1] to I_InsurPlcyClauseTypeLink         as _InsurancePolicyClauseType on  $projection.InsurPlcyClauseType     = _InsurancePolicyClauseType.InsurPlcyClauseType
                                                                                        and $projection.InsurPlcyClauseTemplate = _InsurancePolicyClauseType.InsurPlcyClauseTemplate
  association [1..*] to I_InsurPlcyTemplateT              as _InsurPlcyTemplateT        on  $projection.InsurPlcyClauseTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate

{

  key OpenApplJrnl.InsurPlcyApplUUID,
  key cast( OpenApplJrnl.InsuranceApplication as /pm0/vdm_applicationnr_tt preserving type )              as InsuranceApplication,
  key Clause.InsurPlcyInsurContr,
  key Clause.InsurPlcyCoveragePackageID,
  key Clause.InsurPlcyCoverageID,
  key Clause.InsurPlcySubCvrgID,
  key Clause.InsurPlcyInsuredObjectID,
  key Clause.InsurPlcyClauseID,
  key cast( OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      Clause.InsurPlcyJrnlNmbr,
      Clause.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Clause.InsurPlcyProductPackageID,
      OpenApplJrnl.InsurPlcyUUID,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Clause.InsurPlcyClauseTemplate,
      Clause.InsurPlcyIndivClauseAgrmtText,
      Clause.InsurPlcyClauseDetailTextUUID,
      LongText.LongText,
      LongText.TextObjectCategory,
      LongText.TextObjectKey,
      LongText.Language,
      @ObjectModel.foreignKey.association: '_InsurancePolicyClauseType'
      Clause.InsurPlcyClauseType,
      @Semantics.businessDate.from: true
      Clause.InsurPlcyClauseStartDate,
      @Semantics.businessDate.to: true
      Clause.InsurPlcyClauseEndDate,
      @Semantics.systemDateTime.lastChangedAt: true
      Clause.LastChangeDateTime,

      /* Associations */
      _InsurOpenApplSubCoverage,
      @Consumption.hidden: true
      _InsurancePolicyClauseType,
      @Consumption.hidden: true
      _InsurPlcyTemplateT

}
where
      Clause.InsurPlcyInsuredObjectID   =  0
  and Clause.InsurPlcyCoveragePackageID <> 0
  and Clause.InsurPlcyCoverageID        <> 0
  and Clause.InsurPlcySubCvrgID         <> 0
  and OpenApplJrnl.InsurPlcyApplUUID    is not initial //Perf. Tuning: Make inner Join out of left outer Join

  and OpenApplJrnl.InsuranceApplication is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYCLAUSEBASIC",
"I_INSURPLCYCLAUSELONGTXTBASIC",
"P_INSUROPENAPPLCLAUSELATEST"
],
"ASSOCIATED":
[
"I_INSUROPENAPPLSUBCOVERAGE",
"I_INSURPLCYCLAUSETYPELINK",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/