I_InsurOpenApplInsuredObject

@EndUserText.label: 'Cvrg InsOb of Cvrg Pckg in InsurOpenAppl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [  '_InsOpApCvrgInsrdObjClause',
                              '_InsOpApCvrgInsrdObjDcbl',
                              '_InsOpApCvrgObjSurchrgDisc',
//                              '_InsurApplCvrgInsuredVehicle',

//                              '_InsurApplCvrgNamedDriver',

//                              '_InsurApplCvrgSpclEquipment'

                                '_InsOpApCvrgPckgCvrgBldng']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyInsuredObjectID',
   semanticKey: [ 'InsurPlcyInsrdObjUnqID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #L
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IOAInsrdObj'
}
define view entity I_InsurOpenApplInsuredObject
  as select from           I_InsurPlcyInsuredObjectBasic as Subject

    left outer to one join P_InsurOpenApplInsrdObjLatest as OpenApplJrnl on  (
        OpenApplJrnl.InsurPlcyUUID                                                                                       = Subject.InsurPlcyUUID
        or OpenApplJrnl.InsurPlcyApplUUID                                                                                = Subject.InsurPlcyUUID
      )
                                                                         and OpenApplJrnl.InsurPlcyInsurContr            = Subject.InsurPlcyInsurContr
                                                                         and OpenApplJrnl.InsurPlcyCoveragePackageID     = Subject.InsurPlcyCoveragePackageID
                                                                         and OpenApplJrnl.InsurPlcyCoverageID            = Subject.InsurPlcyCoverageID
                                                                         and OpenApplJrnl.InsurPlcyInsuredObjectID       = Subject.InsurPlcyInsuredObjectID
                                                                         and OpenApplJrnl.InsurPlcyJrnlNmbr              = Subject.InsurPlcyJrnlNmbr
                                                                         and OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr < Subject.InsurPlcyJrnlEndNmbr


  association        to parent I_InsurOpenApplCoverage as _InsurOpenApplCoverage    on  $projection.InsurPlcyApplUUID              = _InsurOpenApplCoverage.InsurPlcyApplUUID
                                                                                    and $projection.InsuranceApplication           = _InsurOpenApplCoverage.InsuranceApplication
                                                                                    and $projection.InsurPlcyInsurContr            = _InsurOpenApplCoverage.InsurPlcyInsurContr
                                                                                    and $projection.InsurPlcyCoveragePackageID     = _InsurOpenApplCoverage.InsurPlcyCoveragePackageID
                                                                                    and $projection.InsurPlcyCoverageID            = _InsurOpenApplCoverage.InsurPlcyCoverageID
                                                                                    and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurOpenApplCoverage.InsurPlcyContrDataDetnJrnlNmbr

  composition [0..*] of I_InsOpApCvrgInsrdObjectClause as _InsOpApCvrgInsrdObjClause
  composition [0..*] of I_InsOpApCvrgInsrdObjDcbl      as _InsOpApCvrgInsrdObjDcbl
  composition [0..*] of I_InsOpApCvrgObjSurchrgDisc    as _InsOpApCvrgObjSurchrgDisc
  composition [0..1] of I_InsOpApCvrgInsuredVehicle    as _InsOpApCvrgInsuredVehicle
  composition [0..*] of I_InsOpApCoverageNamedDriver   as _InsOpApCvrgNamedDriver
  composition [0..*] of I_InsOpApCvrgSpclEquipment     as _InsOpApCvrgSpclEquipment
  composition [0..1] of I_InsOpApCvrgPckgCvrgBuilding  as _InsOpApCvrgPckgCvrgBldng

  association [1..1] to I_InsurInsrdObjectCategory     as _InsurInsrdObjectCategory on  $projection.InsurPlcyInsuredObjectCategory = _InsurInsrdObjectCategory.InsurPlcyInsuredObjectCategory
  association [1..1] to I_InsurInsrdObjSubCategory     as _InsurInsrdObjSubCategory on  $projection.InsurPlcyInsrdObjSubCategory = _InsurInsrdObjSubCategory.InsurPlcyInsrdObjSubCategory
  association [1..*] to I_InsurPlcyTemplateT           as _InsurPlcyTemplateT       on  $projection.InsurPlcyInsrdObjectTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate

  association [1..1] to I_InsurInsurableObject         as _InsurInsurableObject     on  $projection.InsurPlcyInsrdObjUnqID = _InsurInsurableObject.InsurInsrblObj
                                                                                    and $projection.InsurInsrblObjJrnlNmbr = _InsurInsurableObject.InsurInsrblObjJrnlNmbr

{

  key OpenApplJrnl.InsurPlcyApplUUID,
  key cast( OpenApplJrnl.InsuranceApplication as /pm0/vdm_applicationnr_tt preserving type )              as InsuranceApplication,
  key Subject.InsurPlcyInsurContr,
  key Subject.InsurPlcyCoveragePackageID,
  key Subject.InsurPlcyCoverageID,
  key Subject.InsurPlcyInsuredObjectID,
  key cast( OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      Subject.InsurPlcyJrnlNmbr,
      Subject.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Subject.InsurPlcyProductPackageID,
      OpenApplJrnl.InsurPlcyUUID,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Subject.InsurPlcyInsrdObjectTemplate,
      @ObjectModel.foreignKey.association: '_InsurInsrdObjectCategory'
      Subject.InsurPlcyInsuredObjectCategory,
      @ObjectModel.foreignKey.association: '_InsurInsrdObjSubCategory'
      Subject.InsurPlcyInsrdObjSubCategory,
      @ObjectModel.foreignKey.association: '_InsurInsurableObject'
      Subject.InsurPlcyInsrdObjUnqID,
      Subject.InsurInsrblObjJrnlNmbr,
      @Semantics.systemDateTime.lastChangedAt: true
      Subject.LastChangeDateTime,

      /* Associations */
      _InsurOpenApplCoverage,
      _InsOpApCvrgInsrdObjClause,
      _InsOpApCvrgInsrdObjDcbl,
      _InsOpApCvrgObjSurchrgDisc,
      _InsOpApCvrgInsuredVehicle,
      _InsOpApCvrgNamedDriver,
      _InsOpApCvrgSpclEquipment,
      _InsOpApCvrgPckgCvrgBldng,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _InsurInsrdObjectCategory,
      @Consumption.hidden: true
      _InsurInsrdObjSubCategory,
      _InsurInsurableObject

}
where
      Subject.InsurPlcyCoveragePackageID <> 0
  and Subject.InsurPlcyCoverageID        <> 0
  and OpenApplJrnl.InsurPlcyApplUUID     is not initial //Perf. Tuning: Make inner Join out of left outer Join

  and OpenApplJrnl.InsuranceApplication  is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYINSUREDOBJECTBASIC",
"P_INSUROPENAPPLINSRDOBJLATEST"
],
"ASSOCIATED":
[
"I_INSOPAPCOVERAGENAMEDDRIVER",
"I_INSOPAPCVRGINSRDOBJDCBL",
"I_INSOPAPCVRGINSRDOBJECTCLAUSE",
"I_INSOPAPCVRGINSUREDVEHICLE",
"I_INSOPAPCVRGOBJSURCHRGDISC",
"I_INSOPAPCVRGPCKGCVRGBUILDING",
"I_INSOPAPCVRGSPCLEQUIPMENT",
"I_INSURINSRDOBJECTCATEGORY",
"I_INSURINSRDOBJSUBCATEGORY",
"I_INSURINSURABLEOBJECT",
"I_INSUROPENAPPLCOVERAGE",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/