I_InsurClmFNOLPaytAppTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Payment section in FNOL - TP'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
    serviceQuality: #X,
    sizeCategory: #S,
    dataClass: #MIXED
}
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle: {
contract: {type: #SAP_INTERNAL_API }
 }
define view entity I_InsurClmFNOLPaytAppTP
  as select from I_InsurClmPaymentApp
  association        to parent I_InsurClmFNOLTP  as _ClaimHead   on  $projection.InsuranceClaim = _ClaimHead.InsuranceClaim
                                                                 and $projection.InsurClaimUUID = _ClaimHead.InsurClaimUUID
  association [0..*] to I_InsurClmPaymentItem    as _PayItem     on  $projection.InsuranceClaim = _PayItem.InsuranceClaim
  association [0..*] to I_InsurClmFNOLPaytConfig as _PayFNOL     on  $projection.InsurClmType = _PayFNOL.InsurClmType
  association [1]    to I_InsurClmBenefitType    as _BenefitType on  $projection.InsurBnftType = _BenefitType.InsurBnftType
  association [0..*] to I_CAPaymentMethodText    as _PayText     on  $projection.Country            = _PayText.Country
                                                                 and $projection.InsurClmPaytMethod = _PayText.CAPaymentMethod

{
  key      InsuranceClaim,
  key      cast ( hextobin('00000000000000000000000000000000') as sysuuid_x16 preserving type ) as InsurClaimUUID,
  key      InsurClmType,
  key      _PayFNOL.InsurBnftType                                                               as InsurBnftType,
  key      InsurClmSubclm,
  key      InsurClmPayt,
  key      cast ( hextobin('00000000000000000000000000000000') as sysuuid_x16 preserving type ) as InsurClmPaytUUID,
           _PayFNOL.InsurClmIncdntType                                                          as InsurClmIncdntType,
           _PayFNOL.InsurClmPolicyProduct                                                       as InsurClmPolicyProduct,


           _PayFNOL.InsurClmSubclmType,
           // Field to be edited on screen

           @ObjectModel.editableFieldFor: 'InsurBnftType'
           _PayFNOL.InsurBnftType                                                               as InsurBnftTypeForEdit,
           InsurClmPaymentCurrency,
           @Semantics.amount.currencyCode: 'InsurClmPaymentCurrency'
           InsurClmPaytTotalAmount,
           InsurClmPaytMethod,
           InsurClmPaytIsFinalPayment,
           InsurClmBankID,
           InsurClmPaytAddrNmbrForChecks,
           InsuranceClaimPayee,
           Country,
           //  InsurClmPaytCheckRcpntAddrNmbr,

           _PayText[Language = $session.system_language ].CAPaymentMethodName,
           InsurClmAuthznGrp,
           //           _CompanyCode.Country,

           @Semantics.booleanIndicator: true
           cast('' as xbkkt preserving type )                                                   as BankDetailsOfBPAreRequired,
           @Semantics.booleanIndicator: true
           cast('' as xstra preserving type )                                                   as AddressDetailsAreRequired,
           _ClaimHead,
           _BenefitType,
           _PayFNOL
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CAPAYMENTMETHODTEXT",
"I_INSURCLMFNOLPAYTCONFIG",
"I_INSURCLMPAYMENTAPP"
],
"ASSOCIATED":
[
"I_INSURCLMBENEFITTYPE",
"I_INSURCLMFNOLPAYTCONFIG",
"I_INSURCLMFNOLTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/