I_InsurClm1stNotifContrValHelp

@AbapCatalog.sqlViewName: 'ICL1STNFCONTRVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Schadenmeldung - Wertehilfe Vertrag'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #COMPOSITE
@ObjectModel.representativeKey: 'InsuranceContract'
@ObjectModel.dataCategory:#VALUE_HELP
@Search.searchable: true
define view I_InsurClm1stNotifContrValHelp
  as select from I_BusinessPartner                                         as _PolicyHolder

    inner join   P_InsurClm1stNotifContractVH(P_SAPClient:$session.client) as _Policy_PM on _PolicyHolder.BusinessPartner = _Policy_PM.InsurancePolicyholder

{
      @UI.selectionField: [ { position: 130 } ]
      @Search.defaultSearchElement : true
      @Search.fuzzinessThreshold : 0.8
      @Search.ranking : #HIGH
  key InsuranceContract,

      @UI.selectionField: [ { position: 10 } ]
      @Search.defaultSearchElement : true
      @Search.fuzzinessThreshold : 0.8
      @Search.ranking : #HIGH
      _PolicyHolder.BirthDate,

      @UI.selectionField: [ { position: 30 } ]
      @Search.defaultSearchElement : true
      @Search.fuzzinessThreshold : 0.8
      @Search.ranking : #HIGH
      @Semantics.name.familyName: true
      _PolicyHolder.LastName,

      @UI.selectionField: [ { position: 20 } ]
      @Search.defaultSearchElement : true
      @Search.fuzzinessThreshold : 0.8
      @Search.ranking : #MEDIUM
      @Semantics.name.givenName: true
      _PolicyHolder.FirstName,

      @UI.selectionField: [ { position: 40 } ]
      @Semantics.name.fullName: true
      cast( _PolicyHolder.BusinessPartnerName as icl_policyholder_name preserving type)                                          as InsurancePolicyholderName,

      @UI.selectionField: [ { position: 50 } ]
      @Semantics.address.type: [ { HOME } ]
      @Semantics.address.street: true
      _PolicyHolder._CurrentDefaultAddress._Address.StreetName,

      @UI.selectionField: [ { position: 60 } ]
      @Semantics.address.number: true
      _PolicyHolder._CurrentDefaultAddress._Address.HouseNumber,

      @UI.selectionField: [ { position: 70 } ]
      @Semantics.address.city: true
      _PolicyHolder._CurrentDefaultAddress._Address.CityName,

      @UI.selectionField: [ { position: 80 } ]
      @Semantics.address.postBox: true
      _PolicyHolder._CurrentDefaultAddress._Address.PostalCode,

      @UI.selectionField: [ { position: 90 } ]
      @Semantics.telephone.type: [#PREF, #CELL]
      _PolicyHolder._CurrentDefaultAddress._Address._DefaultPhoneNumber.PhoneNumber,

      @UI.selectionField: [ { position: 100 } ]
      @Semantics.eMail.type:  [ #PREF, #WORK ]
      @Semantics.eMail.address: true
      _PolicyHolder._CurrentDefaultAddress._Address._DefaultEmailAddress.EmailAddress,

      @UI.selectionField: [ { position: 110 } ]
      cast( _PolicyHolder.BusinessPartner as icl_polholder preserving type )                                                     as InsurancePolicyholder,

      //For authorizations

      @UI.hidden: true
      _PolicyHolder.AuthorizationGroup,
      @UI.hidden: true
      _PolicyHolder.IsBusinessPurposeCompleted,
      //added only for DCL check

     @Consumption.hidden:true
      @UI.hidden:true
     _PolicyHolder.DataControllerSet as DataControllerSet,                                                                                                                                                                      
      @Consumption.hidden:true
      @UI.hidden:true
     _PolicyHolder.DataController1 as DataController1,                                                                                                                                                                      
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
     _PolicyHolder.DataController2 as DataController2,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
     _PolicyHolder.DataController3 as DataController3,
     //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
     _PolicyHolder.DataController4 as DataController4,
     //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
     _PolicyHolder.DataController5 as DataController5,                                                                                                                                                                       
      @Consumption.hidden:true
      @UI.hidden:true
     _PolicyHolder.DataController6 as  DataController6,                                                                                                                                                                        
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
     _PolicyHolder.DataController7 as DataController7,                                                                                                                                                                      
     //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
    _PolicyHolder.DataController8 as DataController8,
     //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
     _PolicyHolder.DataController9 as DataController9,                                                                                                                                   
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
     _PolicyHolder.DataController10 as DataController10

      //Associations


}
where
  InsuranceContract <> ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_ADDRESSEMAILADDRESS",
"I_ADDRESSPHONENUMBER",
"I_BPCURRENTDEFAULTADDRESS",
"I_BUSINESSPARTNER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/