I_InsurClmFactsItems

@AbapCatalog.sqlViewName: 'ICLSFCITEMS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: {
    dataClass: #MIXED,
    sizeCategory: #L,
    serviceQuality: #X
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'SFC Items'
define view I_InsurClmFactsItems
  as select from I_InsurClmFactCapture
  association to parent I_InsurClmFactsHeader as _SFCHeader on  $projection.InsuranceClaim         = _SFCHeader.InsuranceClaim
                                                            and $projection.InsurClmFactsDraftUUID = _SFCHeader.InsurClmFactsDraftUUID
{
  key InsuranceClaim,
  key InsurClmFactCaptureCategory,
  key InsurFactsSubobject,

  key InsurClmFactCaptureQstn,

  key InsurClmFactCaptureAnswer,
  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x16 preserving type ) as InsurClmFactsDraftUUID,
      //  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x16 preserving type ) as SFCItemDraftUUID,

      _FactCaptureAnswer.InsurClmFactFreeTextAnswerCat                                     as InsurClmFactFreeTextAnswerCat,

      // Introducing ForEdit fields as Key fields cannot be edited.

      @ObjectModel.editableFieldFor: 'InsurClmFactCaptureQstn'
      InsurClmFactCaptureQstn                                                              as InsurClmFactCaptureQstnForEdit,
      @ObjectModel.editableFieldFor: 'InsurClmFactCaptureAnswer'
      InsurClmFactCaptureAnswer                                                            as InsurClmFactCaptureAnswForEdit,
      //      concat(InsurClmFactCaptureQstn, InsurClmFactCaptureAnswer) as InsurClmFactCaptureAnswForEdit,


      InsurClmFactCaptureQstnPos,
      InsurClmFactCaptureQstnSqnc,
      InsurClmFactCaptureSqncVersion,
      InsurClmFactCaptureSqncVariant,

      _FactCaptureQstn.InsurClmFactCaptureQstnCat                                          as InsurClmFactCaptureQstnCat,
      _FactCaptureQstn._FactCaptureQstnText[ Language = $session.system_language ].InsurClmFactCaptureQstnShrtTxt,
      _FactCaptureQstn._FactCaptureQstnText[ Language = $session.system_language ].InsurClmFactCaptureQstnLongTxt,
      _FactCaptureAnswer._FactCaptureAnswerT[ Language = $session.system_language ].InsurClmFactAnswerShortText,
      _FactCaptureAnswer._FactCaptureAnswerT[ Language = $session.system_language ].InsurClmFactAnswerLongText,
      _FactCaptureTxtAnswer. InsurClmFactCaptureTextAnswer,

      // Transient field to hold answer keys for user selected answers for a multiple choice question

      //     InsurClmFactCaptureTextAnswer as InsurClmFactUsrSeldAnswerKeys,

      _FactCaptureTxtAnswer.InsurClmFactCaptureTextAnswer                                  as InsurClmFactUsrSeldAnswerKeys,
      _FactCaptureQstn. InsurClmFactQstnIsMltplChoice,
      _FactCaptureAnswer. InsurClmFactCaptureNextQstn,
      //      cast('' as xfeld preserving type )                                                   as UIHiddenFlag,

      /* Associations */
      //I_InsurClm1stNotifFactCapture

      _FactCaptureAnswer,
      _FactCaptureQstn,

      _Claim,
      _SFCHeader // Make association public

}

where
      InsurClmFactCaptureCategory = 'KF'
  and InsurClmSubobject           = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURCLMFACTCAPTURE",
"I_INSURCLMFACTCAPTUREANSWER",
"I_INSURCLMFACTCAPTUREANSWERT",
"I_INSURCLMFACTCAPTUREQSTN",
"I_INSURCLMFACTCAPTUREQSTNTEXT",
"I_INSURCLMFACTCAPTURETXTANSWER"
],
"ASSOCIATED":
[
"I_INSURANCECLAIM",
"I_INSURCLMFACTCAPTUREANSWER",
"I_INSURCLMFACTCAPTUREQSTN",
"I_INSURCLMFACTSHEADER"
],
"BASE":
[
"I_INSURCLMFACTCAPTURE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/