I_InsurApplInsuredObject

@EndUserText.label: 'Cvrg InsOb of Cvrg Pckg in Insur Appl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [  '_InsurApplCvrgInsrdObjClause',
                              '_InsurApplCvrgInsrdObjDcbl',
                              '_InsurApplCvrgObjSurchrgDisc',
                              '_InsurApplCvrgInsuredVehicle',
                              '_InsurApplCvrgNamedDriver',
                              '_InsurApplCvrgSpclEquipment']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyInsuredObjectID',
   semanticKey: [ 'InsurPlcyInsrdObjUnqID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #L
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IAInsrdObj'
}

define view entity I_InsurApplInsuredObject
  as select from P_InsurPolicyJournalKeys      as PlcyJrnl
    inner join   I_InsurPlcyInsuredObjectBasic as Subject on  PlcyJrnl.InsurPlcyUUID                  =  Subject.InsurPlcyUUID
                                                          and PlcyJrnl.InsurPlcyInsurContr            =  Subject.InsurPlcyInsurContr
                                                          and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr >= Subject.InsurPlcyJrnlNmbr
                                                          and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr <  Subject.InsurPlcyJrnlEndNmbr

  association        to parent I_InsurApplCoverage    as _InsurApplCoverage        on  $projection.InsurPlcyUUID                  = _InsurApplCoverage.InsurPlcyUUID
                                                                                   and $projection.InsurPlcyInsurContr            = _InsurApplCoverage.InsurPlcyInsurContr
                                                                                   and $projection.InsurPlcyCoveragePackageID     = _InsurApplCoverage.InsurPlcyCoveragePackageID
                                                                                   and $projection.InsurPlcyCoverageID            = _InsurApplCoverage.InsurPlcyCoverageID
                                                                                   and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurApplCoverage.InsurPlcyContrDataDetnJrnlNmbr

  composition [0..*] of I_InsurApplCvrgInsrdObjClause as _InsurApplCvrgInsrdObjClause
  composition [0..*] of I_InsurApplCvrgInsrdObjDcbl   as _InsurApplCvrgInsrdObjDcbl
  composition [0..*] of I_InsurApplCvrgObjSurchrgDisc as _InsurApplCvrgObjSurchrgDisc
  composition [0..1] of I_InsurApplCvrgInsuredVehicle as _InsurApplCvrgInsuredVehicle
  composition [0..*] of I_InsurApplCvrgNamedDriver    as _InsurApplCvrgNamedDriver
  composition [0..*] of I_InsurApplCvrgSpclEquipment  as _InsurApplCvrgSpclEquipment
  composition [0..1] of I_InsurApplCvrgPckgCvrgBldng  as _InsurApplCvrgPckgCvrgBldng

  association [1..1] to I_InsurInsrdObjectCategory    as _InsurInsrdObjectCategory on  $projection.InsurPlcyInsuredObjectCategory = _InsurInsrdObjectCategory.InsurPlcyInsuredObjectCategory
  association [1..1] to I_InsurInsrdObjSubCategory    as _InsurInsrdObjSubCategory on  $projection.InsurPlcyInsrdObjSubCategory = _InsurInsrdObjSubCategory.InsurPlcyInsrdObjSubCategory
  association [1..*] to I_InsurPlcyTemplateT          as _InsurPlcyTemplateT       on  $projection.InsurPlcyInsrdObjectTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate

  association [1..1] to I_InsurInsurableObject        as _InsurInsurableObject     on  $projection.InsurPlcyInsrdObjUnqID = _InsurInsurableObject.InsurInsrblObj
                                                                                   and $projection.InsurInsrblObjJrnlNmbr = _InsurInsurableObject.InsurInsrblObjJrnlNmbr

{

  key Subject.InsurPlcyUUID,
  key Subject.InsurPlcyInsurContr,
  key Subject.InsurPlcyCoveragePackageID,
  key Subject.InsurPlcyCoverageID,
  key Subject.InsurPlcyInsuredObjectID,
  key cast( PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      Subject.InsurPlcyJrnlNmbr,
      Subject.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Subject.InsurPlcyProductPackageID,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Subject.InsurPlcyInsrdObjectTemplate,
      @ObjectModel.foreignKey.association: '_InsurInsrdObjectCategory'
      Subject.InsurPlcyInsuredObjectCategory,
      @ObjectModel.foreignKey.association: '_InsurInsrdObjSubCategory'
      Subject.InsurPlcyInsrdObjSubCategory,
      @ObjectModel.foreignKey.association: '_InsurInsurableObject'
      Subject.InsurPlcyInsrdObjUnqID,
      Subject.InsurInsrblObjJrnlNmbr,
      @Semantics.systemDateTime.lastChangedAt: true
      Subject.LastChangeDateTime,

      /* Associations */
      _InsurApplCoverage,
      _InsurApplCvrgInsrdObjClause,
      _InsurApplCvrgInsrdObjDcbl,
      _InsurApplCvrgObjSurchrgDisc,
      _InsurApplCvrgInsuredVehicle,
      _InsurApplCvrgNamedDriver,
      _InsurApplCvrgSpclEquipment,
      _InsurApplCvrgPckgCvrgBldng,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _InsurInsrdObjectCategory,
      @Consumption.hidden: true
      _InsurInsrdObjSubCategory,
      _InsurInsurableObject

}
where
      Subject.InsurPlcyCoveragePackageID <> 0
  and Subject.InsurPlcyCoverageID        <> 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYINSUREDOBJECTBASIC",
"P_INSURPOLICYJOURNALKEYS"
],
"ASSOCIATED":
[
"I_INSURAPPLCOVERAGE",
"I_INSURAPPLCVRGINSRDOBJCLAUSE",
"I_INSURAPPLCVRGINSRDOBJDCBL",
"I_INSURAPPLCVRGINSUREDVEHICLE",
"I_INSURAPPLCVRGNAMEDDRIVER",
"I_INSURAPPLCVRGOBJSURCHRGDISC",
"I_INSURAPPLCVRGPCKGCVRGBLDNG",
"I_INSURAPPLCVRGSPCLEQUIPMENT",
"I_INSURINSRDOBJECTCATEGORY",
"I_INSURINSRDOBJSUBCATEGORY",
"I_INSURINSURABLEOBJECT",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/