I_InsurInsrblObjectVehicle

@EndUserText.label: 'Insurable Vehicle'
@VDM                                  : {
    viewType                          : #COMPOSITE,
    lifecycle.contract.type           : #PUBLIC_LOCAL_API }

@AccessControl                        : {
    authorizationCheck                : #PRIVILEGED_ONLY,
    personalData.blocking             : #('TRANSACTIONAL_DATA')
//    privilegedAssociations          : [  ' ',  ' ',  ' ']

}

@ObjectModel                          : {
    representativeKey                 : 'InsurInsrblObjUUID',
    semanticKey                       : [ 'InsurInsrblObj' ],
    usageType                         : {
    dataClass                         : #TRANSACTIONAL,
    serviceQuality                    : #A,
    sizeCategory                      : #XL },
    supportedCapabilities             : [ #CDS_MODELING_DATA_SOURCE ] }

@Metadata.allowExtensions             : false
@Metadata.ignorePropagatedAnnotations : false
@Analytics                            : {
    technicalName                     : 'IInsrblObjVeh'}
define view entity I_InsurInsrblObjectVehicle
  as select from I_InsurInsrblObjVehBasic as InsurableObjectVeh

  association        to parent I_InsurInsurableObject as _InsurInsurableObject        on  $projection.InsurInsrblObjUUID     = _InsurInsurableObject.InsurInsrblObjUUID
                                                                                      and $projection.InsurInsrblObjJrnlNmbr = _InsurInsurableObject.InsurInsrblObjJrnlNmbr
                                                                                      and $projection.InsurInsrblObj         = _InsurInsurableObject.InsurInsrblObj

  association [1..1] to I_InsurPlcyVehLicPlateType    as _InsurPlcyVehLicPlateType    on  $projection.InsurPlcyInsrblVehLicPlateType = _InsurPlcyVehLicPlateType.InsurPlcyInsrblVehLicPlateType
  association [1..1] to I_InsurPlcyVehRegnDstrct      as _InsurPlcyVehRegnDstrct      on  $projection.InsurPlcyInsrblVehRegnDstrct = _InsurPlcyVehRegnDstrct.InsurPlcyInsrblVehRegnDstrct
  association [1..1] to I_InsurPlcyVehAdminvDstrct    as _InsurPlcyVehAdminvDstrct    on  $projection.InsurPlcyInsrblVehAdminvDstrct = _InsurPlcyVehAdminvDstrct.InsurPlcyInsrblVehAdminvDstrct
  association [1..1] to I_InsurPlcyInsrblVehicleType  as _InsurPlcyInsrblVehicleType  on  $projection.InsurPlcyInsrblVehTypeKey = _InsurPlcyInsrblVehicleType.InsurPlcyInsrblVehTypeKey
                                                                                      and $projection.InsurPlcyInsrblVehMfrID   = _InsurPlcyInsrblVehicleType.InsurPlcyInsrblVehMfrID
  association [1..1] to I_InsurPlcyVehIntlVehCountry  as _InsurPlcyVehIntlVehCountry  on  $projection.InsurPlcyInsrblVehIntlVehCntry = _InsurPlcyVehIntlVehCountry.InsurPlcyInsrblVehIntlVehCntry
  association [1..1] to I_InsurPlcyInsrblVehUsgeOfVeh as _InsurPlcyInsrblVehUsgeOfVeh on  $projection.InsurPlcyInsrblVehUsgeOfVeh    = _InsurPlcyInsrblVehUsgeOfVeh.InsurPlcyInsrblVehUsgeOfVeh
                                                                                      and $projection.InsurPlcyInsrblVehInsrdInCntry = _InsurPlcyInsrblVehUsgeOfVeh.InsurPlcyInsrblVehInsrdInCntry
  association [1..1] to I_InsurPlcyInsrblVehVehClass  as _InsurPlcyInsrblVehVehClass  on  $projection.InsurPlcyInsrblVehVehicleClass = _InsurPlcyInsrblVehVehClass.InsurPlcyInsrblVehVehicleClass
  association [1..1] to I_InsurPlcyInsrblVehBodyType  as _InsurPlcyInsrblVehBodyType  on  $projection.InsurPlcyInsrblVehBodyType     = _InsurPlcyInsrblVehBodyType.InsurPlcyInsrblVehBodyType
                                                                                      and $projection.InsurPlcyInsrblVehVehicleClass = _InsurPlcyInsrblVehBodyType.InsurPlcyInsrblVehVehicleClass
  association [1..1] to I_InsurPlcyInsrblVehTypeOfVeh as _InsurPlcyInsrblVehTypeOfVeh on  $projection.InsurPlcyInsrblVehTypeOfVeh = _InsurPlcyInsrblVehTypeOfVeh.InsurPlcyInsrblVehTypeOfVeh

  association [1..1] to I_InsurPlcyInsrblVehIntlMfr   as _InsurPlcyInsrblVehIntlMfr   on  $projection.InsurPlcyInsrblVehIntlMfrID = _InsurPlcyInsrblVehIntlMfr.InsurPlcyInsrblVehIntlMfrID
  association [1..1] to I_InsurPlcyVehIntlTypeLink    as _InsurPlcyVehIntlTypeLink    on  $projection.InsurPlcyInsrblVehIntlMfrID   = _InsurPlcyVehIntlTypeLink.InsurPlcyInsrblVehIntlMfrID
                                                                                      and $projection.InsurPlcyInsrblVehIntlTypeID  = _InsurPlcyVehIntlTypeLink.InsurPlcyInsrblVehIntlTypeID
                                                                                      and $projection.InsurPlcyInsrblVehIntlModelID = _InsurPlcyVehIntlTypeLink.InsurPlcyInsrblVehIntlModelID

  association [1..1] to I_InsurInsrblObjPartPrpty     as _InsurInsrblObjPartPrpty     on  $projection.InsurInsrblObjPartPrpty = _InsurInsrblObjPartPrpty.InsurInsrblObjPartPrpty
  association [0..1] to I_BusinessPartner             as _BusinessPartner             on  $projection.InsurInsrblObjPartner = _BusinessPartner.BusinessPartner

{
  key InsurableObjectVeh.InsurInsrblObjUUID,
  key InsurableObjectVeh.InsurInsrblObjJrnlNmbr,
  key InsurableObjectVeh.InsurInsrblObj,
      InsurableObjectVeh.InsurInsrblObjName,
      InsurableObjectVeh.InsurInsrblObjEffctvDte,
      InsurableObjectVeh.InsurInsrblObjCategory,
      //      _InsurInsurableObject._InsurInsrblObjCategory._Text.InsurPlcyInsrdObjCategoryName,

      InsurableObjectVeh.InsurInsrblObjSubCategory,
      //      _InsurInsurableObject._InsurInsrblObjSubCat._Text.InsurPlcyInsrdObjSubCatName,

      InsurableObjectVeh.InsurInsrblObjExtObjNmbr,
      InsurableObjectVeh.InsurInsrblObjStatus,
      @ObjectModel.foreignKey.association: '_BusinessPartner'
      InsurableObjectVeh.InsurInsrblObjPartner,
      @ObjectModel.foreignKey.association: '_InsurInsrblObjPartPrpty'
      InsurableObjectVeh.InsurInsrblObjPartPrpty,
      // MVA specific fields

      InsurableObjectVeh.InsurPlcyInsrblVehLicPltNumber,
      InsurableObjectVeh.InsurPlcyInsrblVehIdnNumber,
      @ObjectModel.foreignKey.association: '_InsurPlcyVehLicPlateType'
      InsurableObjectVeh.InsurPlcyInsrblVehLicPlateType,
      InsurableObjectVeh.InsurPlcyVehSeasonStartMonth,
      InsurableObjectVeh.InsurPlcyInsrblVehSeasnEndMnth,
      @ObjectModel.foreignKey.association: '_InsurPlcyVehRegnDstrct'
      InsurableObjectVeh.InsurPlcyInsrblVehRegnDstrct,
      @ObjectModel.foreignKey.association: '_InsurPlcyVehAdminvDstrct'
      InsurableObjectVeh.InsurPlcyInsrblVehAdminvDstrct,
      InsurableObjectVeh.InsurPlcyInsrblVehInitRegnDate,
      InsurableObjectVeh.InsurPlcyInsrblVehMfrID,
      @ObjectModel.foreignKey.association: '_InsurPlcyInsrblVehicleType'
      InsurableObjectVeh.InsurPlcyInsrblVehTypeKey,
      InsurableObjectVeh.InsurPlcyInsrblVehTypeName,
      InsurableObjectVeh.InsurPlcyInsrblVehMfrName,
      InsurableObjectVeh.InsurPlcyInsrblVehNmbrOfSeats,
      InsurableObjectVeh.InsurPlcyInsrblVehRplcmtCost,
      InsurableObjectVeh.InsurPlcyInsrblVehWindshield,
      InsurableObjectVeh.InsurPlcyInsrblVehIsOthOutput,
      InsurableObjectVeh.InsurPlcyVehMunicipalityID,
      InsurableObjectVeh.InsurPlcyVehShrtTrmPltExpryDte,
      InsurableObjectVeh.InsurPlcyVehChkNmbrVehIdn,
      InsurableObjectVeh.InsurPlcyInsrblVehRegnDate,
      @ObjectModel.foreignKey.association: '_InsurPlcyVehIntlVehCountry'
      InsurableObjectVeh.InsurPlcyInsrblVehIntlVehCntry,
      InsurableObjectVeh.InsurPlcyVehInfoMunicipality,
      InsurableObjectVeh.InsurPlcyInsrblVehNatlTypeID,
      InsurableObjectVeh.InsurPlcyInsrblVehTrdDesc,
      @ObjectModel.foreignKey.association: '_InsurPlcyInsrblVehUsgeOfVeh'
      InsurableObjectVeh.InsurPlcyInsrblVehUsgeOfVeh,
      @ObjectModel.foreignKey.association: '_InsurPlcyInsrblVehTypeOfVeh'
      InsurableObjectVeh.InsurPlcyInsrblVehTypeOfVeh,
      InsurableObjectVeh.InsurPlcyInsrblVehStsIsPrvsnl,
      InsurableObjectVeh.InsurPlcyInsrblVehInsurCertID,
      InsurableObjectVeh.InsurPlcyInsrblVehInsrdInCntry,
      InsurableObjectVeh.InsurPlcyInsrblVehNetLoadQty,
      InsurableObjectVeh.InsurPlcyInsrblVehNetLoadUnit,
      InsurableObjectVeh.InsurPlcyInsrblVehTotWeightQty,
      InsurableObjectVeh.InsurPlcyInsrblVehTotWgtUnit,
      InsurableObjectVeh.InsurPlcyInsrblVehWgtEmptyQty,
      InsurableObjectVeh.InsurPlcyInsrblVehWgtEmptyUnit,
      InsurableObjectVeh.InsurPlcyVehIsIntchgblLicPlt,
      InsurableObjectVeh.InsurPlcyVehReltdIntchgblLic,
      InsurableObjectVeh.InsurPlcyInsrblVehBodyTypeGer,
      @ObjectModel.foreignKey.association: '_InsurPlcyInsrblVehVehClass'
      InsurableObjectVeh.InsurPlcyInsrblVehVehicleClass,
      InsurableObjectVeh.InsurPlcyInsrblVehVehClassName,
      @ObjectModel.foreignKey.association: '_InsurPlcyInsrblVehBodyType'
      InsurableObjectVeh.InsurPlcyInsrblVehBodyType,
      InsurableObjectVeh.InsurPlcyInsrblVehBodyTypeName,
      @Semantics.quantity.unitOfMeasure: 'InsurPlcyInsrblVehEngnPwrUnit'
      InsurableObjectVeh.InsurPlcyInsrblVehEnginePwrQty,
      InsurableObjectVeh.InsurPlcyInsrblVehEngnPwrUnit,
      @Semantics.quantity.unitOfMeasure: 'InsurPlcyInsrblVehEngnCapUnit'
      InsurableObjectVeh.InsurPlcyInsrblVehEngineCapQty,
      InsurableObjectVeh.InsurPlcyInsrblVehEngnCapUnit,
      @ObjectModel.foreignKey.association: '_InsurPlcyInsrblVehIntlMfr'
      InsurableObjectVeh.InsurPlcyInsrblVehIntlMfrID,
      @ObjectModel.foreignKey.association: '_InsurPlcyVehIntlTypeLink'
      InsurableObjectVeh.InsurPlcyInsrblVehIntlTypeID,
      InsurableObjectVeh.InsurPlcyInsrblVehIntlModelID,
      InsurableObjectVeh.InsurPlcyInsrblVehMfgYear,
      InsurableObjectVeh.InsurPlcyInsrblVehPostalCode,
      InsurableObjectVeh.InsurPlcyInsrblVehIsELicPlt,
      @Semantics.systemDateTime.lastChangedAt: true
      InsurableObjectVeh.LastChangeDateTime,
      InsurableObjectVeh.LastChangedByUser,
      @Semantics.systemDateTime.createdAt: true
      InsurableObjectVeh.CreationDateTime,
      InsurableObjectVeh.CreatedByUser,

      @Consumption.hidden: true
      _InsurPlcyVehLicPlateType,
      @Consumption.hidden: true
      _InsurPlcyVehRegnDstrct,
      @Consumption.hidden: true
      _InsurPlcyVehAdminvDstrct,
      @Consumption.hidden: true
      _InsurPlcyInsrblVehicleType,
      @Consumption.hidden: true
      _InsurPlcyVehIntlVehCountry,
      @Consumption.hidden: true
      _InsurPlcyInsrblVehUsgeOfVeh,
      @Consumption.hidden: true
      _InsurPlcyInsrblVehVehClass,
      @Consumption.hidden: true
      _InsurPlcyInsrblVehBodyType,
      @Consumption.hidden: true
      _InsurPlcyInsrblVehTypeOfVeh,
      @Consumption.hidden: true
      _InsurInsrblObjPartPrpty,
      @Consumption.hidden: true
      _InsurPlcyInsrblVehIntlMfr,
      @Consumption.hidden: true
      _InsurPlcyVehIntlTypeLink,
      _BusinessPartner,
      _InsurInsurableObject

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURINSRBLOBJVEHBASIC"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_INSURINSRBLOBJPARTPRPTY",
"I_INSURINSURABLEOBJECT",
"I_INSURPLCYINSRBLVEHBODYTYPE",
"I_INSURPLCYINSRBLVEHICLETYPE",
"I_INSURPLCYINSRBLVEHINTLMFR",
"I_INSURPLCYINSRBLVEHTYPEOFVEH",
"I_INSURPLCYINSRBLVEHUSGEOFVEH",
"I_INSURPLCYINSRBLVEHVEHCLASS",
"I_INSURPLCYVEHADMINVDSTRCT",
"I_INSURPLCYVEHINTLTYPELINK",
"I_INSURPLCYVEHINTLVEHCOUNTRY",
"I_INSURPLCYVEHLICPLATETYPE",
"I_INSURPLCYVEHREGNDSTRCT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/