I_InsurOpenApplContrCoverage

@EndUserText.label: 'Contract Coverage in InsurOpenAppl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
                    privilegedAssociations:  [  '_InsOpApContrCvrgSurcharge',
                                                '_InsOpApContrCvrgLimit',
                                                '_InsOpApContrCvrgClause',
                                                '_InsOpApContrCvrgDeductible',
                                                '_InsOpApContrCvrgInsrdObj',
                                                '_InsOpApContrCvrgSubCvrg',
                                                '_InsOpApContrCvrgTypeRgnlCl',
                                                '_InsOpApContrCvrgPremComprn',
                                                '_InsOpApContrCvrgBonusMalus',
                                                 '_InsOpApContrCvrgBeneficiary' ]
}
@ObjectModel: {
   representativeKey: 'InsurPlcyCoverageID',
   semanticKey: [ 'InsurPlcyInsuranceCoverage' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IOAPlcyContrCvrg'
}
define view entity I_InsurOpenApplContrCoverage
  as select from           I_InsurPlcyCoverageBasic      as Coverage

    left outer to one join P_InsurOpenApplCoverageLatest as OpenApplJrnl          on  (
                 OpenApplJrnl.InsurPlcyUUID                                                                                       = Coverage.InsurPlcyUUID
                 or OpenApplJrnl.InsurPlcyApplUUID                                                                                = Coverage.InsurPlcyUUID
               )
                                                                                  and OpenApplJrnl.InsurPlcyInsurContr            = Coverage.InsurPlcyInsurContr
                                                                                  and OpenApplJrnl.InsurPlcyCoveragePackageID     = Coverage.InsurPlcyCoveragePackageID
                                                                                  and OpenApplJrnl.InsurPlcyCoverageID            = Coverage.InsurPlcyCoverageID
                                                                                  and OpenApplJrnl.InsurPlcyJrnlNmbr              = Coverage.InsurPlcyJrnlNmbr
                                                                                  and OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr < Coverage.InsurPlcyJrnlEndNmbr
  // Get Template of Contract

    inner join             I_InsurOpenApplContract       as InsurApplContractTmpl on  Coverage.InsurPlcyUUID                      = InsurApplContractTmpl.InsurPlcyUUID
                                                                                  and Coverage.InsurPlcyInsurContr                = InsurApplContractTmpl.InsurPlcyInsurContr
                                                                                  and OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr = InsurApplContractTmpl.InsurPlcyContrDataDetnJrnlNmbr


  // Join to Regular Premium on Coveragelevel

    left outer to one join R_InsurOpenApplicationPremium as RegularPremium        on  RegularPremium.InsurPlcyApplUUID              = OpenApplJrnl.InsurPlcyApplUUID
                                                                                  and RegularPremium.InsurPlcyInsurContr            = Coverage.InsurPlcyInsurContr
                                                                                  and RegularPremium.InsurPlcyCoveragePackageID     = Coverage.InsurPlcyCoveragePackageID
                                                                                  and RegularPremium.InsurPlcyCoverageID            = Coverage.InsurPlcyCoverageID
                                                                                  and RegularPremium.InsurPlcyContrDataDetnJrnlNmbr = OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr

    left outer to one join I_InsurPlcyRegPremConfig      as PremiumConfig         on  PremiumConfig.InsurPlcyProductTemplate = InsurApplContractTmpl.InsurPlcyProductTemplate
                                                                                  and PremiumConfig.InsurPremType            = RegularPremium.InsurPremType

  association        to parent I_InsurOpenApplContract as _InsurOpenApplContract     on  $projection.InsurPlcyApplUUID              = _InsurOpenApplContract.InsurPlcyApplUUID
                                                                                     and $projection.InsuranceApplication           = _InsurOpenApplContract.InsuranceApplication
                                                                                     and $projection.InsurPlcyInsurContr            = _InsurOpenApplContract.InsurPlcyInsurContr
                                                                                     and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurOpenApplContract.InsurPlcyContrDataDetnJrnlNmbr

  composition [0..*] of I_InsurOpenApplContrCvrgLimit  as _InsOpApContrCvrgLimit
  composition [0..*] of I_InsurOpenApplContrCvrgClause as _InsOpApContrCvrgClause
  composition [0..*] of I_InsOpApContrCvrgDeductible   as _InsOpApContrCvrgDeductible
  composition [0..*] of I_InsOpApContrCvrgInsrdObject  as _InsOpApContrCvrgInsrdObj
  composition [0..*] of I_InsOpApContrCvrgSurcharge    as _InsOpApContrCvrgSurcharge
  composition [0..*] of I_InsOpApContrCvrgSubCoverage  as _InsOpApContrCvrgSubCvrg
  composition [0..*] of I_InsOpApContrCvrgTypeRgnlCl   as _InsOpApContrCvrgTypeRgnlCl
  composition [0..1] of I_InsOpApContrCvrgPremComprn   as _InsOpApContrCvrgPremComprn
  composition [0..*] of I_InsOpApContrCvrgBonusMalus   as _InsOpApContrCvrgBonusMalus
  composition [0..*] of I_InsurOpenApplContrCvrgBnfcy  as _InsOpApContrCvrgBeneficiary

  association [1..1] to I_Currency                     as _PremiumCurrency           on  $projection.InsurPlcyPremiumCurrency = _PremiumCurrency.Currency
  association [1..1] to I_Currency                     as _CoverageCurrency          on  $projection.InsurPlcyCoverageCurrency = _CoverageCurrency.Currency
  association [1..1] to I_InsurContrCanclnReason       as _InsurContrCanclnReason    on  $projection.InsurContrCanclnRsn = _InsurContrCanclnReason.InsurContrCanclnRsn
  association [1..1] to I_InsurPlcyCvrgLifeCycSts      as _InsurPlcyCvrgLifeCycSts   on  $projection.InsurPlcyCvrgLifeCycleStatus = _InsurPlcyCvrgLifeCycSts.InsurPlcyCvrgLifeCycleStatus
  association [1..1] to I_InsurPlcyCvrgInsrdSumCalc    as _InsurPlcyCvrgInsrdSumCalc on  $projection.InsurPlcyCvrgInsrdSumCalcMeth = _InsurPlcyCvrgInsrdSumCalc.InsurPlcyCvrgInsrdSumCalcMeth
  association [1..1] to I_InsurPlcyCvrgSuspension      as _InsurPlcyCvrgSuspension   on  $projection.InsurPlcyCoverageSuspension = _InsurPlcyCvrgSuspension.InsurPlcyCoverageSuspension
  association [1..*] to I_InsurPlcyTemplateT           as _InsurPlcyTemplateT        on  $projection.InsurPlcyElementaryProdTmpl = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [1..1] to I_InsurPlcyCvrgPremExmpRsnLink as _InsurPlcyCvrgPremExmpRsn  on  $projection.InsurPlcyCvrgPremExmpReason = _InsurPlcyCvrgPremExmpRsn.InsurPlcyCvrgPremExmpReason
                                                                                     and $projection.InsurPlcyElementaryProdTmpl = _InsurPlcyCvrgPremExmpRsn.InsurancePolicyCoverageControl

{

  key OpenApplJrnl.InsurPlcyApplUUID,
  key cast( OpenApplJrnl.InsuranceApplication as /pm0/vdm_applicationnr_tt preserving type )              as InsuranceApplication,
  key Coverage.InsurPlcyInsurContr,
  key Coverage.InsurPlcyCoveragePackageID,
  key Coverage.InsurPlcyCoverageID,
  key cast( OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      Coverage.InsurPlcyJrnlNmbr,
      Coverage.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Coverage.InsurPlcyProductPackageID,
      Coverage.InsurPlcyInsuranceCoverage,
      OpenApplJrnl.InsurPlcyUUID,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Coverage.InsurPlcyElementaryProdTmpl,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCoverageStartDateTime,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCoverageEndDateTime,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgPremExmpRsn'
      Coverage.InsurPlcyCvrgPremExmpReason,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgLifeCycSts'
      Coverage.InsurPlcyCvrgLifeCycleStatus,
      @ObjectModel.foreignKey.association: '_InsurContrCanclnReason'
      Coverage.InsurContrCanclnRsn,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCvrgCanclnDateTime,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgSuspension'
      Coverage.InsurPlcyCoverageSuspension,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCvrgSuspnStrtDateTime,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCvrgSuspnEndDateTime,
      @Semantics.amount.currencyCode: 'InsurPlcyCoverageCurrency'
      Coverage.InsurPlcyCvrgInsuredSumAmount,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgInsrdSumCalc'
      Coverage.InsurPlcyCvrgInsrdSumCalcMeth,
      Coverage.InsurPlcyCvrgInsuredSumPercent,
      @ObjectModel.foreignKey.association: '_CoverageCurrency'
      Coverage.InsurPlcyCoverageCurrency,
      //FS-PM Auto sibling specific fields

      Coverage.InsurPlcyBonusRestorerType,
      Coverage.InsurPlcyVehDeregistrationDate,
      Coverage.InsurPlcyBonusMalusIsNotCeded,
      Coverage.InsurPlcyInsurEndMsgSendDate,
      Coverage.InsurPlcySubcoverageVariant,
      Coverage.InsurPlcyVehInsurCoverEndDate,
      Coverage.InsurPlcyNrOfVehClaimsRestored,
      Coverage.InsurPlcyCrteInsurEndMessage,
      Coverage.InsurPlcyDiscProtIsActive,
      @Semantics.systemDateTime.lastChangedAt: true
      Coverage.LastChangeDateTime,

      RegularPremium.InsurancePolicyPremium,
      RegularPremium.InsurPlcyJrnlNmbr                                                                    as InsurPlcyPremiumJournalNumber,
      RegularPremium.InsurPlcyJrnlEndNmbr                                                                 as InsurPlcyPremJournalEndNumber,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPerdPremBfrTaxPaytAmt,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPerdPremAftTaxPaytAmt,
      RegularPremium.InsurPremType,
      @Semantics.booleanIndicator:true
      RegularPremium.InsurPlcyCvrgIsPremiumExempt,
      RegularPremium.InsurPlcyCvrgPremExmpEndDate,
      @ObjectModel.foreignKey.association: '_PremiumCurrency'
      RegularPremium.InsurPlcyPremiumCurrency,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPlcyTotAnnPremAmt,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPlcyPerdPremBfrTxPaytAmt,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      RegularPremium.InsurPlcyPremiumTemplate,

      /* Associations */
      _InsurOpenApplContract,
      _InsOpApContrCvrgSurcharge,
      _InsOpApContrCvrgLimit,
      _InsOpApContrCvrgClause,
      _InsOpApContrCvrgDeductible,
      _InsOpApContrCvrgInsrdObj,
      _InsOpApContrCvrgSubCvrg,
      _InsOpApContrCvrgTypeRgnlCl,
      _InsOpApContrCvrgPremComprn,
      _InsOpApContrCvrgBonusMalus,
      _InsOpApContrCvrgBeneficiary,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _InsurContrCanclnReason,
      @Consumption.hidden: true
      _InsurPlcyCvrgLifeCycSts,
      @Consumption.hidden: true
      _InsurPlcyCvrgSuspension,
      @Consumption.hidden: true
      _InsurPlcyCvrgInsrdSumCalc,
      @Consumption.hidden: true
      _CoverageCurrency,
      @Consumption.hidden: true
      _PremiumCurrency,
      @Consumption.hidden: true
      _InsurPlcyCvrgPremExmpRsn

}
where
      Coverage.InsurPlcyCoveragePackageID = 0
  and OpenApplJrnl.InsurPlcyApplUUID      is not initial //Perf. Tuning: Make inner Join out of left outer Join

  and OpenApplJrnl.InsuranceApplication   is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSUROPENAPPLCONTRACT",
"I_INSURPLCYCOVERAGEBASIC",
"I_INSURPLCYREGPREMCONFIG",
"P_INSUROPENAPPLCOVERAGELATEST",
"R_INSUROPENAPPLICATIONPREMIUM"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_INSOPAPCONTRCVRGBONUSMALUS",
"I_INSOPAPCONTRCVRGDEDUCTIBLE",
"I_INSOPAPCONTRCVRGINSRDOBJECT",
"I_INSOPAPCONTRCVRGPREMCOMPRN",
"I_INSOPAPCONTRCVRGSUBCOVERAGE",
"I_INSOPAPCONTRCVRGSURCHARGE",
"I_INSOPAPCONTRCVRGTYPERGNLCL",
"I_INSURCONTRCANCLNREASON",
"I_INSUROPENAPPLCONTRACT",
"I_INSUROPENAPPLCONTRCVRGBNFCY",
"I_INSUROPENAPPLCONTRCVRGCLAUSE",
"I_INSUROPENAPPLCONTRCVRGLIMIT",
"I_INSURPLCYCVRGINSRDSUMCALC",
"I_INSURPLCYCVRGLIFECYCSTS",
"I_INSURPLCYCVRGPREMEXMPRSNLINK",
"I_INSURPLCYCVRGSUSPENSION",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/